age_subj.plt

set terminal pngcairo dashed size 970,600
set output "age-subj.png"
set title "Pontuação por idade por disciplina."
set ylabel "nota normalizada"
set xlabel "idade (anos)"
por = "hist_age_por.txt"
mat = "hist_age_mat.txt"
inf = "hist_age_inf.txt"
atu = "hist_age_atu.txt"
lpor(x) = py0 + pm*x
lmat(x) = my0 + mm*x
linf(x) = iy0 + im*x
latu(x) = ay0 + am*x
fit lpor(x) por using 1:3 via py0, pm
fit lmat(x) mat using 1:3 via my0, mm
fit linf(x) inf using 1:3 via iy0, im
fit latu(x) atu using 1:3 via ay0, am
cpor = "brown"
cmat = "dark-green"
cinf = "blue"
catu = "black"
set label "Português"   at first 17, first 0.75 textcolor rgb cpor
set label "Matemática"  at first 17, first 0.54 textcolor rgb cmat
set label "Informática" at first 17, first 0.43 textcolor rgb cinf
set label "Atualidades" at first 17, first 0.66 textcolor rgb catu
set key off
plot por using 1:3 lt -1 lc rgb cpor with lines, \
     por using 1:3:5 lt -1 lc rgb cpor with yerrorbars, \
     lpor(x) lt 2 lw 3 lc rgb cpor, \
     mat using 1:3 lt -1 lc rgb cmat with lines, \
     mat using 1:3:5 lt -1 lc rgb cmat with yerrorbars, \
     lmat(x) lt 2 lw 3 lc rgb cmat, \
     inf using 1:3 lt -1 lc rgb cinf with lines, \
     inf using 1:3:5 lt -1 lc rgb cinf with yerrorbars, \
     linf(x) lt 2 lw 3 lc rgb cinf, \
     atu using 1:3 lt -1 lc rgb catu with lines, \
     atu using 1:3:5 lt -1 lc rgb catu with yerrorbars, \
     latu(x) lt 2 lw 3 lc rgb catu