Tungsten Carbide tinkers

#loader contenttweaker

import mods.contenttweaker.MaterialSystem;
import mods.contenttweaker.Material;
import mods.contenttweaker.MaterialBuilder;
import mods.contenttweaker.tconstruct.Trait;
import mods.contenttweaker.tconstruct.TraitBuilder;

var part_names = ["dust", "gear", "plate", "nugget", "ingot"] as string[];

var builder = MaterialSystem.getMaterialBuilder();
builder.setName("Tungsten Carbide");
builder.setColor(0x63595f);
builder.setHasEffect(false);

val tungstenCarbide = builder.build();

tungstenCarbide.registerParts(part_names);

var tCBlock = tungstenCarbide.registerPart("block").getData();
tCBlock.addDataValue("hardness", "5");
tCBlock.addDataValue("resistance", "30");
tCBlock.addDataValue("harvestTool", "pickaxe");
tCBlock.addDataValue("harvestLevel", "1");

var tCFluid = tungstenCarbide.registerPart("molten").getData();
tCFluid.addDataValue("temperature", "3200");
tCFluid.addDataValue("density", "15000");
tCFluid.addDataValue("luminosity", "5");
tCFluid.addDataValue("viscosity", "30000");
tCFluid.addDataValue("vaporize", "false");

val tCMat = mods.contenttweaker.tconstruct.MaterialBuilder.create("tungsten_carbide_ct");
tCMat.color = 0x63595f;
tCMat.craftable = false;
tCMat.castable = true;
tCMat.liquid = <liquid:tungsten_carbide>;
tCMat.localizedName = "Tungsten Carbide";
tCMat.representativeOre = <ore:ingotTungstenCarbide>;

// stats!
tCMat.addHeadMaterialStats(801, 9.6, 8.5, 20);
tCMat.addHandleMaterialStats(0.88, 80);
tCMat.addExtraMaterialStats(120);

// custom traits!
val superhard = mods.contenttweaker.tconstruct.TraitBuilder.create("superhard");
superhard.localizedDescription = "Mines blocks with higher harvest level faster. Cannot be combined with silky";
superhard.localizedName = "Superhard";
superhard.color = 0x63595f;

// prevent combining with silky
superhard.canApplyTogetherTrait = function(thisTrait, otherTrait) { return otherTrait != "silktouch"; };

// mine faster
global speedLookup as float[] = [1, 1.3, 1.7, 2.2, 2.9, 3.7, 4.8, 6.3, 8.2] as float[];
superhard.getMiningSpeed = function(trait, tool, event) {
    val lookup = event.block.definition.harvestLevel;
    if (lookup < 9)
    {
        event.newSpeed = event.originalSpeed * speedLookup[lookup];
    } else
    {
        event.newSpeed = event.originalSpeed * 12;
    }
};
val superhardTrait = superhard.register() as Trait;

// add the trait
tCMat.addMaterialTrait(superhardTrait, "head");

tCMat.register();