(Pawn) Anuncios via Facebook

#include a_samp

// ===========================================================================

// Mude APENAS essas duas definições !!
#define FACEBOOK    "" // Mude aqui para seu facebook. Caso não tiver usuário, pode colocar id!
#define KEYACCESS   "" // Mude aqui para sua access_key


// Como o host do Joao Paulo tinha algumas propagandas, usei esta defina
// Caso ela estiver no código, ela retira a parte "Hosting24 Analytics Code"

#define PROPAGANDA


// ===========================================================================



#if !defined HTTP_ERROR_BAD_HOST

        #include a_http

#endif

#define FacebookAnn:: FacebookAnn_
#define FacebookAnn_function%0(%1) forward %0(%1); public %0(%1)



/* ---------------------------------------------------

    Ao iniciar filterscript, começar as requisições

 -----------------------------------------------------*/


public OnFilterScriptInit() {

    printf("Sistema de Facebook Carregado");

    FacebookCheck();

    return true;
}



/* ---------------------------------------------------

    Função responsável por fazer a requisição HTTP
   Não mude a URL, ela foi configurada corretamente para isto

 -----------------------------------------------------*/

FacebookAnn::function FacebookCheck() {

    // AGRADEÇAM João Pedro por hospedar o código PHP responsável pelo processamento com Facebook!
    HTTP(0, HTTP_GET, "joaopedroalves.tk/pawn/news-system/?user_name="FACEBOOK"&acess_token="KEYACCESS"", "\0", "FacebookResponse");

    return SetTimer("FacebookCheck", 13000, false );
}





/* -------------------------------------------------------------

    Função responsável por fazer o processamento da requisicao
      Nessa parte é processado o link que o meu site retornou
        e também é enviado a mensagem aos jogadores!!

 -----------------------------------------------------*/

new lastpost[141];

FacebookAnn::function FacebookResponse(index, c, data[]) {

    if ( c ==  200  ) {


        #if defined PROPAGANDA

        if((c=strfind(data, "<!-- Hosting24 Analytics Code -->")) != (-1)) {
            data[c] = EOS;
        }

        #endif

        if(strlen(lastpost) < 5 || strcmp(data, lastpost, true) == -1) {

            new string [167];
            format(string, 167, data);

            html_entities(string, string);
            format( string, 167, " Facebook: ("FACEBOOK"): %s", string);


            // --- Enviar mensagem para todos jogadores
            SendClientMessageToAll(-1, string);
            print(string);

            format(lastpost, 141, data);
        }
    }

    return true;

}




/* -------------------------------------------------------------

    Função "html_entities" usada para fazer entities de alguns acentos
           Assim fixando o texto recebido via html !!

 -----------------------------------------------------*/


html_entities(dest[], html[], len = sizeof html, destl = sizeof dest) {

    static entitie[4], i, c;

    for( i = 0 ; html[i+3] ; i++) {

        if( html[i] == '&' && html[i+1] == '#') {

            if(-1 != (c=strfind(html, ";", false, i + 2))) {

                strmid(entitie, html, i+2, c);

                strdel(html, i, c+1);

                c = i;
                i += 3 + strlen(entitie);

                format(entitie, 4, "%c", strval(entitie));

                strins(html, entitie, c, len);
            }
        }
    }

    return format(dest, destl, html);
}