pkgname=afancontrol
pkgver=3.1.0
pkgrel=1
pkgdesc="Advanced Fan Control program, which controls PWM fans according to the current temperatures of the system components."
arch=('any')
url="https://github.com/KostyaEsmukov/afancontrol"
license=('MIT')
depends=('python-click')
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
optdepends=('lm_sensors: to use the motherboard-based sensors and PWM fans'
            'freeipmi: readonly PWM fans'
            'hddtemp: for measuring HDD/SSD temperatures'
            'python-pyserial: Arduino support'
            'python-prometheus_client: Prometheus support')
backup=("etc/$pkgname/$pkgname.conf")
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
sha256sums=('c00b8ac736bd6b4d79a2e3e594aad3e4065f4a7123b0b73991b0722bfcf629d3')

prepare() {
  cd "$pkgname-$pkgver"
  sed -i 's/etc\/systemd/lib\/systemd/g' setup.py
  sed -i 's/usr\/local/usr/g' "pkg/$pkgname.conf"
}

build() {
  cd "$pkgname-$pkgver"
  python -m build --wheel --no-isolation
}

package() {
  cd "$pkgname-$pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl

  install -d "$pkgdir/etc"
  mv "$pkgdir/usr/etc/afancontrol" "$pkgdir/etc"
  rmdir "$pkgdir/usr/etc"

  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}