Stock Quote Script (Financial Data) v2.3

;Stock Quote Script (Financial Stock Data) v2.3
;Made by nick1
;View online and report bugs at http://hawkee.com/snippet/9578
;Last edit March 17, 2015

;DISCLAIMER: Data and information provided may be delayed.
;Data and information is provided for informational purposes only, and is not intended for trading purposes. - Currency in USD
;NOTE: API is deprecated and unofficial, see http://tinyurl.com/mircstock for column options

alias -l stockVersion {
  return v2.3
}
alias stock {
  var %ticks $ticks
  tokenize 32 $strip($1-)
  if ($1) {
    if ($1 == eurusd) { var %ticker EURUSD=X }
    elseif ((*s&p* iswm $1) || (*SP500* iswm $1)) { var %ticker ^GSPC }
    elseif ($1 == nasdaq) { var %ticker ^IXIC }
    elseif ($1 == nyse) { var %ticker ^NYA }
    else {
      var %ticker $1
    }
    set $+(%,stock.,%ticks,.msgtype) echo -a
    set $+(%,stock.,%ticks,.ticker) $replace(%ticker,^,$(%255E,0))
    sockopen $+(stock.,%ticks) query.yahooapis.com 80
  }
  elseif ($1 == $null) {
    echo -act info 4Incorrect Syntax - Use10 /stock <ticker symbol>
  }
}

on *:input:*:{
  $iif($istok(%nolinks,$active,44),return,noop)
  $iif($istok(%youtubefetch,$active,44),return,noop)
  if (($remove($1,$left($strip($1),1)) == stock) || ($remove($1,$left($strip($1),1)) == stocks) || ($remove($1,$left($strip($1),1)) == stockquote) || ($remove($1,$left($strip($1),1)) == price) || ($remove($1,$left($strip($1),1)) == p) || ($remove($1,$left($strip($1),1)) == ystock)) {
    if ($2) {
      if ($2 == eurusd) { var %ticker EURUSD=X }
      elseif ($2 == S&P500) || ($2-3 == s&p 500) { var %ticker ^GSPC }
      elseif ($2 == nasdaq) { var %ticker ^IXIC }
      elseif ($2 == nyse) { var %ticker ^NYA }
      else {
        var %ticker $2
      }
      set $+(%,stock.,%ticks,.msgtype) $iif($chan,$iif($left($1,1) == @,msg $active,echo -a),msg $active)
      set $+(%,stock.,%ticks,.ticker) $replace(%ticker,^,$(%255E,0))
      sockopen $+(stock.,%ticks) query.yahooapis.com 80
    }
    elseif ($2 == $null) {
      echo -a 4Incorrect Syntax - Use10 $1 <ticker symbol>
    }
  }
}


on $*:text:/^[!@](stock|stocks|stockquote|price|p|ystock)(\s|$)/Si:#:{
  $iif($istok(%nolinks,$nick,44),return,noop)
  $iif($istok(%youtubefetch,$chan,44),return,noop)
  if ($($+(%,botflood.,$nick),2)) {
    if ($($+(%,botflood.,$nick),2) >= 300) { ignore -u60 $address($nick,0) | msg $chan $+($nick,$chr(44)) You Have Been Put On Ignore For 60secs For Abusing The Bot. | halt }
    elseif ($($+(%,botflood.,$nick),2) >= 200) { msg $chan $+($nick,$chr(44)) Please Do Not Abuse The Bot. | inc -z $+(%,botflood.,$nick) 20 | halt }
    else { inc -z $+(%,botflood.,$nick) 25 }
  }
  else { inc -z $+(%,botflood.,$nick) 25 }
  var %ticks $ticks
  tokenize 32 $strip($1-)
  if ($2) {
    if ($2 == eurusd) { var %ticker EURUSD=X }
    elseif ($2 == S&P500) || ($2-3 == s&p 500) { var %ticker ^GSPC }
    elseif ($2 == nasdaq) { var %ticker ^IXIC }
    elseif ($2 == nyse) { var %ticker ^NYA }
    else {
      var %ticker $2
    }
    set $+(%,stock.,%ticks,.msgtype) $iif($chan,$iif($left($1,1) == @,msg $chan,notice $nick),msg $nick)
    set $+(%,stock.,%ticks,.ticker) $replace(%ticker,^,$(%255E,0))
    sockopen $+(stock.,%ticks) query.yahooapis.com 80
  }
  elseif ($2 == $null) {
    notice $nick 4Incorrect Syntax - Use10 $1 <ticker symbol>
  }
}

