eventvwr-print.cmd

@echo off
rem Froz 31.01.2020
rem Извлекаем из журнала печати последние события
set EVS=3
set JNL=Microsoft-Windows-PrintService/Operational

rem Проверяем включен ли журнал печати
for /f "tokens=2 delims=: " %%e in ('wevtutil gl %JNL% ^|findstr /c:enabled') do set ENA=%%e
if "%ENA%"=="false" goto enaevent
goto st

:enaevent
echo.
echo Журнал печати %JNL% отключен - включаем...
net session >nul 2>&1
if not %ERRORLEVEL% EQU 0 (
 echo Требуются права администратора.
 echo Запустите этот файл правой кнопкой мыши - "Запуск от имени..."
 echo Или откройте отдельное окно Explorer с повышенными правами...
 echo Выходим.
 pause
 goto:eof
)
rem Включаем журнал PrintService:
wevtutil sl %JNL% /e:true
echo Журнал печати включен, выходим.
echo Чтобы в нём появились записи - нужно сперва что-нибудь отправить на печать.
pause
goto:eof


:st
rem Извлекаем список заданий печати
cls
echo.
echo Последние %EVS% заданий печати:
wevtutil qe %JNL% /rd:true /q:*[System[(EventID=307)]] /f:text /c:%EVS%
echo.
echo Для обновления списка нажмите Enter
set/P EV=или введите кол-во последних заданий печати, или 'q' для выхода:
if -%EV%==- goto st
if -%EV%==-q goto:eof
if %EV% NEQ %EVS% set EVS=%ev%& goto st
goto st