qgnomeplatform

pkgname=('qgnomeplatform' 'qgnomeplatform-qt6')
pkgbase=qgnomeplatform
pkgver=0.8.1
pkgrel=1
pkgdesc="QPlatformTheme for a better Qt application inclusion in GNOME"
arch=('x86_64')
url="https://github.com/FedoraQt/QGnomePlatform"
license=('LGPL2.1')
makedepends=('adwaita-qt>=1.4.1' 'adwaita-qt6>=1.4.1' 'cmake' 'git' 'gtk3'
             'qt5-wayland' 'qt6-wayland')
_commit=f75a94825224edce4ecc3d952cc819b2d5f295b4
source=("$pkgname::git+https://github.com/FedoraQt/QGnomePlatform.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$pkgname"
  git describe --tags | sed 's/-/+/g'
}

build() {
  cmake -B build-qt5 -S "$pkgname" \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUSE_QT6=OFF \
    -Wno-dev
  make -C build-qt5

  cmake -B build-qt6 -S "$pkgname" \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUSE_QT6=ON \
    -Wno-dev
  make -C build-qt6
}

package_qgnomeplatform() {
  pkgdesc="QPlatformTheme for a better Qt5 application inclusion in GNOME"
  depends=('adwaita-qt>=1.4.0' 'gtk3' 'qt5-wayland')

  make -C build-qt5 DESTDIR="$pkgdir" install
}

package_qgnomeplatform-qt6() {
  pkgdesc="QPlatformTheme for a better Qt6 application inclusion in GNOME"
  depends=('adwaita-qt6>=1.4.0' 'gtk3' 'qt6-wayland')

  make -C build-qt6 DESTDIR="$pkgdir" install
}