/*
	Script by: Bullet
	Map by: Bullet
	Mission Base: Last team standing
	Mission Type: Last team standing
	Mission Type ID: 5
*/
//==============================================================================
// Includes
//==============================================================================
#include <a_samp>
#include <crashdetect>
#include <float>

#include "..\filterscripts\MM\stuff\defines"
#include "..\filterscripts\MM\stuff\serverkeymsg"

//==============================================================================
// Defines
//==============================================================================

#define MISSION_NAME 		"Fray in the Hood"
#define Health 				25.0
#define TEAM_DEFEND_NAME 	"Groves"
#define TEAM_ATTACK_NAME 	"Ballas"
#define MAX_MAP_OBJECTS 	9
#define VEHICLE_HEALTH 		0
#define CLASS_POSTION		2467.9666,-1659.0470,13.3114
#define CLASS_CAMERA		2464.6279,-1658.4977,13.2959
#define CLASS_FACING_AGNLE	79.5403
#define START_TIME			20

//==============================================================================
// Per mission functions
//============================================================================== 			20

enum ped_enum
{
	TeamID,
	Skin,
	Float:SpawnX,
	Float:SpawnY,
	Float:SpawnZ,
	Float:SpawnAngle,
	SpawnInterior,
	VirtualWorld,
	Weapon1,
	Ammo1,
	Weapon2,
	Ammo2,
	Weapon3,
	Ammo3,
};

new const PedInfo[][ped_enum] = {
	{TEAM_ATTACK,103,2467.7278,-1658.5833,13.3005,254.8167,0,0,0,0,WEAPON_BAT,0,0,0},
	{TEAM_DEFEND,105, 2511.9343,-1671.3613,13.4689,79.0585,0,0,0,0,WEAPON_BAT,0,0,0}
};

#if MAX_MAP_OBJECTS != 0
new Object[MAX_MAP_OBJECTS];

CreateMap()
{
Object[0] = CreateObject(8661,2463.9038100,-1653.3634000,12.4572000,90.0000000,90.0000000,180.0000000); //
Object[1] = CreateObject(8661,2473.2016600,-1690.7700200,12.4572000,90.0000000,90.0000000,208.0199900); //
Object[2] = CreateObject(8661,2491.9177200,-1688.2888200,12.4572000,90.0000000,90.0000000,270.2396500); //
Object[3] = CreateObject(8661,2518.7148400,-1681.7840600,12.4572000,90.0000000,90.0000000,289.2597700); //
Object[4] = CreateObject(8661,2515.4755900,-1673.9218800,12.4572000,90.0000000,90.0000000,319.0795900); //
Object[5] = CreateObject(8661,2513.4118700,-1663.0034200,12.4572000,90.0000000,90.0000000,372.2391100); //
Object[6] = CreateObject(8661,2505.4245600,-1649.1261000,12.4572000,90.0000000,90.0000000,419.2788700); //
Object[7] = CreateObject(8661,2485.9069800,-1649.4702100,12.4572000,90.0000000,90.0000000,450.1786500); //
Object[8] = CreateObject(8661,2483.1350100,-1649.4552000,12.4572000,90.0000000,90.0000000,450.1786500); //
}
#endif

//==============================================================================
// Basic vars
//==============================================================================

new bool:MissionStarted;
new bool:ObjectiveStarted;
new bool:MissionCancelled;

native IsValidVehicle(vehicleid);

enum teamdata
{
	Kills,
	Name[32],
	Members
};

enum playerdata
{
	UserName[MAX_PLAYER_NAME],
	bool:TeamChosen,
	TeamSelection,
	PlayerClassID,
	Counted,
	AllowedToSpawn
};

new Team[2][teamdata];
new PlayerMissionInfo[MAX_PLAYERS][playerdata];

//==============================================================================
// Basic script
//==============================================================================

main()
{
	print("----------------------------------");
	print(" Mission: "MISSION_NAME" started.");
	print("----------------------------------\n");
}

public OnGameModeInit()
{
	MissionStarted= true;

	format(Team[TEAM_DEFEND][Name],32,"%s",TEAM_DEFEND_NAME);
	format(Team[TEAM_ATTACK][Name],32,"%s",TEAM_ATTACK_NAME);

	if(CallRemoteFunction("GetCurrentMissionCJWalk","")) UsePlayerPedAnims();

	#if MAX_MAP_OBJECTS != 0
	CreateMap();
	#endif

	for(new i=0; i<sizeof(PedInfo); i++)AddPlayerClassEx(PedInfo[i][TeamID],PedInfo[i][Skin],PedInfo[i][SpawnX],PedInfo[i][SpawnY],PedInfo[i][SpawnZ],PedInfo[i][SpawnAngle],0,0,0,0,0,0);

	for(new i=0; i<MAX_VEHICLES; i++) if(IsValidVehicle(i)) SetVehicleHealth(i,VEHICLE_HEALTH);
	for(new i=0; i<MAX_PLAYERS; i++) PlayerMissionInfo[i][TeamSelection]= NO_TEAM;

	SetTimer("StartMissionFunc",3000,false);
	return 1;
}

