import minetweaker.item.IItemStack;

print("---PRINT OUT--- DRPMedieval");
##Mods Requirement
# - NULL

#------------------------------------------------------------------------------------------------------------------------------------------------------------#

val listDRPMFirewood = [<drpmedieval:Firewood:0>, <drpmedieval:Firewood:1>, <drpmedieval:Firewood:2>, <drpmedieval:Firewood:3>, <drpmedieval:Firewood:4>, <drpmedieval:Firewood:5>] as IItemStack[];
val listMCLog        = [<minecraft:log:0>       , <minecraft:log:1>       , <minecraft:log:2>       , <minecraft:log:3>       , <minecraft:log2:1>      , <minecraft:log2:0>]       as IItemStack[];
val listMCPlank      = [<minecraft:planks:0>    , <minecraft:planks:1>    , <minecraft:planks:2>    , <minecraft:planks:3>    , <minecraft:planks:5>    , <minecraft:planks:4>]     as IItemStack[];
val listDRPMPlank    = [<drpmedieval:Plank:0>   , <drpmedieval:Plank:1>   , <drpmedieval:Plank:2>   , <drpmedieval:Plank:3>   , <drpmedieval:Plank:4>   , <drpmedieval:Plank:5>]    as IItemStack[];
oreDict.vanillaAxe.add(<minecraft:wooden_axe:*>);
oreDict.vanillaAxe.add(<minecraft:stone_axe:*>);
oreDict.vanillaAxe.add(<minecraft:iron_axe:*>);
oreDict.vanillaAxe.add(<minecraft:golden_axe:*>);
oreDict.vanillaAxe.add(<minecraft:diamond_axe:*>);
for i, theDRPMLog in listDRPMFirewood {
  var theMCLog = listMCLog[i];
  var theMCPlank = listMCPlank[i];
  var theDRPMPlank = listDRPMPlank[i];
  recipes.addShapeless(theDRPMLog * 2, [<ore:vanillaAxe>.transformDamage(), theMCLog]);
  recipes.addShapeless(theDRPMPlank * 4, [<ore:vanillaAxe>.transformDamage(), theDRPMLog]);
  recipes.addShapeless(theMCLog, [theDRPMLog , theDRPMLog]);
  recipes.addShapeless(theMCPlank, [theDRPMPlank]);
}