/// draw_sprite_wave(sprite,subimage,x,y,xscale,yscale,amount,time,frequency,segments,colour,alpha)

var _sprite    = argument0;
var _subimage  = argument1;
var _x         = argument2;
var _y         = argument3;
var _xscale    = argument4;
var _yscale    = argument5;
var _amount    = argument6;
var _time      = argument7;
var _frequency = argument8;
var _segments  = argument9;
var _colour    = argument10;
var _alpha     = argument11;
var _xoffset   = sprite_get_xoffset(_sprite);
var _yoffset   = sprite_get_yoffset(_sprite);
var _width     = sprite_get_width(_sprite);
var _height    = sprite_get_height(_sprite);
var _texture   = sprite_get_texture(_sprite, _subimage);
var _yIncrease = _height / _segments;
var _iIncrease = 1 / _height * _yIncrease;
var _i         = 0;

_x -= _xoffset * _xscale;
_y -= _yoffset * _yscale;

_yIncrease *= _yscale;

draw_primitive_begin_texture(pr_trianglestrip, _texture);

repeat (_segments + 1)
{
    draw_vertex_texture_colour(_x + sin(_time) * _amount,                   _y, 0, _i, _colour, _alpha);
    draw_vertex_texture_colour(_x + sin(_time) * _amount + _width * _xscale,_y, 1, _i, _colour, _alpha);
    _i    += _iIncrease;
    _y    += _yIncrease;
    _time += _frequency;
}

draw_primitive_end();