FUNCTION StartMissionFunc()
{
	CallRemoteFunction("StartMission","");
	SetTimer("CloseSpawns",1000*(START_TIME-3),false);
	ObjectiveStarted= true;
	return 1;
}

FUNCTION CloseSpawns()
{
	PlaySoundForAll(1057);
	if(Team[TEAM_DEFEND][Members] >= 1 && Team[TEAM_ATTACK][Members] >= 1)
	{
		GameTextForAll("~r~START THE BLOOD WAR!",1000,3);
		ObjectiveStarted= true;
		ToggleControllable(true);
		SendClientMessageToAll(COLOR_SERVER,""SERVER_KEY_MSG" The last team standing deathmatch has started. KILL THE OTHER TEAM!");
		CallRemoteFunction("ShowInfoBox", "iisi", -1, -1,"The last team standing deathmatch has started. KILL THE OTHER TEAM!",0);
	}
	else CallRemoteFunction("EndMission","");
}

public OnGameModeExit()
{
	#if MAX_MAP_OBJECTS != 0
		for(new i=0;i<MAX_MAP_OBJECTS;i++) DestroyObject(Object[i]);
	#endif
	return 1;
}

public OnPlayerDisconnect(playerid)
{
	if(PlayerMissionInfo[playerid][TeamSelection] != NO_TEAM && PlayerMissionInfo[playerid][Counted])
	{
	    Team[PlayerMissionInfo[playerid][TeamSelection]][Members] --;
		CallRemoteFunction("TdmUpdate","sssdd","Players Alive",Team[TEAM_DEFEND][Name],Team[TEAM_ATTACK][Name],Team[TEAM_DEFEND][Members],Team[TEAM_ATTACK][Members]);
		if(Team[PlayerMissionInfo[playerid][TeamSelection]][Members] == 0 && ObjectiveStarted) CallRemoteFunction("EndMission","");
	}
	return 1;
}

public OnPlayerRequestClass(playerid,classid)
{
	SetPlayerPos(playerid,CLASS_POSTION);
    SetPlayerCameraPos(playerid,CLASS_CAMERA);
    SetPlayerCameraLookAt(playerid,CLASS_POSTION);
    SetPlayerFacingAngle(playerid,CLASS_FACING_AGNLE);

	CallRemoteFunction("TdmHide","i",playerid);
	CallRemoteFunction("ShowClassSelection","iisiii",playerid, PedInfo[classid][TeamID],Team[PedInfo[classid][TeamID]][Name], PedInfo[classid][Weapon1], PedInfo[classid][Weapon2], PedInfo[classid][Weapon3]);

	if(PlayerMissionInfo[playerid][Counted] && PlayerMissionInfo[playerid][TeamSelection] != NO_TEAM)
	{
		Team[PlayerMissionInfo[playerid][TeamSelection]][Members]--;
	    PlayerMissionInfo[playerid][Counted] = false;
		CallRemoteFunction("TdmUpdate","sssdd","Players Alive",Team[TEAM_DEFEND][Name],Team[TEAM_ATTACK][Name],Team[TEAM_DEFEND][Members],Team[TEAM_ATTACK][Members]);
	}

	PlayerMissionInfo[playerid][TeamSelection] = PedInfo[classid][TeamID];
	PlayerMissionInfo[playerid][PlayerClassID]=classid;

	return 1;
}

public OnPlayerRequestSpawn(playerid)
{
	new opp_team = (PlayerMissionInfo[playerid][TeamSelection] == 1)? 0:1;
	if(Team[PlayerMissionInfo[playerid][TeamSelection]][Members] > Team[opp_team][Members])
	{
		CallRemoteFunction("ShowInfoBox", "iisi", playerid, -1,"This Team is full, choose another!",0);
	    return 0;
	}
	return 1;
}