on *:sockopen:stock.*: {
  var %sw sockwrite -nt $sockname
  var %enc1 $(select%20*%20from%20csv%20where%20url%3D'http%3A%2F%2Fdownload.finance.yahoo.com%2Fd%2Fquotes.csv%3Fs%3D,0)
  var %enc2 $(%26f%3D,0)
  var %enc3 $(%26e%3D.csv'%20and%20columns%3D',0)
  var %options e1snd1t1l1c6p2j1c8r
  var %columns Error,symbol,name,date,time,price,change,percentChange,MarketCap,AfterChange,PERatio
  var %columns $replace(%columns,$chr(44),$(%2C,0))
  %sw GET $+(/v1/public/yql?q=,%enc1,$($+(%,$sockname,.ticker),2),%enc2,%options,%enc3,%columns,'&diagnostics=true) HTTP/1.1
  %sw Host: query.yahooapis.com
  %sw $crlf
}
alias -l months {
  return January,February,March,April,May,June,July,August,September,October,November,December
}

on *:SOCKREAD:stock.*: {
  if ($sockerr) { echo -a SOCKET ERROR: $sockerr | halt }
  var %ticks $remove($sockname,stock.)
  var %url $+(http://finance.yahoo.com/q?s=,$($+(%,stock.,%ticks,.ticker),2))
  sockread &t
  if ((*400 bad request* iswm $bvar(&t,1-).text) || (*column mismatch* iswm $bvar(&t,1-).text)) {
    $($+(%,stock.,%ticks,.msgtype),2) $+(7,$($+(%,stock.,%ticks,.ticker),2),) 04This symbol could not be found. $&
      Please try again or search for it at12 %url
    unset $+(%,stock.,$remove($sockname,stock.),*)
    sockclose $sockname
  }
  var %pos $bfind(&t,1,<row>)
  var %pos2 $bfind(&t,%pos,</row>)
  if (%pos != 0) {
    set $+(%,stock.,%ticks,.xml) $bvar(&t,$+($calc(%pos + 5),-,$calc(%pos2 - 1))).text
    if ($stockparser(%ticks,name) == N/A) {
      $($+(%,stock.,%ticks,.msgtype),2) $+(7,$($+(%,stock.,%ticks,.ticker),2),) 04This symbol could not be found. $&
        Please try again or search for it at12 %url
      unset $+(%,stock.,$remove($sockname,stock.),*)
      sockclose $sockname
    }
    else {
      var %colorcode $iif($left($stockparser(%ticks,percentchange),1) == +,03,04)
      var %month $gettok($months,$gettok($stockparser(%ticks,date),1,47),44)
      var %ascdate $replace($+(%month,/,$gettok($stockparser(%ticks,date),2-,47)) $stockparser(%ticks,time),/,$chr(32))
      var %timestamp $duration($calc($gmt - $calc($ctime(%ascdate) + $timezone)),2) ago
      var %timestamp $iif(*-* iswm %timestamp,now,%timestamp)
      $($+(%,stock.,%ticks,.msgtype),2) $+(7,$stockparser(%ticks,symbol)) $&
        $+(,$openparens,07,$replace($stockparser(%ticks,name),&amp;,&,&#39;,'),$closeparens) $&
        10Last:04 $stockparser(%ticks,price) $+(,$openparens,04,%timestamp,$closeparens) $&
        $+(10Change:,%colorcode) $stockparser(%ticks,change) $&
        $+($openparens,%colorcode,$stockparser(%ticks,percentchange),$closeparens) $&
        10Mkt Cap:3 $stockparser(%ticks,marketcap) $&
        10Link:12 %url
      unset $+(%,stock.,$remove($sockname,stock.),*)
      sockclose $sockname
    }
  }
}

alias -l openparens { return $+(01,$chr(40)) }

alias -l closeparens { return $+(01,$chr(41)) }

alias -l stockParser {
  ;Syntax $stockparser(ticks,DATA_TYPE)
  ;Options for DATA_TYPE are {error,symbol,name,date,time,price,change,percentChange,MarketCap,PERatio}
  var %xml $($+(%,stock.,$1,.xml),2)
  return $remove($wildtok(%xml,* $+ $2 $+ *,1,60),>,$2)
}

on *:start: .timerStockUpdate 1 60 StockUpdate

alias stockUpdate {
  echo -atc info 12[04Stock Script12] Checking for updates...
  sockopen stockUpdate hawkee.com 80
}

on *:sockopen:stockUpdate: {
  sockwrite -nt $sockname GET /snippet/9578/ HTTP/1.1
  sockwrite -nt $sockname Host: hawkee.com
  sockwrite -nt $sockname $crlf
}

on *:SOCKREAD:stockUpdate: {
  if ($sockerr) { echo -a SOCKET ERROR: $sockerr $sockname $asctime | halt }
  sockread %sockreader
  if (*<title>* iswm %sockreader) {
    tokenize 32 %sockreader
    echo -atc info 12[04Stock Script12] Current: $StockVersion Latest: $7 Status: $iif($StockVersion == $7,Up to date,Please update at www.hawkee.com/snippet/9578/)
    unset %sockreader
    sockclose $sockname
  }
}