/obj/machinery/metal_detector
	name = "metal detector"
	desc = "A advanced metal detector used to detect weapons."
	icon = 'icons/obj/machines/metal_detector.dmi'
	icon_state = "metal_detector"
	plane = ABOVE_HUMAN_PLANE
	layer = ABOVE_HUMAN_LAYER
	anchored = 1

	var/list/banned_objects=list(/obj/item/weapon/gun,
								/obj/item/weapon/material,
								/obj/item/weapon/melee,
								/obj/item/device/transfer_valve,
								/obj/item/weapon/grenade/,
								/obj/item/ammo_casing/,
								/obj/item/ammo_magazine
								)

	req_access = list(access_security)

/obj/machinery/metal_detector/New()
	..()
	component_parts = list()
	component_parts += new /obj/item/weapon/circuitboard/metal_detector(src)
	component_parts += new /obj/item/weapon/stock_parts/scanning_module(src)
	component_parts += new /obj/item/weapon/stock_parts/scanning_module(src)
	component_parts += new /obj/item/weapon/stock_parts/scanning_module(src)
	component_parts += new /obj/item/weapon/stock_parts/console_screen(src)
	RefreshParts()

/obj/machinery/metal_detector/attackby(obj/item/W, mob/usr)

	if(default_deconstruction_screwdriver(usr, W))
		return

	if(default_deconstruction_crowbar(usr, W))
		return

/obj/machinery/metal_detector/Crossed(var/atom/A)
	if(istype(A, /mob/living))
		var/mob/living/M = A
		if(src.allowed(M))
			return //Faction-members with security access are immune.

	check_items(recursive_content_check(src.loc, sight_check = FALSE, include_mobs = FALSE, recursion_limit = 4))
	..()

/obj/machinery/metal_detector/proc/check_items(var/list/L)
	for(var/O in banned_objects)
		for(var/A in L)
			if(istype(A, O))
				flick("metal_detector_anim",src)
				visible_message("<span class='danger'>\The [src] sends off an alarm!</span>")
				playsound(src, 'sound/ambience/alarm4.ogg', 60, 1)
				return