player-interact.zs

import crafttweaker.event.PlayerInteractEvent;
import crafttweaker.event.PlayerInteractBlockEvent;
import crafttweaker.event.PlayerInteractEntityEvent;
import crafttweaker.event.EntityLivingUseItemEvent.Start;
import crafttweaker.entity.IEntityLiving;
import crafttweaker.entity.IEntityEquipmentSlot as slots;
import crafttweaker.server.IServer;
import crafttweaker.block.IBlock;
import crafttweaker.entity.IEntity;
import crafttweaker.world.IFacing;
import crafttweaker.command.ICommandSender;
import mods.ctutils.utils.Math;
import scripts.player_interact_statics as stats;


events.onPlayerInteractEntity(function(event as PlayerInteractEntityEvent)
{
  if ((event.player.currentItem.definition.id == <minecraft:flint_and_steel>.definition.id) && (event.target instanceof IEntityLiving))
  {
    event.target.setFire(3);
    val unbreakingLvl = stats.getUnbreakingLevel(event.player.currentItem.enchantments);
    print("unbreakingLvl: "~unbreakingLvl);
    print("break chance: "~(1/(unbreakingLvl + 1)));
    if(Math.random() < 1/(unbreakingLvl + 1))
    {
      print("damage: "~event.player.currentItem.damage);
      print("maxDamage: "~event.player.currentItem.maxDamage);
      if(event.player.currentItem.damage < event.player.currentItem.maxDamage)
      {
        print("damaging flint+steel");
        event.player.currentItem.damageItem(1, event.player);
        print("new damage: "~event.player.currentItem.damage);
      }
      else
      {
        print("destroying flint+steel");
        event.player.setItemToSlot(slots.mainHand(), null);
      }
    }
  }
});