Mode Thanker for Koragg v2.0

;taken from http://www.ladysclub.net/index.php/downloads/download/2-mirc-scripte/1-g-script.html

ON *:START: { init }
ON *:LOAD: { init }

ON *:EXIT: {
  if ($hget(thx)) { hsave thx $qt(settings.hsh) }
}

dialog -l autothx {
  title "Mode Thanker - (/mt)"
  size -1 -1 172 266
  option dbu
  box "Voice", 1, 3 3 166 21
  edit "", 2, 5 11 162 10, autohs
  box "Halfop", 3, 3 51 166 21
  edit "", 4, 5 59 162 10, autohs
  box "Op", 5, 3 99 166 21
  edit "", 6, 5 107 162 10, autohs
  box "", 7, 3 242 166 21
  check "Activate Mode Thanker", 8, 43 250 85 10
  ;box "", 9, 1 -2 170 267
  box "Devoice", 10, 3 25 166 21
  edit "", 11, 5 33 162 10, autohs
  box "Dehalfop", 12, 3 73 166 21
  edit "", 13, 5 81 162 10, autohs
  edit "", 14, 5 128 162 10, autohs
  box "Deop", 15, 3 120 166 21
  box "Deprotect", 16, 3 167 166 21
  box "Protect", 17, 3 146 166 21
  edit "", 18, 5 154 162 10, autohs
  edit "", 19, 5 175 162 10, autohs
  box "Owner", 20, 3 193 166 21
  box "Deowner", 21, 3 214 166 21
  edit "", 22, 5 201 162 10, autohs
  edit "", 23, 5 222 162 10, autohs
}

ON *:DIALOG:autothx:*:*: {
  if ($devent == init) {
    if ($hget(thx,akt)) { did -c $dname 8 }
    if ($hget(thx,voice)) { did -a $dname 2 $v1 }
    if ($hget(thx,devoice)) { did -a $dname 11 $v1 }
    if ($hget(thx,halfop)) { did -a $dname 4 $v1 }
    if ($hget(thx,dehalfop)) { did -a $dname 13 $v1 }
    if ($hget(thx,op)) { did -a $dname 6 $v1 }
    if ($hget(thx,deop)) { did -a $dname 14 $v1 }
    if ($hget(thx,prot)) { did -a $dname 18 $v1 }
    if ($hget(thx,deprot)) { did -a $dname 19 $v1 }
    if ($hget(thx,own)) { did -a $dname 22 $v1 }
    if ($hget(thx,deown)) { did -a $dname 23 $v1 }
  }

  if ($devent == edit) {
    if ($did == 2) { hadd -m thx voice $did($did).text }
    if ($did == 11) { hadd -m thx devoice $did($did).text }
    if ($did == 4) { hadd -m thx halfop $did($did).text }
    if ($did == 13) { hadd -m thx dehalfop $did($did).text }
    if ($did == 6) { hadd -m thx op $did($did).text }
    if ($did == 14) { hadd -m thx deop $did($did).text }
    if ($did == 18) { hadd -m thx prot $did($did).text }
    if ($did == 19) { hadd -m thx deprot $did($did).text }
    if ($did == 22) { hadd -m thx own $did($did).text }
    if ($did == 23) { hadd -m thx deown $did($did).text }
  }

  if ($devent == sclick) && ($did = 8) { hadd -m thx akt $did($did).state }
  if ($devent == close) { hsave thx $qt(settings.hsh) }
}

ON !*:RAWMODE:#: {
  tokenize 32 $strip($1-)

  var %spam = $evalnext($+(%,modethankercheck,.,$nick))

  if (%spam) { return }

  if ($hget(thx,akt)) && ($me isin $2-) {
    if ($right($nick,4) == Serv) || ($nick == Global) || (help isin $chan) || ($chr(46) isin $nick) { return }

    var %not_nicks = Autobot X Q
    if ($istok(%not_nicks,$nick,32)) { return }

    var %voice = $hget(thx,voice)
    var %devoice = $hget(thx,devoice)
    var %halfop = $hget(thx,halfop)
    var %dehalfop = $hget(thx,dehalfop)
    var %op = $hget(thx,op)
    var %deop = $hget(thx,deop)
    var %protect = $hget(thx,prot)
    var %deprotect = $hget(thx,deprot)
    var %owner = $hget(thx,own)
    var %deowner = $hget(thx,deown)

    if (*+* iswm $1) {
      if (!%voice) && (!%halfop) && (!%op) && (!%protect) && (!%owner) { return }

      if (*q* iswmcs $1) && (%owner) { awaynoticesystem $nick $evalnext(%owner) }
      if (*a* iswmcs $1) && (%protect) { awaynoticesystem $nick $evalnext(%protect) }
      if (*o* iswmcs $1) && (%op) { awaynoticesystem $nick $evalnext(%op) }
      if (*h* iswmcs $1) && (%halfop) { awaynoticesystem $nick $evalnext(%halfop) }
      if (*v* iswmcs $1) && (%voice) { awaynoticesystem $nick $evalnext(%voice) }
    }

    if (*-* iswm $1) {
      if (!%devoice) && (!%dehalfop) && (!%deop) && (!%deprotect) && (!%deowner) { return }

      if (*q* iswmcs $1) && (%deowner) { awaynoticesystem $nick $evalnext(%deowner) }
      if (*a* iswmcs $1) && (%deprotect) { awaynoticesystem $nick $evalnext(%deprotect) }
      if (*o* iswmcs $1) && (%deop) { awaynoticesystem $nick $evalnext(%deop) }
      if (*h* iswmcs $1) && (%dehalfop) { awaynoticesystem $nick $evalnext(%dehalfop) }
      if (*v* iswmcs $1) && (%devoice) { awaynoticesystem $nick $evalnext(%devoice) }
    }

  }
}

alias mt { $iif(!$dialog(autothx),dialog -md,dialog -v) autothx autothx }

alias -l awaynoticesystem {
  var %spam = $evalnext($+(%,modethankercheck,.,$nick))

  if (%spam) { return }

  .quote notice $1 $+ $chr(32) $+ $chr(58) $+ $2-

  set -eu10 $+(%,modethankercheck,.,$nick) 1
}

alias -l init {
  var %h = thx
  var %f = settings.hsh

  if ($hget(%h)) { hfree %h }
  if (!$hget(%h)) { hmake %h 100 }
  if ($file(%f)) { hload %h $qt(%f) }
}