public OnPlayerSpawn(playerid)
{
	CallRemoteFunction("TdmShow","i",playerid);
	CallRemoteFunction("TdmUpdate","sssdd","Players Alive",Team[TEAM_DEFEND][Name],Team[TEAM_ATTACK][Name],Team[TEAM_DEFEND][Members],Team[TEAM_ATTACK][Members]);
	new string[124];
	if(CallRemoteFunction("GetSpectateStatus","d",playerid)) return CallRemoteFunction("SpecOffAdmin","d",playerid);
	if(!CallRemoteFunction("GetJailedStatus","d",playerid))
	{
		SetPlayerPos(playerid,PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][SpawnX],PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][SpawnY],PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][SpawnZ]);
		SetPlayerFacingAngle(playerid,PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][SpawnAngle]);
		SetPlayerInterior(playerid,PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][SpawnInterior]);
		CallRemoteFunction("GivePlayerWeaponEx","ddd",playerid,PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][Weapon1],PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][Ammo1]);
		CallRemoteFunction("GivePlayerWeaponEx","ddd",playerid,PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][Weapon2],PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][Ammo2]);
		CallRemoteFunction("GivePlayerWeaponEx","ddd",playerid,PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][Weapon3],PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][Ammo3]);

		if(ObjectiveStarted && !PlayerMissionInfo[playerid][AllowedToSpawn])
		{
			SetPlayerVirtualWorld(playerid,2);
			SetPlayerInterior(playerid,PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][SpawnInterior]);
			SetPlayerColor(playerid,COLOR_GREY);
			CallRemoteFunction("OnPlayerMissionComplete","d",playerid);
		}
		else
		{
			if(!ObjectiveStarted) TogglePlayerControllable(playerid,false);
			SetPlayerVirtualWorld(playerid,PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][VirtualWorld]);
			if(!PlayerMissionInfo[playerid][Counted])
			{
				Team[PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][TeamID]][Members]++;
				PlayerMissionInfo[playerid][Counted]= true;
			}

			CallRemoteFunction("updateLTS","dd",Team[TEAM_DEFEND][Members],Team[TEAM_ATTACK][Members]);
			PlayerMissionInfo[playerid][TeamChosen] = true;
			new opp_team = (PlayerMissionInfo[playerid][TeamSelection] == 1)? 0:1;
			format(string,sizeof(string),"You have chosen team %s, your mission is to kill %s.",Team[PlayerMissionInfo[playerid][TeamSelection]][Name],Team[opp_team][Name]);
			CallRemoteFunction("ShowInfoBox", "iisi", playerid, -1,string,0);
			format(string,sizeof(string),"~r~~h~Eliminate ~w~%s.",Team[opp_team][Name]);
			CallRemoteFunction("ShowInfoText", "iisi", playerid, -1,string,0);
			PlayerMissionInfo[playerid][AllowedToSpawn]= false;
			SetPlayerTeam(playerid,PlayerMissionInfo[playerid][TeamSelection]);
			if(PlayerMissionInfo[playerid][TeamSelection] == TEAM_ATTACK) SetPlayerColor(playerid,COLOR_TEAM_ATTACK);
			else SetPlayerColor(playerid,COLOR_TEAM_DEFEND);
			CallRemoteFunction("UpdateAliveState","ii",playerid,1);
		}
	}


	SetPlayerHealth(playerid,Health);
	CallRemoteFunction("TdmUpdate","sssdd","Players Alive",Team[TEAM_DEFEND][Name],Team[TEAM_ATTACK][Name],Team[TEAM_DEFEND][Members],Team[TEAM_ATTACK][Members]);
	return 1;
}

public OnPlayerDeath(playerid, killerid, reason)
{
	if(!MissionStarted)
	{
		PlayerMissionInfo[playerid][AllowedToSpawn]= true;
		return 1;
	}
	if(killerid != INVALID_PLAYER_ID && PlayerMissionInfo[killerid][TeamSelection] != NO_TEAM)
	{
	    Team[PlayerMissionInfo[killerid][TeamSelection]][Kills]++;
		SetPlayerScore(killerid,GetPlayerScore(killerid)+1);
	}
	if(PlayerMissionInfo[playerid][Counted] && PlayerMissionInfo[playerid][TeamSelection] != NO_TEAM)
	{
		Team[PlayerMissionInfo[playerid][TeamSelection]][Members]--;
		PlayerMissionInfo[playerid][Counted]= false;
		if(Team[PlayerMissionInfo[playerid][TeamSelection]][Members] == 0) CallRemoteFunction("EndMission","");
	}
	CallRemoteFunction("UpdateAliveState","ii",playerid,0);
	CallRemoteFunction("TdmUpdate","sssdd","Players Alive",Team[TEAM_DEFEND][Name],Team[TEAM_ATTACK][Name],Team[TEAM_DEFEND][Members],Team[TEAM_ATTACK][Members]);
	return 1;
}

