new MM menu

// moves a gui item to any position
// i.e. guiitemmove 0 -5 -15 [ guititle "Hi" ]
guiitemmove = [
    guialign $arg1 [
        guistrut $arg2
        guilist [
            guistrut $arg3
            arg4
        ]
    ]
]

newgui mapmodels [
    local Xn Yn XYn mmid

    Xn   = 7
    Yn   = 4
    XYn  = (* $Xn $Yn)

    guikeeptab 1
    guinoautotab [
        loop "n" (ceil (divf $nummapmodels $XYn)) [
            if $n [ guitab (+ $n 1) ]
            if (= $guitabnum (+ $n 1)) [
                loop "y" $Yn [
                    guilist [
                        loop "x" $Xn [
                            mmid = (+ (* $XYn $n) (+ (* $y $Xn) $x))
                            if (< $mmid $nummapmodels) [
                                guiimage "<mad:.1/.1/.1>packages/textures/razgriz/white.png" $mmid 3 0
                                guiitemmove -1 0.0 -12.0 [ guimodelpreview (mapmodelname $mmid) "mapmodel" [ newent mapmodel @mmid ] 3 0 0 1 ]
                                guiitemmove -1 0.2 -11.3 [ guititle (concatword (? (= $guirolloverimgaction $mmid) "^f2" "^f4") $mmid) ]
                            ] [ guistrut 12 ; guistrut 6 1 ]
                        ]
                    ]
                ]
                guistrut 0.2
                guititle (concatword "^f7" (strreplace $guirolloverpreviewname "/" "^f2/^f7"))
            ]
        ]
    ]
]