LogFileFunction

REM See Also https://pastebin.com/auWb4ELX for a menu based file Logger

@ECHO OFF
SETLOCAL EnableDelayedExpansion
Set Val=0
Set Found=0
Set Home_Dir=%windir%\system32
Set Prog_Dir=%~dp0
if exist "files.txt" (
DEL /Q files.txt
)

MODE CON: cols=150 lines=30

::: Add remove extensions to be searched to suit needs

Set "ext=com" && CALL :process
Set "ext=dll" && CALL :process

REM ::: Display Completion Statement

ECHO 
ECHO  Logging Complete. !Found! Files found out of !Val! Files Searched
ECHO 

REM ::: Open the Log

START notepad.exe %Prog_Dir%files.txt
pause > nul
exit

REM ::: Recursive option for Substitution with CD .. FOR %%a IN ..
REM ::: FOR /R "%Home_Dir%" %%a IN (*.%ext%) DO (


REM ::: Use For Loop to Generate array of File Information, Call extFilter to Sort Desired Files.

:process
CD %Home_Dir%
FOR %%a IN (*.%ext%) DO (
        Set /a Val+=1
        Set name[!val!]=%%~na
        Set EXT[!val!]=%%~xa
        Set location[!val!]=%%~dpa
        CALL :extFilter
)
GOTO :EOF

REM ::: Call Filter by Filetype.
REM ::: Adjust Conditions to suit Needs.


:extFilter
IF "!EXT[%val%]!"==".com" CALL :Filter_com
IF "!EXT[%val%]!"==".dll" CALL :Filter_dll
GOTO :EOF

REM ::: Test for Specific Letter in Specific Position Of filename String, Log if True.

:Filter_dll
Set "testletter=!name[%val%]!"
Set testletter=%testletter:~1,1%
            IF /I "!testletter!"=="i" (
        Set /a Found+=1
        ECHO  Logging File... !location[%Val%]! !Val! Files Searched
        ECHO  Found !Found! Files
        ECHO  Last File Logged: !name[%val%]!!EXT[%val%]!
        ECHO !location[%val%]!!name[%val%]!!EXT[%val%]!>>%Prog_Dir%files.txt
    ) else (
    ECHO  Searching... !location[%Val%]! !Val! Files Searched
)

GOTO :EOF

REM ::: Test Filename for Specific length with use of 'strlen' sub-function, Log if True.

:Filter_com
Call :strlen result !name[%val%]!
            IF !result!==4 (
        Set /a Found+=1
        ECHO  Logging File... !location[%Val%]! !Val! Files Searched
        ECHO  Found !Found! Files
        ECHO  Last File Logged: !name[%val%]!!EXT[%val%]!
        ECHO !location[%val%]!!name[%val%]!!EXT[%val%]!>>%Prog_Dir%files.txt
    ) else (
    ECHO  Searching... !location[%Val%]! !Val! Files Searched
)

GOTO :EOF

REM ::: Sub function using For loop to test a String against itself and Determine length of string.

REM ********* function thanks to Jeb https://stackoverflow.com/users/463115/jeb *****************************
:strlen <resultVar> <stringVar>
set tmp=%~2
If defined tmp (
        set "len=1"
        for %%P in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
            if "!tmp:~%%P,1!" NEQ "" (
                set /a "len+=%%P"
                set "tmp=!tmp:~%%P!"
            )
        )
    ) ELSE (
        set len=0
)
(
    set "%~1=%len%"
    exit /b
)