stock alt_strins(string[], const substr[], pos, maxlength = sizeof string)
{
    if (string[0] > 255)
    {
        new
            strlength = strlen(string),
            sublength = strlen(substr),
            m4 = maxlength * 4
        ;

        if (strlength + sublength >= m4)
        {
            if (pos + sublength >= m4) {
                return
                    string{pos} = '\0',
                    strcat(string, substr, maxlength);
            }
            else {
                string{maxlength - sublength - 1} = '\0';
            }
        }
        return strins(string, substr, pos, maxlength);
    }
    else if (substr[0] > 255)
    {
        new
            strlength = strlen(string),
            sublength = strlen(substr)
        ;
        if (strlength + sublength >= maxlength)
        {
            if (pos + sublength >= maxlength) {
                return
                    string[pos] = '\0',
                    strcat(string, substr, maxlength);
            }
            else {
                string[maxlength - sublength - 1] = '\0';
            }
        }
        return strins(string, substr, pos, maxlength);
    }
    else
    {
        return format(string, maxlength, "%.*s%s%s", pos, string, substr, string[pos]);
    }
}

#define _ALS_strins
#define strins( alt_strins(