# Maintainer:  Vitalii Kuzhdin <[email protected]>

pkgbase="rustpython-bootstrap"
pkgname=(
  "rustpython-build-bootstrap"
  "rustpython-flit-core-bootstrap"
  "rustpython-installer-bootstrap"
  "rustpython-packaging-bootstrap"
  "rustpython-pyproject-hooks-bootstrap"
  "rustpython-setuptools-bootstrap"
  "rustpython-wheel-bootstrap"
)
pkgver=3.13.0
pkgrel=1
arch=('any')
url="https://gitlab.archlinux.org/archlinux/python-bootstrap"
license=('custom')
depends=(
  'rustpython'
)
makedepends=(
  'git'
  'rustpython'
)
_pkgsrc="${url##*/}"
source=(
  "${_pkgsrc}::git+${url}.git#tag=${pkgver}?signed"
  "python-build::git+https://github.com/pypa/build.git"
  "python-flit::git+https://github.com/takluyver/flit.git"
  "python-installer::git+https://github.com/pypa/installer.git"
  "python-wheel::git+https://github.com/pypa/wheel.git"
  "python-packaging::git+https://github.com/pypa/packaging"
  "python-pyproject-hooks::git+https://github.com/pypa/pyproject-hooks"
  "python-setuptools::git+https://github.com/pypa/setuptools.git"
)
sha256sums=('375ff304891e5818f8ecd856fc030b54a33d27241d27e986e40f3b8b64dcd36e'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP')
validpgpkeys=('991F6E3F0765CF6295888586139B09DA5BF0D338') # David Runge <[email protected]> (TU)

prepare() {
  cd "${srcdir}/${_pkgsrc}"
  git submodule init

  git config submodule."external/build".url "${srcdir}/python-build"
  git config submodule."external/flit".url "${srcdir}/python-flit"
  git config submodule."external/installer".url "${srcdir}/python-installer"
  git config submodule."external/wheel".url "${srcdir}/python-wheel"
  git config submodule."external/packaging".url "${srcdir}/python-packaging"
  git config submodule."external/pyproject-hooks".url "${srcdir}/python-pyproject-hooks"
  git config submodule."external/setuptools".url "${srcdir}/python-setuptools"

  git -c protocol.file.allow=always submodule update
  git submodule update --init --recursive

  # ?
  find . -type f -name '*.py' -exec \
    sed -i 's/python -m/rustpython -m/g' "{}" +
}

build() {
  cd "${srcdir}/${_pkgsrc}"
  rustpython -m bootstrap.build
}

package_rustpython-build-bootstrap() {
  pkgdesc="A simple, correct PEP 517 build frontend (bootstrap)"
  depends+=(
    'rustpython-packaging'
    'rustpython-pyproject-hooks'
  )
  provides=(
    "${pkgname%-bootstrap}"
  )
  conflicts=(
    "${pkgname%-bootstrap}"
  )

  cd "${srcdir}/${_pkgsrc}"
  rustpython -m bootstrap.install dist/build-*-py3-none-any.whl -d "${pkgdir}"
}

package_rustpython-installer-bootstrap() {
  pkgdesc="Low-level library for installing a Python package from a wheel distribution (bootstrap)"
  provides=(
    "${pkgname%-bootstrap}"
  )
  conflicts=(
    "${pkgname%-bootstrap}"
  )

  cd "${srcdir}/${_pkgsrc}"
  rustpython -m bootstrap.install dist/installer-*-py3-none-any.whl -d "${pkgdir}"
}

package_rustpython-flit-core-bootstrap() {
  pkgdesc="Simplified packaging of Python modules (core backend) (bootstrap)"
  provides=(
    "${pkgname%-bootstrap}"
  )
  conflicts=(
    "${pkgname%-bootstrap}"
  )

  cd "${srcdir}/${_pkgsrc}"
  rustpython -m bootstrap.install dist/flit_core-*-py3-none-any.whl -d "${pkgdir}"
}

package_rustpython-wheel-bootstrap() {
  pkgdesc="A built-package format for Python (bootstrap)"
  provides=(
    "${pkgname%-bootstrap}"
  )
  conflicts=(
    "${pkgname%-bootstrap}"
  )

  cd "${srcdir}/${_pkgsrc}"
  rustpython -m bootstrap.install dist/wheel-*-py3-none-any.whl -d "${pkgdir}"
}

package_rustpython-packaging-bootstrap() {
  pkgdesc="Core utilities for Python packages (bootstrap)"
  provides=(
    "${pkgname%-bootstrap}"
  )
  conflicts=(
    "${pkgname%-bootstrap}"
  )

  cd "${srcdir}/${_pkgsrc}"
  rustpython -m bootstrap.install dist/packaging-*-py3-none-any.whl -d "${pkgdir}"
}

package_rustpython-pyproject-hooks-bootstrap() {
  pkgdesc="A low-level library for calling build-backends in pyproject.toml-based project (bootstrap)"
  provides=(
    "${pkgname%-bootstrap}"
  )
  conflicts=(
    "${pkgname%-bootstrap}"
  )

  cd "${srcdir}/${_pkgsrc}"
  rustpython -m bootstrap.install dist/pyproject_hooks-*-py3-none-any.whl -d "${pkgdir}"
}

package_rustpython-setuptools-bootstrap() {
  pkgdesc="Easily download, build, install, upgrade, and uninstall Python packages (bootstrap)"
  provides=(
    "${pkgname%-bootstrap}"
  )
  conflicts=(
    "${pkgname%-bootstrap}"
  )

  cd "${srcdir}/${_pkgsrc}"
  rustpython -m bootstrap.install dist/setuptools-*-py3-none-any.whl -d "${pkgdir}"
}