FUNCTION EndTheMission()
{
	if(!MissionStarted) return 1;
	MissionStarted= false;
	if(!MissionCancelled && !ObjectiveStarted)
	{
		new string[128];
		new amount= 10000;
		new winning_team;
		if(Team[TEAM_DEFEND][Members] == Team[TEAM_ATTACK][Members]) { winning_team = 2; }
		else if(Team[TEAM_DEFEND][Members] > Team[TEAM_ATTACK][Members]) { winning_team = 0; }
		else { winning_team = 1; }

		if(winning_team != 2 && ObjectiveStarted)
		{
			amount +=Team[winning_team][Kills]*100;
			format(string,sizeof(string),""SERVER_KEY_MSG" %s has won the last team standing deathmatch! Reward: $%d",Team[winning_team][Name],amount);
			CallRemoteFunction("IRC_SendMessage","ss",string,IRC_SERVER_COLOR);
			SendClientMessageToAll(COLOR_SERVER,string);
			for(new i=0,j=GetPlayerPoolSize(); i <= j; i++)
			{
				if(PlayerMissionInfo[i][TeamSelection] == winning_team && PlayerMissionInfo[i][TeamChosen])
				{
					PlayerPlaySound(i,3200,0,0,0);
					CallRemoteFunction("GivePlayerCash","ii",i,amount);
					CallRemoteFunction("PlayerMissionStats","dd",i,0);
				}
				if(PlayerMissionInfo[i][TeamSelection] != winning_team && PlayerMissionInfo[i][TeamChosen])
				{
					PlayerPlaySound(i,17004,0,0,0);
					GameTextForPlayer(i,"~R~MISSION FAILED~w~!",3000,3);
					CallRemoteFunction("PlayerMissionStats","dd",i,1);
				}
			}
		}
		else
		{
			PlaySoundForAll(1058);
			format(string,sizeof(string),""SERVER_KEY_MSG" IT'S A DRAW! No team has won the last team standing deathmatch.");
			SendClientMessageToAll(COLOR_SERVER,string);
			CallRemoteFunction("IRC_SendMessage","ss",string,IRC_SERVER_COLOR);
			for(new i=0,j=GetPlayerPoolSize(); i <= j; i++)
			{
				if(PlayerMissionInfo[i][TeamChosen])
				{
					CallRemoteFunction("PlayerMissionStats","dd",i,2);
				}
			}
		}
	}
	else
	{
		PlaySoundForAll(1058);
		SendClientMessageToAll(COLOR_SERVER,""SERVER_KEY_MSG" The mission has been cancelled.");
		CallRemoteFunction("IRC_SendMessage","ss",""SERVER_KEY_MSG" The mission has been cancelled.",IRC_SERVER_COLOR);
		CallRemoteFunction("ShowInfoBox", "iisi", -1, -1,"The mission has been cancelled.",0);
		GameTextForAll("~R~MISSION CANCELLED~w~!",3000,3);
	}

	return 1;
}

//==============================================================================
// Mission functions
//==============================================================================

PlaySoundForAll(sound)
{
	for (new i=0,j=GetPlayerPoolSize(); i <=j ; i++)
    {
    	if(IsPlayerConnected(i)) PlayerPlaySound(i,sound,0,0,0);
    }
}


ToggleControllable(control)
{
	for(new i=0,j=GetPlayerPoolSize(); i<=j; i++)
	{
		if(IsPlayerConnected(i))
		{
			if(CallRemoteFunction("GetAliveState","i",i)) TogglePlayerControllable(i,control);
		}
	}
	return 1;
}

//==============================================================================
// Important functions required
//==============================================================================

FUNCTION CancelTheMission()
{
	MissionCancelled= true;
	return 1;
}

FUNCTION OnPlayerNameRecieve(playerid,name[])
{
	format(PlayerMissionInfo[playerid][UserName],MAX_PLAYER_NAME,"%s",name);
	return 1;
}

FUNCTION MissionObjectiveStarted() return ObjectiveStarted;

FUNCTION OnPlayerRespawned(playerid)
{
	if(PlayerMissionInfo[playerid][Counted])
	{
		Team[PedInfo[PlayerMissionInfo[playerid][PlayerClassID]][TeamID]][Members]--;
		PlayerMissionInfo[playerid][Counted]= false;
	}
	PlayerMissionInfo[playerid][AllowedToSpawn]= true;
	return 1;
}