METHOD send_mail.

    DATA(lo_mail) = cl_bcs=>create_persistent( ).
    DATA(lo_document) = NEW cl_document_bcs( ).

    DATA lv_subject TYPE so_obj_des.

    "Temat wiadomości: Dokument sprzedaży do zamówienia nr &1.
    lv_subject = TEXT-001.
    REPLACE '&1' IN lv_subject WITH |{ s_inv_mail-bstkd ALPHA = OUT }|.

    "Pobieranie treści
    DATA(lt_text) = me->get_text( ).

    "Tworzenie dokumentu
    lo_document = cl_document_bcs=>create_document(
                  EXPORTING
                   i_type       = 'HTM'
                   i_subject    = lv_subject
                   i_length     = '1000000'
                   i_language   = sy-langu
                   i_importance = '1'
                   i_text       = lt_text
    ).

    TRY.
        "Dodawanie załącznika
        lo_document->add_attachment(
          EXPORTING
            i_attachment_type    = 'BIN'
            i_attachment_subject = |{ s_inv_mail-bstkd }.pdf|
            i_attachment_size    = CONV so_obj_len( iv_pdf_length )
            i_att_content_hex    = it_pdf_content
        ).

      CATCH cx_document_bcs.
        EXIT.

    ENDTRY.

    "Przypisanie dokumentu
    lo_mail->set_document( lo_document ).

    "Ustawianie nadawcy
    lo_mail->set_sender( i_sender =  cl_cam_address_bcs=>create_internet_address( 'esklep@kross.pl' ) ).

    TRY.
        "Dodawanie odbiorcy
        lo_mail->add_recipient(
          EXPORTING
            i_recipient     = cl_cam_address_bcs=>create_internet_address( s_inv_mail-smtp_addr  )
            i_express       = 'X'  " Send As Express Message
        ).

        "Wysyłanie maila
        ev_ok = lo_mail->send( ).

      CATCH cx_address_bcs.
        EXIT.

    ENDTRY.


  ENDMETHOD.