API tools faq
paste
Guest User

QTGMC for avs 2.60

a guest
Dec 31st, 2016
155
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Avisynth 80.13 KB | None | 0 0
raw download clone embed print report diff
  1. #-------------------------------------------------------------------#
  2. #                                                                   #
  3. #           QTGMC 3.349, by Vit, 2012, 2016 mod by A.SONY           #
  4. #                                                                   #
  5. #   A high quality deinterlacer using motion-compensated temporal   #
  6. #  smoothing, with a range of features for quality and convenience  #
  7. #          Originally based on TempGaussMC_beta2 by Didée           #
  8. #                                                                   #
  9. #-------------------------------------------------------------------#
  10. #
  11. # Full documentation is in the 'QTGMC' html file that comes with this script
  12. #
  13. # --- LATEST CHANGES ---
  14. #
  15. # v3.349s
  16. # - added tr0=-1 to use the EdiExt clip (if there is no EdiExt clip then it will be like tr0=0)
  17. # - rep0 now will be 0 if tr0 < 1
  18. #
  19. # v3.347s
  20. # - fix SourceMatch (bug after new YUY2 method, thanks to ndjamena for report it)
  21. #
  22. # v3.346s
  23. # - EEDI3+NNEDI3 bug fix by ndjamena
  24. # - Renamed DftThreads parameter to FftThreads, to set the ncpu argument of FFT3DFilter (from VS)
  25. # - FFT3DFilter will work now in YUY2, use it with Denoiser="fft3df" (or use NoisePreset)
  26. #
  27. # v3.345s
  28. # - work with SMDegrain_KNLMeansCL now to process chroma too
  29. #
  30. # v3.343s
  31. # - edit in ChromaEdi
  32. # - others
  33. #
  34. # v3.34s (mod) 2016 12 18 (ravewulf idea in another way)
  35. # - Added yadifmod2 (if you need old one use it like this EdiMode="cYadif" or EdiMode="RepcYadif")
  36. # - fast and clean up YUY2 (will work in x64 now, no need to SSETools)
  37. #
  38. # v3.33s (mod) 2016 12 06
  39. # - Add TR2=4 and TR2=5
  40. # - add TV_range bool and dither_luma_rebuild (from SMDegrain) Str and Amp
  41. # - for avsplus now QTGMC_Bob is ready for any 420, not only yv12
  42. #
  43. # v3.33s (mod) 2016 04 11
  44. # - Add KNLMeansCL as another Denoiser to NoiseProcess
  45. # - others
  46. #
  47. # v3.33s (mod) 2016 01 19
  48. # - make QTGMC_deflate/QTGMC_inflate work with YUY2 using masktool2 for avs 2.60
  49. #
  50. # v3.33s (mod) 2015 10 23
  51. # - revert to QTGMC_deflate/QTGMC_inflate quoted from Dogway
  52. #
  53. # v3.33s (mod) 2015 9 10
  54. # - fix Multiple QTGMC Calls
  55. # - others fix
  56. #
  57. # v3.33s (mod) 2015 8 6
  58. # - some changes in bob to speed up
  59. #
  60. # v3.33s (mod) 2015 8 4
  61. # - fix bug in YUY2 with SourceMatch
  62. # - add slice=false to ditherpost to avoid artefacts
  63. #
  64. # v3.33s (mod)
  65. # - fix bob chroma
  66. # - work with new masktool2 for avs 2.60 in YUY2
  67. #
  68. # v3.33d (mod)
  69. # - Added 32 bit precision option through the lsbd (for dfttest and knlmeanscl) and lsb (mdegrain) options.
  70. # - optimized some mask handling a bit as originally suggested by Vit
  71. # - others
  72. #
  73. # v3.33
  74. # - Increased maximum value for Rep0, Rep1 and Rep2 to 7 (from 5). Higher values help with flicker on static detail, potential for minor motion blur
  75. # - Bug fix for the fact that Bob always outputs a BFF clip regardless of field order of input (thanks ajp_anton)
  76. # - Improved generation of noise (NoiseDeint="Generate") for noise bypass / EZKeepGrain
  77. # - Minor change to denoising
  78. #
  79. # v3.32
  80. # - Bugfix with shutter blur and ChromaMotion (thanks Heaud)
  81. # - Tweaked vector recalculation for shutter motion blur
  82. # - Changed defaults for TR2 when using source-match
  83. # - Minor bugfix with SLMode/SLRad on pass-through settings
  84. #
  85. # --- REQUIREMENTS ---
  86. #
  87. # Input colorspaces: YV12, YUY2, others as plugins supports
  88. #
  89. # Core plugins:
  90. #   MVTools2 (2.7.5.22 or above from pinterf https://github.com/pinterf/mvtools/releases)
  91. #   MaskTools v2 (2.0b1 or above)
  92. #   NNEDI3 (0.9.4.6 or above)
  93. #   RgTools
  94. #
  95. # Additional plugins:
  96. #   NNEDI2, NNEDI, EEDI3, EEDI2, TDeInt - if selected directly or via a source-match preset
  97. #   yadifmod2 - for Preset="Ultra Fast" or if selected directly
  98. #   FFT3DFilter - if selected for noise processing
  99. #   dfttest (1.9.4 or above) - if selected for noise processing
  100. #       For FFT3DFilter & ddftest you also need the FFTW3 library (FFTW.org). On Windows the file needed for both is libfftw3f-3.dll. However, for FFT3DFilter
  101. #       the file needs to be called FFTW3.dll, so you will need two copies and rename one. On Windows put the files in your System32 or SysWow64 folder
  102. #   KNLMeansCL - if selected for noise processing
  103. #   AddGrainC - if NoiseDeint="Generate" selected for noise bypass
  104.  
  105.  
  106. # --- GETTING STARTED ---
  107. #
  108. # Install AviSynth and ensure you have at least the core plugins listed in the requirements section above. Put them in the plugins autoload folder.
  109. # To use QTGMC write a script like this:
  110. #   YourSource("yourfile")   # DGDecode_mpeg2source, FFVideoSource, AviSource, whatever your source requires
  111. #   QTGMC( Preset="Slow" )
  112. #   SelectEven()             # Add this line to keep original frame rate, leave it out for smoother doubled frame rate
  113. #
  114. # Save this script with an ".avs" extension. You can now use it as an AVI source for encoding.
  115. #
  116. # The "Preset" used selects sensible settings for a given encoding speed. Choose a preset from:
  117. #   "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast" & "Draft"
  118. # The default preset is "Slower"
  119. # Don't be obsessed with using slower settings as the differences can be small. HD material benefits little from extreme settings (and will be very slow)
  120. # For much faster speeds read the full documentation, the section on 'Multi-threading'
  121. #
  122. # There are many settings for tweaking the script, full details in the main documentation. You can display settings currently being used with "ShowSettings":
  123. #   QTGMC( Preset="Slow", ShowSettings=true )
  124.  
  125.  
  126. function QTGMC( clip Input, string "Preset", int "TR0", int "TR1", int "TR2", int "Rep0", int "Rep1", int "Rep2", string "EdiMode", bool "RepChroma", \
  127.                     int "NNSize", int "NNeurons", int "EdiQual", int "EdiMaxD", string "ChromaEdi", int "EdiThreads", clip "EdiExt", float "Sharpness", \
  128.                     int "SMode", int "SLMode", int "SLRad", int "SOvs", float "SVThin", int "Sbb", int "SrchClipPP", int "SubPel", int "SubPelInterp", \
  129.                     int "BlockSize", int "Overlap", int "Search", int "SearchParam", int "PelSearch", bool "ChromaMotion", bool "TrueMotion", int "Lambda", \
  130.                     int "LSAD", int "PNew", int "PLevel", bool "GlobalMotion", int "DCT", int "ThSAD1", int "ThSAD2", int "ThSCD1", int "ThSCD2", \
  131.                     int "SourceMatch", string "MatchPreset", string "MatchEdi", string "MatchPreset2", string "MatchEdi2", int "MatchTR2", \
  132.                     float "MatchEnhance", int "Lossless", int "NoiseProcess", float "EZDenoise", float "EZKeepGrain", string "NoisePreset", string "Denoiser", \
  133.                     int "FftThreads", bool "DenoiseMC", int "NoiseTR", float "Sigma", bool "ChromaNoise", val "ShowNoise", float "GrainRestore", \
  134.                     float "NoiseRestore", string "NoiseDeint", bool "StabilizeNoise", int "InputType", float "ProgSADMask", int "FPSDivisor", \
  135.                     int "ShutterBlur", float "ShutterAngleSrc", float "ShutterAngleOut", int "SBlurLimit", bool "Border", bool "Precise", string "Tuning", \
  136.                     bool "ShowSettings", string "GlobalNames", string "PrevGlobals", int "ForceTR", \
  137.                     val "BT", val "DetailRestore", val "MotionBlur", val "MBlurLimit", val "NoiseBypass", float "Str", float "Amp", bool "TV_range", bool "lsbd", bool "lsb" )
  138. {
  139.     # EdiMode="RepcYadif"/"cYadif" require the Yadif plugin, which doesn't autoload. Typically the calling script would load it.
  140.  
  141.     # Temporary Warnings
  142.     Assert( !defined(BT),            "QTGMC: Setting BT has been replaced by setting NoiseTR" )
  143.     Assert( !defined(DetailRestore), "QTGMC: Setting DetailRestore has been renamed to GrainRestore" )
  144.     Assert( !defined(MotionBlur),    "QTGMC: Setting MotionBlur has been renamed to ShutterBlur" )
  145.     Assert( !defined(MBlurLimit),    "QTGMC: Setting MBlurLimit has been renamed to SBlurLimit" )
  146.     Assert( !defined(NoiseBypass),   "QTGMC: Setting NoiseBypass has been renamed to NoiseProcess" )
  147.  
  148.     #---------------------------------------
  149.     # Presets
  150.     lsbd         = default( lsbd,    false)
  151.     lsb          = default( lsb,     false)
  152.     Str          = default( Str,      1.0 )
  153.     Amp          = default( Amp,   0.0625 )
  154.     TV_range     = default( TV_range, true)
  155.  
  156.     # Select presets / tuning
  157.     Preset = default( Preset, "Slower" )
  158.     pNum = (Preset == "Placebo"   ) ? 0 : \
  159.            (Preset == "Very Slow" ) ? 1 : \
  160.            (Preset == "Slower"    ) ? 2 : \
  161.            (Preset == "Slow"      ) ? 3 : \
  162.            (Preset == "Medium"    ) ? 4 : \
  163.            (Preset == "Fast"      ) ? 5 : \
  164.            (Preset == "Faster"    ) ? 6 : \
  165.            (Preset == "Very Fast" ) ? 7 : \
  166.            (Preset == "Super Fast") ? 8 : \
  167.            (Preset == "Ultra Fast") ? 9 : \
  168.            (Preset == "Draft"     ) ? 10 : 11
  169.     Assert( pNum  < 11, "'Preset' choice is invalid" )
  170.  
  171.     mpNum1 = (!defined(MatchPreset))       ? ((pNum + 3 <= 9) ? (pNum + 3) : 9) : \
  172.              (MatchPreset == "Placebo"   ) ? 0 : \
  173.              (MatchPreset == "Very Slow" ) ? 1 : \
  174.              (MatchPreset == "Slower"    ) ? 2 : \
  175.              (MatchPreset == "Slow"      ) ? 3 : \
  176.              (MatchPreset == "Medium"    ) ? 4 : \
  177.              (MatchPreset == "Fast"      ) ? 5 : \
  178.              (MatchPreset == "Faster"    ) ? 6 : \
  179.              (MatchPreset == "Very Fast" ) ? 7 : \
  180.              (MatchPreset == "Super Fast") ? 8 : \
  181.              (MatchPreset == "Ultra Fast") ? 9 : \
  182.              (MatchPreset == "Draft"     ) ? 10 : 11
  183.     Assert( mpNum1 < 10, "'MatchPreset' choice is invalid/unsupported" )
  184.     MatchPreset = Select( mpNum1, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  185.  
  186.     mpNum2 = (!defined(MatchPreset2))       ? ((mpNum1 + 2 <= 9) ? (mpNum1 + 2) : 9) : \
  187.              (MatchPreset2 == "Placebo"   ) ? 0 : \
  188.              (MatchPreset2 == "Very Slow" ) ? 1 : \
  189.              (MatchPreset2 == "Slower"    ) ? 2 : \
  190.              (MatchPreset2 == "Slow"      ) ? 3 : \
  191.              (MatchPreset2 == "Medium"    ) ? 4 : \
  192.              (MatchPreset2 == "Fast"      ) ? 5 : \
  193.              (MatchPreset2 == "Faster"    ) ? 6 : \
  194.              (MatchPreset2 == "Very Fast" ) ? 7 : \
  195.              (MatchPreset2 == "Super Fast") ? 8 : \
  196.              (MatchPreset2 == "Ultra Fast") ? 9 : \
  197.              (MatchPreset2 == "Draft"     ) ? 10 : 11
  198.     Assert( mpNum2 < 10, "'MatchPreset2' choice is invalid/unsupported" )
  199.     MatchPreset2 = Select( mpNum2, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  200.  
  201.     NoisePreset = default( NoisePreset, "Fast" )
  202.     npNum = (NoisePreset == "Slower" ) ? 0 : \
  203.             (NoisePreset == "Slow"   ) ? 1 : \
  204.             (NoisePreset == "Medium" ) ? 2 : \
  205.             (NoisePreset == "Fast"   ) ? 3 : \
  206.             (NoisePreset == "Faster" ) ? 4 : 5
  207.     Assert( npNum < 5, "'NoisePreset' choice is invalid" )
  208.  
  209.     Tuning = default( Tuning, "None" )
  210.     tNum = (Tuning == "None"  ) ? 0 : \
  211.            (Tuning == "DV-SD" ) ? 1 : \
  212.            (Tuning == "DV-HD" ) ? 2 : 3
  213.     Assert( tNum < 3, "'Tuning' choice is invalid" )
  214.  
  215.     # Tunings only affect blocksize in this version
  216.     bs = Select( tNum,  16, 16, 32 )
  217.     bs2 = (bs >= 16) ? 32 : bs * 2
  218.  
  219.     #                                                               Very                                                        Very      Super      Ultra
  220.     # Preset groups:                                     Placebo    Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast       Fast       Draft
  221.     TR0          = default( TR0,          Select( pNum,  2,         2,        2,        2,        2,        2,        1,        1,        1,         1,         0      ) )
  222.     TR1          = default( TR1,          Select( pNum,  2,         2,        2,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  223.     TR2X         = default( TR2,          Select( pNum,  3,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  224.     Rep0         = default( Rep0,         Select( pNum,  4,         4,        4,        4,        3,        3,        0,        0,        0,         0,         0      ) )
  225.     Rep1         = default( Rep1,         Select( pNum,  0,         0,        0,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  226.     Rep2         = default( Rep2,         Select( pNum,  4,         4,        4,        4,        4,        4,        4,        4,        3,         3,         0      ) )
  227.     Rep0         = TR0 < 1 ? 0 : Rep0
  228.     EdiMode      = default( EdiMode,      Select( pNum, "NNEDI3",  "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3",  "RepYadif","Bob"   ) )
  229.     NNSize       = default( NNSize,       Select( pNum,  1,         1,        1,        1,        5,        5,        4,        4,        4,         4,         4      ) )
  230.     NNeurons     = default( NNeurons,     Select( pNum,  2,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  231.     EdiQual      = default( EdiQual,      Select( pNum,  1,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  232.     EdiMaxD      = default( EdiMaxD,      Select( pNum,  12,        10,       8,        7,        7,        6,        6,        5,        4,         4,         4      ) )
  233.     SMode        = default( SMode,        Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        2,         2,         0      ) )
  234.     SLModeX      = default( SLMode,       Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        0,         0,         0      ) )
  235.     SLRad        = default( SLRad,        Select( pNum,  3,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  236.     Sbb          = default( Sbb,          Select( pNum,  3,         1,        1,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  237.     SrchClipPP   = default( SrchClipPP,   Select( pNum,  3,         3,        3,        3,        3,        2,        2,        2,        1,         1,         0      ) )
  238.     SubPel       = default( SubPel,       Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  239.     Blocksize    = default( Blocksize,    Select( pNum,  bs,        bs,       bs,       bs,       bs,       bs,       bs2,      bs2,      bs2,       bs2,       bs2    ) )
  240.     bs = Blocksize
  241.     Overlap      = default( Overlap,      Select( pNum,  bs/2,      bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/4,     bs/4,      bs/4,      bs/4   ) )
  242.     Search       = default( Search,       Select( pNum,  5,         4,        4,        4,        4,        4,        4,        4,        0,         0,         0      ) )
  243.     SearchParam  = default( SearchParam,  Select( pNum,  2,         2,        2,        2,        2,        2,        2,        1,        1,         1,         1      ) )
  244.     PelSearch    = default( PelSearch,    Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  245.     ChromaMotion = default( ChromaMotion, Select( pNum,  true,      true,     true,     false,    false,    false,    false,    false,    false,     false,     false  ) )
  246.     Precise      = default( Precise,      Select( pNum,  true,      true,     false,    false,    false,    false,    false,    false,    false,     false,     false  ) )
  247.     ProgSADMask  = default( ProgSADMask,  Select( pNum,  10.0,      10.0,     10.0,     10.0,     10.0,     0.0,      0.0,      0.0,      0.0,       0.0,       0.0    ) )
  248.  
  249.     # Noise presets                                           Slower     Slow       Medium     Fast       Faster
  250.     Denoiser       = default( Denoiser,       Select( npNum, "dfttest", "dfttest", "dfttest", "fft3df",  "fft3df" ) )
  251.     DenoiseMC      = default( DenoiseMC,      Select( npNum,  true,      true,      false,     false,     false   ) )
  252.     NoiseTR        = default( NoiseTR,        Select( npNum,  2,         1,         1,         1,         0       ) )
  253.     NoiseDeint     = default( NoiseDeint,     Select( npNum, "Generate","Bob",      "",        "",        ""      ) )
  254.     StabilizeNoise = default( StabilizeNoise, Select( npNum,  true,      true,      true,      false,     false   ) )
  255.  
  256.     # The basic source-match step corrects and re-runs the interpolation of the input clip. So it initialy uses same interpolation settings as the main preset
  257.     SourceMatch   = default( SourceMatch, 0 )
  258.     MatchNNSize   = NNSize
  259.     MatchNNeurons = NNeurons
  260.     MatchEdiMaxD  = EdiMaxD
  261.     MatchEdiQual  = EdiQual
  262.  
  263.     # However, can use a faster initial interpolation when using source-match allowing the basic source-match step to "correct" it with higher quality settings
  264.     Assert( SourceMatch == 0 || mpNum1 >= pNum, "'MatchPreset' cannot use a slower setting than 'Preset'" )
  265.     #                                                                    Very                                                        Very      Super     Ultra
  266.     # Basic source-match presets                                Placebo  Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  267.     NNSize   = (SourceMatch == 0) ? NNSize   : Select( mpNum1,  1,       1,        1,        1,        5,        5,        4,        4,        4,        4     )
  268.     NNeurons = (SourceMatch == 0) ? NNeurons : Select( mpNum1,  2,       2,        1,        1,        1,        0,        0,        0,        0,        0     )
  269.     EdiMaxD  = (SourceMatch == 0) ? EdiMaxD  : Select( mpNum1,  12,      10,       8,        7,        7,        6,        6,        5,        4,        4     )
  270.     EdiQual  = (SourceMatch == 0) ? EdiQual  : Select( mpNum1,  1,       1,        1,        1,        1,        1,        1,        1,        1,        1     )
  271.     TempEdi  = EdiMode # Main interpolation is actually done by basic-source match step when enabled, so a little swap and wriggle is needed
  272.     EdiMode  = (SourceMatch == 0) ? EdiMode  : default( MatchEdi, ((mpNum1 < 9) ?  EdiMode : "Yadif") ) # Force Yadif for "Ultra Fast" basic source match
  273.     MatchEdi = TempEdi
  274.  
  275.     #                                                          Very                                                        Very      Super     Ultra
  276.     # Refined source-match presets                   Placebo   Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  277.     MatchEdi2 = default( MatchEdi2, Select( mpNum2, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "TDeint",  ""    ) )
  278.     MatchNNSize2                  = Select( mpNum2,  1,        1,        1,        1,        5,        5,        4,        4,        4,        4     )
  279.     MatchNNeurons2                = Select( mpNum2,  2,        2,        1,        1,        1,        0,        0,        0,        0,        0     )
  280.     MatchEdiMaxD2                 = Select( mpNum2,  12,       10,       8,        7,        7,        6,        6,        5,        4,        4     )
  281.     MatchEdiQual2                 = Select( mpNum2,  1,        1,        1,        1,        1,        1,        1,        1,        1,        1     )
  282.  
  283.  
  284.     #---------------------------------------
  285.     # Settings
  286.  
  287.     # Core and Interpolation defaults
  288.     TR2        = (SourceMatch > 0) ? default(TR2, ((TR2X == 0) ? 1 : TR2X)) : TR2X  # ***TR2 defaults always at least 1 when using source-match***
  289.     RepChroma  = default( RepChroma,  true )
  290.     EdiThreads = default( EdiThreads, 0    )
  291.     ChromaEdi  = default( ChromaEdi,  ""   )
  292.     NNeurons   = (EdiMode == "NNEDI2" && NNeurons > 2) ? 2 : NNeurons # Smaller range for NNeurons in NNEDI2 (which calls it nsize)
  293.     EdiQual    = (EdiMode == "EEDI3+NNEDI3" || EdiMode == "NNEDI3") && EdiQual > 2 ? 2 : EdiQual  # Smaller range for EdiQual in NNEDI3
  294.  
  295.     # Source-match / lossless defaults
  296.     MatchTR1     = TR1
  297.     MatchTR2     = default( MatchTR2,     1   )
  298.     MatchEnhance = default( MatchEnhance, 0.5 )
  299.     Lossless     = default( Lossless,     0   )
  300.     Assert( Lossless <= 2, "Lossless setting only supports mode 1 ('true lossless') and mode 2 ('fake lossless') - see documentation in script and consider source-match settings" )
  301.  
  302.     # Sharpness defaults. Sharpness default is always 1.0 (0.2 with source-match), but adjusted to give roughly same sharpness for all settings
  303.     SMode      = (defined(Sharpness) && Sharpness == 0.0) ? 0 : SMode
  304.     SLMode     = (SourceMatch > 0) ? default(SLMode, 0) : SLModeX  # ***Sharpness limiting disabled by default for source-match***
  305.     SLMode     = (SLRad <= 0)      ? 0 : SLMode
  306.     spatialSL  = (SLMode == 1 || SLMode == 3)
  307.     temporalSL = (SLMode == 2 || SLMode == 4)
  308.     Sharpness  = default( Sharpness, (SMode == 0) ? 0.0 : ((SourceMatch > 0) ? 0.2 : 1.0) )      # Default sharpness is 1.0, or 0.2 if using source-match
  309.     sharpMul   = (temporalSL) ? 2 : (spatialSL) ? 1.5 : 1                                        # Adjust sharpness based on other settings
  310.     sharpAdj   = Sharpness * (sharpMul * (0.2 + TR1*0.15 + TR2*0.25) + ((SMode == 1) ? 0.1 : 0)) # [This needs a bit more refinement]
  311.     Sbb        = (SMode == 0) ? 0 : Sbb
  312.     SOvs       = default( SOvs,   0   )
  313.     SVThin     = default( SVThin, 0.0 )
  314.  
  315.     # Noise processing settings
  316.     Assert( !defined(EZDenoise) || EZDenoise <= 0.0 || !defined(EZKeepGrain) || EZKeepGrain <= 0.0, "QTGMC: EZDenoise and EZKeepGrain cannot be used together" )
  317.     NoiseProcess = defined(NoiseProcess) ? NoiseProcess : \
  318.                    (defined(EZDenoise)   && EZDenoise   > 0.0)    ? 1 : \
  319.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0)    ? 2 : \
  320.                    (Preset == "Placebo" || Preset == "Very Slow") ? 2 : 0
  321.     GrainRestore = defined(GrainRestore) ? GrainRestore : \
  322.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  323.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.3 * sqrt(EZKeepGrain) : \
  324.                                                                 Select( NoiseProcess, 0.0, 0.7, 0.3 )
  325.     NoiseRestore = defined(NoiseRestore) ? NoiseRestore : \
  326.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  327.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.1 * sqrt(EZKeepGrain) : \
  328.                                                                 Select( NoiseProcess, 0.0, 0.3, 0.1 )
  329.     Sigma        = defined(Sigma)       ? Sigma : \
  330.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? EZDenoise : \
  331.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 4.0 * EZKeepGrain : 2.0
  332.     FftThreads   = default( FftThreads, EdiThreads )
  333.     ChromaNoise  = default( ChromaNoise, false )
  334.     ShowNoise    = default( ShowNoise, 0.0 )
  335.     ShowNoise    = IsBool( ShowNoise ) ? (ShowNoise ? 10.0 : 0.0) : ShowNoise
  336.     NoiseProcess = (ShowNoise > 0.0)   ? 2   : NoiseProcess
  337.     NoiseRestore = (ShowNoise > 0.0)   ? 1.0 : NoiseRestore
  338.     NoiseTR      = (NoiseProcess == 0) ? 0   : NoiseTR
  339.     GrainRestore = (NoiseProcess == 0) ? 0.0 : GrainRestore
  340.     NoiseRestore = (NoiseProcess == 0) ? 0.0 : NoiseRestore
  341.     totalRestore = GrainRestore + NoiseRestore
  342.     StabilizeNoise = (totalRestore <= 0) ? false : StabilizeNoise
  343.     noiseTD  = Select( NoiseTR, 1, 3, 5 )
  344.     noiseCentre = (Denoiser == "dfttest") ? "128" : "128.5"
  345.  
  346.     # MVTools settings
  347.     SubPelInterp = default( SubPelInterp, 2     )
  348.     TrueMotion   = default( TrueMotion,   false )
  349.     GlobalMotion = default( GlobalMotion, true  )
  350.     Lambda       = default( Lambda, ((TrueMotion) ? 1000 : 100 ) * (BlockSize*BlockSize)/(8*8) )
  351.     LSAD         = default( LSAD,    (TrueMotion) ? 1200 : 400 )
  352.     PNew         = default( PNew,    (TrueMotion) ? 50   : 25  )
  353.     PLevel       = default( PLevel,  (TrueMotion) ? 1    : 0   )
  354.     DCT          = default( DCT,     0          )
  355.     ThSAD1       = default( ThSAD1,  10 * 8*8   )
  356.     ThSAD2       = default( ThSAD2,   4 * 8*8   )
  357.     ThSCD1       = default( ThSCD1,  180        )
  358.     ThSCD2       = default( ThSCD2,  98         )
  359.  
  360.     # Motion blur settings
  361.     FPSDivisor  = default( FPSDivisor, 1 )
  362.     ShutterBlur = default( ShutterBlur, 0 )
  363.     ShutterAngleSrc = default( ShutterAngleSrc, 180 )
  364.     ShutterAngleOut = default( ShutterAngleOut, 180 )
  365.     SBlurLimit  = default( SBlurLimit, 4 )
  366.     ShutterBlur = (ShutterAngleOut * FPSDivisor == ShutterAngleSrc) ? 0 : ShutterBlur  # If motion blur output is same as input
  367.  
  368.     # Miscellaneous
  369.     InputType      = default( InputType,     0        )
  370.     Border         = default( Border,        false    )
  371.     ShowSettings   = default( ShowSettings,  false    )
  372.     GlobalNames    = default( GlobalNames,  "QTGMC"   )
  373.     PrevGlobals    = default( PrevGlobals,  "Replace" )
  374.     ForceTR        = default( ForceTR,       0        )
  375.     ReplaceGlobals = (PrevGlobals == "Replace" || PrevGlobals == "Reuse") # If reusing existing globals put them back afterwards - simplifies logic later
  376.     ReuseGlobals   = (PrevGlobals == "Reuse")
  377.     ProgSADMask    = (InputType != 2 && InputType != 3) ? 0.0 : ProgSADMask
  378.     rgBlur         = (Precise) ? 11 : 12
  379.  
  380.     # Get maximum temporal radius needed
  381.     maxTR = (temporalSL)       ? SLRad : 0
  382.     maxTR = (MatchTR2 > maxTR) ? MatchTR2 : maxTR
  383.     maxTR = (TR1 > maxTR)      ? TR1 : maxTR
  384.     maxTR = (TR2 > maxTR)      ? TR2 : maxTR
  385.     maxTR = (NoiseTR > maxTR)  ? NoiseTR : maxTR
  386.     maxTR = (ProgSADMask > 0.0 || StabilizeNoise || ShutterBlur > 0) ? (maxTR > 1 ? maxTR : 1) : maxTR
  387.     maxTR = (ForceTR > MaxTR)  ? ForceTR : maxTR
  388.  
  389.  
  390.     #---------------------------------------
  391.     # Pre-Processing
  392.  
  393.     w = Input.Width()
  394.     h = Input.Height()
  395.     yuy2 = Input.IsYUY2()
  396.     epsilon = 0.0001
  397.  
  398.     # Reverse "field" dominance for progressive repair mode 3 (only difference from mode 2)
  399.     compl = (InputType == 3) ? Input.ComplementParity() : Input
  400.  
  401.     # Pad vertically during processing (to prevent artefacts at top & bottom edges)
  402.     clip = (Border) ? compl.PointResize( w,h+8, 0,-4,0,h+8+epsilon ) : compl
  403.     h = (Border) ? h+8 : h
  404.  
  405.     # Calculate padding needed for MVTools super clips to avoid crashes [fixed in latest MVTools, but keeping this code for a while]
  406.     hpad = w - (Int((w - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  407.     vpad = h - (Int((h - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  408.     hpad = (hpad > 8) ? hpad : 8 # But match default padding if possible
  409.     vpad = (vpad > 8) ? vpad : 8
  410.  
  411.  
  412.     #---------------------------------------
  413.     # Motion Analysis
  414.  
  415.     # >>> Planar YUY2 for motion analysis, interleaved whilst blurring search clip
  416.     planarClip = yuy2 ? clip.converttoyv16() : clip
  417.  
  418.     # Bob the input as a starting point for motion search clip
  419.     bobbed = (InputType == 0) ? planarClip.QTGMC_Bob( 0,0.5 ) : \
  420.              (InputType == 1) ? planarClip : \
  421.                                 planarClip.Blur( 0,1 )
  422.  
  423.     # If required, get any existing global clips with a matching "GlobalNames" setting. Unmatched values get NOP (= 0)
  424.     srchClip  = QTGMC_GetUserGlobal( GlobalNames, "srchClip",  ReuseGlobals )
  425.     srchSuper = QTGMC_GetUserGlobal( GlobalNames, "srchSuper", ReuseGlobals )
  426.     bVec1     = QTGMC_GetUserGlobal( GlobalNames, "bVec1",     ReuseGlobals )
  427.     fVec1     = QTGMC_GetUserGlobal( GlobalNames, "fVec1",     ReuseGlobals )
  428.     bVec2     = QTGMC_GetUserGlobal( GlobalNames, "bVec2",     ReuseGlobals )
  429.     fVec2     = QTGMC_GetUserGlobal( GlobalNames, "fVec2",     ReuseGlobals )
  430.     bVec3     = QTGMC_GetUserGlobal( GlobalNames, "bVec3",     ReuseGlobals )
  431.     fVec3     = QTGMC_GetUserGlobal( GlobalNames, "fVec3",     ReuseGlobals )
  432.     bVec4     = QTGMC_GetUserGlobal( GlobalNames, "bVec4",     ReuseGlobals )
  433.     fVec4     = QTGMC_GetUserGlobal( GlobalNames, "fVec4",     ReuseGlobals )
  434.     bVec5     = QTGMC_GetUserGlobal( GlobalNames, "bVec5",     ReuseGlobals )
  435.     fVec5     = QTGMC_GetUserGlobal( GlobalNames, "fVec5",     ReuseGlobals )
  436.  
  437.     CMmt = ChromaMotion ? 3   :  1
  438.     CMts = ChromaMotion ? 255 :  0
  439.     CMrg = ChromaMotion ? 12  : -1
  440.  
  441.     # The bobbed clip will shimmer due to being derived from alternating fields. Temporally smooth over the neighboring frames using a binomial kernel. Binomial
  442.     # kernels give equal weight to even and odd frames and hence average away the shimmer. The two kernels used are [1 2 1] and [1 4 6 4 1] for radius 1 and 2.
  443.     # These kernels are approximately Gaussian kernels, which work well as a prefilter before motion analysis (hence the original name for this script)
  444.     # Create linear weightings of neighbors first                                                 -2    -1     0    1     2
  445.     ts1 = (!IsClip(srchClip) && TR0 > 0) ? bobbed.TemporalSoften( 1, 255,CMts, 28, 2 ) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  446.     ts2 = (!IsClip(srchClip) && TR0 > 1) ? bobbed.TemporalSoften( 2, 255,CMts, 28, 2 ) : NOP()  # 0.20  0.20  0.20  0.20  0.20
  447.  
  448.     # Combine linear weightings to give binomial weightings - TR0=0: (1), TR0=1: (1:2:1), TR0=2: (1:4:6:4:1)
  449.     binomial0 = IsClip(srchClip) ? NOP() : \
  450.     TR0 == -1 && defined(EdiExt) ? isyuy2(EdiExt) ? EdiExt.converttoyv16() : EdiExt : \
  451.                 (TR0 == 0)       ? bobbed : \
  452.                 (TR0 == 1)       ? (ChromaMotion ? ts1.Merge( bobbed, 0.25 ) : ts1.MergeLuma( bobbed, 0.25 )) : \
  453.                                    (ChromaMotion ? ts1.Merge( ts2, 0.357 ).Merge( bobbed, 0.125 ) : ts1.MergeLuma( ts2, 0.357 ).MergeLuma( bobbed, 0.125 ))
  454.  
  455.     # Remove areas of difference between temporal blurred motion search clip and bob that are not due to bob-shimmer - removes general motion blur
  456.     repair0 = (IsClip(srchClip) || Rep0 == 0) ? binomial0 : binomial0.QTGMC_KeepOnlyBobShimmerFixes( bobbed, Rep0, (RepChroma && ChromaMotion) )
  457.  
  458.     # Blur image and soften edges to assist in motion matching of edge blocks. Blocks are matched by SAD (sum of absolute differences between blocks), but even
  459.     # a slight change in an edge from frame to frame will give a high SAD due to the higher contrast of edges
  460.     spatialBlur = (IsClip(srchClip) || SrchClipPP == 0) ? NOP() : \
  461.                   (SrchClipPP == 1) ? repair0.BilinearResize( w/2, h/2 ).RemoveGrain( 12,CMrg).BilinearResize( w, h ) : \
  462.                                       repair0.RemoveGrain( 12,CMrg).GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 )
  463.  
  464.     spatialBlur = (IsClip(spatialBlur) && SrchClipPP > 1) ? (ChromaMotion ? spatialBlur.Merge( repair0, 0.1 ) : spatialBlur.MergeLuma( repair0, 0.1 )) : spatialBlur
  465.     tweaked     = (!IsClip(srchClip) && SrchClipPP > 1) ? mt_lutxy( repair0, bobbed, "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt ) : NOP()
  466.     srchcheck   = IsClip(srchClip)
  467.     srchClip    = srchcheck         ? srchClip : \
  468.                   (SrchClipPP == 0) ? repair0 : \
  469.                   (SrchClipPP < 3)  ? spatialBlur : \
  470.                                       spatialBlur.mt_lutxy( tweaked, "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt )
  471.     srchClip    = tv_range && !srchcheck ? srchClip.Dither_Luma_Rebuild(S0=Str,c=Amp,slice=false,lsb=lsb,uv=CMmt) : srchClip
  472.     # Calculate forward and backward motion vectors from motion search clip
  473.     srchSuper = IsClip(srchSuper) ? srchSuper : \
  474.                 (maxTR > 0)       ? srchClip.MSuper( pel=SubPel, sharp=SubPelInterp, hpad=hpad, vpad=vpad, chroma=ChromaMotion ) : NOP()
  475.     bVec5 = IsClip(bVec5) ? bVec5 : \
  476.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=true,  delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  477.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  478.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  479.     bVec4 = IsClip(bVec4) ? bVec4 : \
  480.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=true,  delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  481.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  482.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  483.     bVec3 = IsClip(bVec3) ? bVec3 : \
  484.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=true,  delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  485.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  486.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  487.     bVec2 = IsClip(bVec2) ? bVec2 : \
  488.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=true,  delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  489.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  490.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  491.     bVec1 = IsClip(bVec1) ? bVec1 : \
  492.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=true,  delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  493.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  494.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  495.     fVec1 = IsClip(fVec1) ? fVec1 : \
  496.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=false, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  497.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  498.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  499.     fVec2 = IsClip(fVec2) ? fVec2 : \
  500.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=false, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  501.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  502.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  503.     fVec3 = IsClip(fVec3) ? fVec3 : \
  504.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=false, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  505.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  506.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  507.     fVec4 = IsClip(fVec4) ? fVec4 : \
  508.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=false, delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  509.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  510.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  511.     fVec5 = IsClip(fVec5) ? fVec5 : \
  512.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=false, delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  513.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  514.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  515.  
  516.     # Expose search clip, motion search super clip and motion vectors to calling script through globals
  517.     QTGMC_SetUserGlobal( GlobalNames, "srchClip",  srchClip,  ReplaceGlobals )
  518.     QTGMC_SetUserGlobal( GlobalNames, "srchSuper", srchSuper, ReplaceGlobals )
  519.     QTGMC_SetUserGlobal( GlobalNames, "bVec1",     bVec1,     ReplaceGlobals )
  520.     QTGMC_SetUserGlobal( GlobalNames, "fVec1",     fVec1,     ReplaceGlobals )
  521.     QTGMC_SetUserGlobal( GlobalNames, "bVec2",     bVec2,     ReplaceGlobals )
  522.     QTGMC_SetUserGlobal( GlobalNames, "fVec2",     fVec2,     ReplaceGlobals )
  523.     QTGMC_SetUserGlobal( GlobalNames, "bVec3",     bVec3,     ReplaceGlobals )
  524.     QTGMC_SetUserGlobal( GlobalNames, "fVec3",     fVec3,     ReplaceGlobals )
  525.     QTGMC_SetUserGlobal( GlobalNames, "bVec4",     bVec4,     ReplaceGlobals )
  526.     QTGMC_SetUserGlobal( GlobalNames, "fVec4",     fVec4,     ReplaceGlobals )
  527.     QTGMC_SetUserGlobal( GlobalNames, "bVec5",     bVec5,     ReplaceGlobals )
  528.     QTGMC_SetUserGlobal( GlobalNames, "fVec5",     fVec5,     ReplaceGlobals )
  529.  
  530.  
  531.     #---------------------------------------
  532.     # Noise Processing
  533.  
  534.     # >>>> Interleaved YUY2 for denoising, planar whilst pre-motion compensating
  535.  
  536.     # Expand fields to full frame size before extracting noise (allows use of motion vectors which are frame-sized)
  537.     fullClip  = (NoiseProcess == 0) ? NOP() : \
  538.                 (InputType > 0)     ? clip : \
  539.                                       clip.QTGMC_Bob( 0,1.0 )
  540.     fullClip  = (yuy2 && NoiseTR > 0) ? fullClip.converttoyv16() : fullClip
  541.     fullSuper = (NoiseTR > 0)         ? fullClip.MSuper( pel=SubPel, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP() #TEST chroma OK?
  542.  
  543.     # Create a motion compensated temporal window around current frame and use to guide denoisers
  544.     noiseWindow = (NoiseProcess == 0) ? NOP() : \
  545.                   (!DenoiseMC)        ? fullClip : \
  546.                   (NoiseTR == 0)      ? fullClip : \
  547.                   (NoiseTR == 1)      ? Interleave( fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  548.                                                     fullClip, \
  549.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) ) : \
  550.                                         Interleave( fullClip.MCompensate( fullSuper, fVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  551.                                                     fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  552.                                                     fullClip, \
  553.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  554.                                                     fullClip.MCompensate( fullSuper, bVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ) )
  555.     noiseWindow = yuy2 && (Denoiser == "fft3df") && NoiseTR > 0 ? noiseWindow.ConvertToYUY2() : noiseWindow
  556.     dnWindow = (NoiseProcess == 0)      ? NOP() : \
  557.                (Denoiser == "dfttest")  ? noiseWindow.dfttest( Y=true, U=ChromaNoise, V=ChromaNoise, sigma=Sigma*4, tbsize=noiseTD, threads=FftThreads, lsb=lsbd ) : \
  558.             (Denoiser == "KNLMeansCL")  ? noiseWindow.SMDegrain_KNLMeansCL(Chroma=ChromaNoise, lsb=lsbd, a=2, d=NoiseTR, h=Sigma, device_type="GPU" ) : \
  559.                                           noiseWindow.FFT3DFilter( plane=(ChromaNoise ? 4 : 0), sigma=Sigma, bt=noiseTD, ncpu=FftThreads )
  560.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && lsbd ? dnWindow.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false) : dnWindow
  561.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && yuy2 ? dnWindow.ConvertToYUY2() : dnWindow
  562.  
  563.     # Rework denoised clip to match source format - various code paths here: discard the motion compensation window, discard doubled lines (from point resize)
  564.     # Also reweave to get interlaced noise if source was interlaced (could keep the full frame of noise, but it will be poor quality from the point resize)
  565.     denoised = (NoiseProcess == 0) ? NOP() : \
  566.                (!DenoiseMC)        ? ((InputType > 0) ? dnWindow : dnWindow.SeparateFields().SelectEvery( 4, 0,3 ).Weave()) : \
  567.                (InputType > 0)     ? ((NoiseTR == 0)  ? dnWindow : dnWindow.SelectEvery( noiseTD, NoiseTR )) : \
  568.                                      dnWindow.SeparateFields().SelectEvery( noiseTD*4, NoiseTR*2,NoiseTR*6+3 ).Weave()
  569.  
  570.     # >>>> Switch to planar YUY2 for noise bypass
  571.  
  572.     CNmt1   = ChromaNoise ? 3 : 1
  573.     CNmt2   = ChromaNoise ? 3 : 2
  574.     CNmt128 = ChromaNoise ? 3 : -128
  575.  
  576.     # Get actual noise from difference. Then 'deinterlace' where we have weaved noise - create the missing lines of noise in various ways
  577.     planarDenoised = (NoiseProcess == 0) ? NOP() : yuy2 ? denoised.converttoyv16() : denoised
  578.     noise = (totalRestore > 0.0)  ? mt_makediff( planarClip, planarDenoised, U=CNmt1,V=CNmt1 ) : NOP()
  579.     deintNoise = (NoiseProcess == 0 || totalRestore == 0.0) ? NOP() : \
  580.                  (InputType != 0)                           ? noise : \
  581.                  (NoiseDeint == "Bob")                      ? noise.QTGMC_Bob( 0,0.5 ) : \
  582.                  (NoiseDeint == "Generate")                 ? noise.QTGMC_Generate2ndFieldNoise( denoised, ChromaNoise ) : \
  583.                                                               noise.DoubleWeave()
  584.     # Motion-compensated stabilization of generated noise
  585.     noiseSuper = (StabilizeNoise) ? deintNoise.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP()
  586.     mcNoise    = (StabilizeNoise) ? deintNoise.MCompensate( noiseSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  587.     finalNoise = (StabilizeNoise) ? mt_lutxy( deintNoise, mcNoise, "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ) : deintNoise
  588.  
  589.     # If NoiseProcess=1 denoise input clip. If NoiseProcess=2 leave noise in the clip and let the temporal blurs "denoise" it for a stronger effect
  590.     innerClip = (NoiseProcess == 1) ? denoised : clip
  591.  
  592.  
  593.     #---------------------------------------
  594.     # Interpolation
  595.  
  596.     # >>>> Interleaved YUY2 for interpolation
  597.  
  598.     # Support badly deinterlaced progressive content - drop half the fields and reweave to get 1/2fps interlaced stream appropriate for QTGMC processing
  599.     ediInput = (InputType == 2 || InputType == 3) ? innerClip.SeparateFields().SelectEvery(4,0,3).Weave() : innerClip
  600.  
  601.     # Create interpolated image as starting point for output
  602.     edi1 = defined(EdiExt) ? EdiExt.PointResize( w,h, 0,(EdiExt.Height()-h)/2, -0,h+epsilon ) : \
  603.                              QTGMC_Interpolate( ediInput, InputType, EdiMode, NNSize, NNeurons, EdiQual, EdiMaxD, EdiThreads, bobbed, ChromaEdi )
  604.  
  605.     # >>>> Switch to planar YUY2 during next step - remains planar until very end of script except blurring for back blending & SVThin
  606.  
  607.     # InputType=2,3: use motion mask to blend luma between original clip & reweaved clip based on ProgSADMask setting. Use chroma from original clip in any case
  608.     inputTypeBlend = (ProgSADMask > 0.0) ? MMask( srchClip, bVec1, kind=1, ml=ProgSADMask ) : NOP()
  609.     edi = (InputType != 2 && InputType != 3) ? (!yuy2 ? edi1 : edi1.ConvertToYV16()) :\
  610.           (ProgSADMask <= 0.0)               ? (!yuy2 ? edi1.MergeChroma( innerClip ) : edi1.MergeChroma( innerClip ).ConvertToYV16()) : \
  611.                                                (!yuy2 ? mt_merge( innerClip, edi1, inputTypeBlend, U=2,V=2 ) : \
  612.                                                         mt_merge( innerClip.ConvertToYV16(), edi1.ConvertToYV16(), inputTypeBlend, U=2,V=2 ))
  613.  
  614.     # Get the max/min value for each pixel over neighboring motion-compensated frames - used for temporal sharpness limiting
  615.     ediSuper = (TR1 > 0 || temporalSL)   ? edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  616.     bComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  617.     fComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  618.     tMax     = (temporalSL)              ? edi.mt_logic( fComp1, "max", U=3,V=3 ).mt_logic( bComp1, "max", U=3,V=3 )    : NOP()
  619.     tMin     = (temporalSL)              ? edi.mt_logic( fComp1, "min", U=3,V=3 ).mt_logic( bComp1, "min", U=3,V=3 )    : NOP()
  620.     bComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, bVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  621.     fComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, fVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  622.     tMax     = (SLRad > 1 && temporalSL) ? tMax.mt_logic( fComp3, "max", U=3,V=3 ).mt_logic( bComp3, "max", U=3,V=3 )   : tMax
  623.     tMin     = (SLRad > 1 && temporalSL) ? tMin.mt_logic( fComp3, "min", U=3,V=3 ).mt_logic( bComp3, "min", U=3,V=3 )   : tMin
  624.  
  625.  
  626.     #---------------------------------------
  627.     # Create basic output
  628.  
  629.     # Use motion vectors to blur interpolated image (edi) with motion-compensated previous and next frames. As above, this is done to remove shimmer from
  630.     # alternate frames so the same binomial kernels are used. However, by using motion-compensated smoothing this time we avoid motion blur. The use of
  631.     # MDegrain1 (motion compensated) rather than TemporalSmooth makes the weightings *look* different, but they evaluate to the same values
  632.     # Create linear weightings of neighbors first                                                                                -2    -1     0    1     2
  633.     degrain1 = (TR1 > 0) ? edi.MDegrain1( ediSuper, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  634.     degrain2 = (TR1 > 1) ? edi.MDegrain1( ediSuper, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP()  # 0.33  0.00  0.33  0.00  0.33
  635.     degrain1 = (TR1 > 0) && lsb ? degrain1.ditherpost(mode=6, slice=false) : degrain1
  636.     degrain2 = (TR1 > 1) && lsb ? degrain2.ditherpost(mode=6, slice=false) : degrain2
  637.  
  638.     # Combine linear weightings to give binomial weightings - TR1=0: (1), TR1=1: (1:2:1), TR1=2: (1:4:6:4:1)
  639.     binomial1 = (TR1 == 0) ? edi : \
  640.                 (TR1 == 1) ? degrain1.Merge( edi, 0.25 ) : \
  641.                              degrain1.Merge( degrain2, 0.2 ).Merge( edi, 0.0625 )
  642.  
  643.     # Remove areas of difference between smoothed image and interpolated image that are not bob-shimmer fixes: repairs residual motion blur from temporal smooth
  644.     repair1 = (Rep1 == 0) ? binomial1 : binomial1.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep1, RepChroma )
  645.  
  646.     # Apply source match - use difference between output and source to succesively refine output [extracted to function to clarify main code path]
  647.     match = (SourceMatch == 0) ? repair1 : \
  648.                                  repair1.QTGMC_ApplySourceMatch( InputType, ediInput, bVec1,fVec1, bVec2,fVec2, SubPel, SubPelInterp, hpad, vpad, \
  649.                                                                  ThSAD1, ThSCD1, ThSCD2, SourceMatch, MatchTR1, MatchEdi, MatchNNSize, MatchNNeurons, \
  650.                                                                  MatchEdiQual, MatchEdiMaxD, MatchTR2, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, \
  651.                                                                  MatchEdiMaxD2, MatchEnhance, EdiThreads, lsb )
  652.  
  653.     # Lossless=2 - after preparing an interpolated, de-shimmered clip, restore the original source fields into it and clean up any artefacts.
  654.     # This mode will not give a true lossless result because the resharpening and final temporal smooth are still to come, but it will add further detail.
  655.     # However, it can introduce minor combing. This setting is best used together with source-match (it's effectively the final source-match stage).
  656.     lossed1 = (Lossless == 2) ? QTGMC_MakeLossless( match, innerClip, InputType ) : match
  657.  
  658.  
  659.     #---------------------------------------
  660.     # Resharpen / retouch output
  661.  
  662.     # Resharpen to counteract temporal blurs. Little sharpening needed for source-match mode since it has already recovered sharpness from source
  663.     vresharp1 = (SMode == 2) ? Merge( lossed1.mt_expand( mode="vertical", U=3,V=3 ), lossed1.mt_inpand( mode="vertical", U=3,V=3 ) ) : NOP()
  664.     vresharp  = (Precise && SMode == 2) ? vresharp1.mt_lutxy( lossed1, "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ) : vresharp1 # Precise mode: reduce tiny overshoot
  665.     resharp   = (SMode == 0) ? lossed1 : \
  666.                 (SMode == 1) ? lossed1.mt_lutxy( lossed1.RemoveGrain( rgBlur ),  "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ) : \
  667.                                lossed1.mt_lutxy( vresharp.RemoveGrain( rgBlur ), "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 )
  668.  
  669.     # Slightly thin down 1-pixel high horizontal edges that have been widened into neigboring field lines by the interpolator
  670.     SVThinSc = SVThin * 6.0
  671.     vertMedD = (SVthin > 0.0) ? mt_lutxy( lossed1, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1 ), "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ) : NOP()
  672.     vertMedD = (SVthin > 0.0) ? (vertMedD.Blur( 1,0 )) : NOP()
  673.     neighborD = (SVthin > 0.0) ? mt_lutxy( vertMedD, vertMedD.RemoveGrain( rgBlur,-1 ), "y 128 - abs x 128 - abs > y 128 ?" ) : NOP()
  674.     thin      = (SVthin > 0.0) ? resharp.mt_adddiff( neighborD, U=2,V=2 ) : resharp
  675.  
  676.     # Back blend the blurred difference between sharpened & unsharpened clip, before (1st) sharpness limiting (Sbb == 1,3). A small fidelity improvement
  677.     backBlend1 = (Sbb != 1 && Sbb != 3) ? thin : \
  678.                          thin.mt_makediff( mt_makediff( thin, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  679.                              .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  680.  
  681.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  682.     # Occurs here (before final temporal smooth) if SLMode == 1,2. This location will restrict sharpness more, but any artefacts introduced will be smoothed
  683.     sharpLimit1 = (SLMode == 1) ? backBlend1.Repair( ((SLrad <= 1) ? edi : backBlend1.Repair( edi, 12 )), 1 ) : \
  684.                   (SLMode == 2) ? backBlend1.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  685.                                   backBlend1
  686.  
  687.     # Back blend the blurred difference between sharpened & unsharpened clip, after (1st) sharpness limiting (Sbb == 2,3). A small fidelity improvement
  688.     backBlend2 = (Sbb < 2) ? sharpLimit1 : \
  689.                          sharpLimit1.mt_makediff( mt_makediff( sharpLimit1, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  690.                                         .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  691.  
  692.     # Add back any extracted noise, prior to final temporal smooth - this will restore detail that was removed as "noise" without restoring the noise itself
  693.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  694.     addNoise1 = (GrainRestore <= 0.0) ? backBlend2 : \
  695.                                         backBlend2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  696.  
  697.     # Final light linear temporal smooth for denoising
  698.     stableSuper = (TR2 > 0) ? addNoise1.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  699.     stable  = (TR2 == 0) ? addNoise1 : \
  700.               (TR2 == 1) ? addNoise1.MDegrain1( stableSuper, bVec1,fVec1,                                                     thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  701.               (TR2 == 2) ? addNoise1.MDegrain2( stableSuper, bVec1,fVec1, bVec2,fVec2,                                        thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  702.               (TR2 == 3) ? addNoise1.MDegrain3( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3,                           thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  703.               (TR2 == 4) ? addNoise1.MDegrain4( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4,              thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  704.                            addNoise1.MDegrain5( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4, bVec5,fVec5, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb )
  705.     stable  = (TR2 > 0) && lsb ? stable.ditherpost(mode=6, slice=false) : stable
  706.  
  707.     # Remove areas of difference between final output & basic interpolated image that are not bob-shimmer fixes: repairs motion blur caused by temporal smooth
  708.     repair2 = (Rep2 == 0) ? stable : stable.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep2, RepChroma )
  709.  
  710.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  711.     # Occurs here (after final temporal smooth) if SLMode == 3,4. Allows more sharpening here, but more prone to introducing minor artefacts
  712.     sharpLimit2 = (SLMode == 3) ? repair2.Repair( ((SLrad <= 1) ? edi : repair2.Repair( edi, 12 )), 1 ) : \
  713.                   (SLMode == 4) ? repair2.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  714.                                   repair2
  715.  
  716.     # Lossless=1 - inject source fields into result and clean up inevitable artefacts. Provided NoiseRestore=0.0 or 1.0, this mode will make the script result
  717.     # properly lossless, but this will retain source artefacts and cause some combing (where the smoothed deinterlace doesn't quite match the source)
  718.     lossed2 = (Lossless == 1) ? QTGMC_MakeLossless( sharpLimit2, innerClip, InputType ) : sharpLimit2
  719.  
  720.     # Add back any extracted noise, after final temporal smooth. This will appear as noise/grain in the output
  721.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  722.     addNoise2 = (NoiseRestore <= 0.0) ? lossed2 : \
  723.                                         lossed2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  724.  
  725.  
  726.     #---------------------------------------
  727.     # Post-Processing
  728.  
  729.     # Shutter motion blur - get level of blur depending on output framerate and blur already in source
  730.     blurLevel = (ShutterAngleOut * FPSDivisor - ShutterAngleSrc) * 100.0 / 360.0
  731.     Assert( blurLevel >= 0, "Cannot reduce motion blur already in source: increase ShutterAngleOut or FPSDivisor" )
  732.     Assert( blurLevel <= 200, "Exceeded maximum motion blur level: decrease ShutterAngleOut or FPSDivisor" )
  733.  
  734.     # ShutterBlur mode 2,3 - get finer resolution motion vectors to reduce blur "bleeding" into static areas
  735.     rBlockDivide = Select( ShutterBlur, 1, 1, 2, 4 )
  736.     rBlockSize = BlockSize / rBlockDivide
  737.     rOverlap   = Overlap   / rBlockDivide
  738.     rBlockSize = (rBlockSize < 4) ? 4 : rBlockSize
  739.     rOverlap   = (rOverlap   < 2) ? 2 : rOverlap
  740.     rBlockDivide = BlockSize / rBlockSize
  741.     rLambda = Lambda / (rBlockDivide * rBlockDivide)
  742.     sbBVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( bVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  743.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : bVec1
  744.     sbFVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( fVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  745.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : fVec1
  746.  
  747.     # Shutter motion blur - use MFlowBlur to blur along motion vectors
  748.     sblurSuper = (ShutterBlur > 0) ? addNoise2.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  749.     sblur =      (ShutterBlur > 0) ? addNoise2.MFlowBlur( sblurSuper, sbBVec1, sbFVec1, blur=blurLevel, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  750.  
  751.     # Shutter motion blur - use motion mask to reduce blurring in areas of low motion - also helps reduce blur "bleeding" into static areas, then select blur type
  752.     sbMotionMask = (ShutterBlur > 0 && SBlurLimit > 0) ? MMask( srchClip, bVec1, kind=0, ml=SBlurLimit ) : NOP()
  753.     sblurred     = (ShutterBlur == 0) ? addNoise2 : \
  754.                    (SBlurLimit == 0)  ? sblur : \
  755.                                         mt_merge( addNoise2, sblur, sbMotionMask, U=3,V=3 )
  756.     # Reduce frame rate
  757.     decimated = (FPSDivisor != 1) ? sblurred.SelectEvery( FPSDivisor, 0 ) : sblurred
  758.  
  759.     # Crop off temporary vertical padding
  760.     cropped = Border ? decimated.Crop( 0, 4, -0, -4 ) : decimated
  761.     h = Border ? h-8 : h
  762.  
  763.     # Show output of choice + settings
  764.     # >>>> Restore YUY2 to interleaved
  765.     output = (ShowNoise == 0.0) ? cropped : finalNoise.mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 )
  766.     output = yuy2 ? output.ConvertToYUY2() : output
  767.     return (ShowSettings == false) ? output : \
  768.         output.Subtitle( "TR0=" + string(TR0) + " | TR1=" + string(TR1) + " | TR2=" + string(TR2) + " | Rep0=" + string(Rep0) + " | Rep1=" + string(Rep1) + \
  769.         " | Rep2=" + string(Rep2) + " | RepChroma=" + string(RepChroma) + "\nEdiMode='" + EdiMode + "' | NNSize=" + string(NNSize) + " | NNeurons=" + \
  770.         string(NNeurons) + " | EdiQual=" + string(EdiQual) + " | EdiMaxD=" + string(EdiMaxD) + " | ChromaEdi='" + ChromaEdi + "' | EdiThreads=" + \
  771.         string(EdiThreads) + "\nSharpness=" + string(Sharpness, "%.2f") + " | SMode=" + string(SMode) + " | SLMode=" + string(SLMode) + " | SLRad=" + \
  772.         string(SLRad) + " | SOvs=" + string(SOvs) + " | SVThin=" + string(SVThin, "%.2f") + " | Sbb=" + string(Sbb) + "\nSrchClipPP=" + string(SrchClipPP) + \
  773.         " | SubPel=" + string(SubPel) + " | SubPelInterp=" + string(SubPelInterp) + " | BlockSize=" + string(BlockSize) + " | Overlap=" + string(Overlap) + \
  774.         "\nSearch=" + string(Search) + " | SearchParam=" + string(SearchParam) + " | PelSearch=" + string(PelSearch) + " | ChromaMotion=" + \
  775.         string(ChromaMotion) + " | TrueMotion=" + string(TrueMotion) + "\nLambda=" + string(Lambda) + " | LSAD=" + string(LSAD) + " | PNew=" + string(PNew) + \
  776.         " | PLevel=" + string(PLevel) + " | GlobalMotion=" + string(GlobalMotion) + " | DCT=" + string(DCT) + "\nThSAD1=" + string(ThSAD1) + " | ThSAD2=" + \
  777.         string(ThSAD2) + " | ThSCD1=" + string(ThSCD1) + " | ThSCD2=" + string(ThSCD2) + "\nSourceMatch=" + string(SourceMatch) + " | MatchPreset='" + \
  778.         MatchPreset + "' | MatchEdi='" + MatchEdi + "'\nMatchPreset2='" + MatchPreset2 + "' | MatchEdi2='" + MatchEdi2 + "' | MatchTR2=" + string(MatchTR2) + \
  779.         " | MatchEnhance=" + string(MatchEnhance, "%.2f") + " | Lossless=" + string(Lossless) + "\nNoiseProcess=" + string(NoiseProcess) + " | Denoiser='" + \
  780.         Denoiser + "' | FftThreads=" + string(FftThreads) + " | DenoiseMC=" + string(DenoiseMC) + " | NoiseTR=" + string(NoiseTR) + " | Sigma=" + \
  781.         string(Sigma, "%.2f") + "\nChromaNoise=" + string(ChromaNoise) + " | ShowNoise=" + string(ShowNoise, "%.2f") + " | GrainRestore=" + \
  782.         string(GrainRestore, "%.2f") + " | NoiseRestore=" + string(NoiseRestore, "%.2f") + "\nNoiseDeint='" + NoiseDeint + "' | StabilizeNoise=" + \
  783.         string(StabilizeNoise) + " | InputType=" + string(InputType) + " | ProgSADMask=" + string(ProgSADMask, "%.2f") + "\nFPSDivisor=" + \
  784.         string(FPSDivisor) + " | ShutterBlur=" + string(ShutterBlur) + " | ShutterAngleSrc=" + string(ShutterAngleSrc, "%.2f") + " | ShutterAngleOut=" + \
  785.         string(ShutterAngleOut, "%.2f") + " | SBlurLimit=" + string(SBlurLimit) + "\nBorder=" + string(Border) + " | Precise=" + string(Precise) + \
  786.         "\nPreset='" + Preset + "' | Tuning='" + Tuning + "' | GlobalNames='" + GlobalNames + "' | PrevGlobals='" + PrevGlobals + "' | ForceTR=" + \
  787.         string(ForceTR), font="Lucida Console", size=11, lsp=12 )
  788. }
  789.  
  790.  
  791. #---------------------------------------
  792. # Helpers
  793.  
  794. # Same as Bob, but keeps the field order the same.
  795. function QTGMC_Bob(clip cp, float "b", float "c", int "height" )
  796. {
  797.   ssispmt = Findstr(VersionString(), "AviSynth+") != 0 && Findstr(VersionString(), "r1576") == 0
  798.   h = Default(height, cp.Height)
  799.   w = cp.Width
  800.   shift = GetParity(cp) ? 0.25 : -0.25
  801.  
  802.   c420 = ssispmt ? Is420(cp) : IsYV12(cp)
  803.  
  804.   c420 ? cp.SeparateFields() : nop()
  805.  
  806.   oeven=c420 ? SelectEven() : nop()
  807.   oodd=c420 ? SelectOdd() : nop()
  808.  
  809.   even=c420 ? ssispmt ? oeven.ConvertToY().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : oeven.ConvertToY8().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : nop()
  810.   odd=c420 ? ssispmt ? oodd.ConvertToY().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : oodd.ConvertToY8().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : nop()
  811.  
  812.   evenChr=c420 ? Interleave(ssispmt ? oeven.ExtractU() : oeven.UToY8(), ssispmt ? oeven.ExtractV() : oeven.VToY8()).BicubicResize(w/2, h/2, b, c, 0, shift, w/2, Height()/2).AssumeFrameBased() : nop()
  813.   oddChr=c420 ? Interleave(ssispmt ? oodd.ExtractU() : oodd.UToY8(), ssispmt ? oodd.ExtractV() :oodd.VToY8()).BicubicResize(w/2, h/2, b, c, 0, -shift, w/2, Height()/2).AssumeFrameBased() : nop()
  814.  
  815.   c420 ? YToUV(Interleave(evenChr.SelectEven(), oddChr.SelectEven()),Interleave(evenChr.SelectOdd(), oddChr.SelectOdd()),Interleave(even, odd)) : cp.Bob( b,c, h )
  816.   GetParity(cp) ? AssumeTFF() : AssumeBFF()
  817. }
  818.  
  819.  
  820. # Interpolate input clip using method given in EdiMode. Use Fallback or Bob as result if mode not in list. If ChromaEdi string if set then interpolate chroma
  821. # separately with that method (only really useful for EEDIx). The function is used as main algorithm starting point and for first two source-match stages
  822. function QTGMC_Interpolate( clip Input, int InputType, string EdiMode, int NNSize, int NNeurons, int EdiQual, int EdiMaxD, int EdiThreads, clip "Fallback", \
  823.                             string "ChromaEdi" )
  824. {
  825.     # >>>> YUY2 is interleaved here
  826.  
  827.     ChromaEdi = default( ChromaEdi, "" )
  828.     CEed = (ChromaEdi == "")
  829.  
  830.     interp = (InputType == 1)            ? Input : \
  831.              (EdiMode == "NNEDI3")       ? Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  832.              (EdiMode == "NNEDI2")       ? Input.NNEDI2( field=-2, nsize=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  833.              (EdiMode == "NNEDI")        ? Input.NNEDI( field=-2, U=CEed,V=CEed ) : \
  834.              (EdiMode == "EEDI3+NNEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed, \
  835.                                                         sclip=Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) ) : \
  836.              (EdiMode == "EEDI3")        ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed ) : \
  837.              (EdiMode == "EEDI2")        ? Input.SeparateFields().EEDI2( field=-2, maxd=EdiMaxD ) : \
  838.              (EdiMode == "Yadif")        ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  839.              (EdiMode == "cYadif")       ? Input.Yadif( mode=3 ) : \
  840.              (EdiMode == "TDeint")       ? Input.TDeInt( mode=1 ) : \
  841.              (EdiMode == "RepYadif")     ? isyuy2(Input) ? Repair( Input.ConvertToYv16().Yadifmod2( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  842.                                                            Input.Yadifmod2( mode=3 ) : \   
  843.              (EdiMode == "RepcYadif")    ? isyuy2(Input) ? Repair( Input.Yadif( mode=3 ).ConvertToYv16(), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  844.                                                    Repair( Input.Yadif( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ), 2, 0 ) : \
  845.                                            default( Fallback, Input.QTGMC_Bob( 0,0.5 ) )
  846.  
  847.     interpuv = (InputType == 1)        ? NOP() : \
  848.                (ChromaEdi == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=4, nns=0, qual=1, threads=EdiThreads, Y=false ) : \
  849.                (ChromaEdi == "Yadif")  ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  850.                (ChromaEdi == "cYadif") ? Input.Yadif( mode=3 ) : \
  851.                (ChromaEdi == "Bob")    ? Input.QTGMC_Bob( 0,0.5 ) : \
  852.                                          NOP()
  853.  
  854.     return (!IsClip(interpuv)) ? interp : interp.MergeChroma( interpuv )
  855. }
  856.  
  857.  
  858. # Functions (from original TGMC) used instead of mt_xxflate with similar operation but a somewhat stronger result. Originally added for speed, they are
  859. # no longer faster due to improvements in masktools. Difference (visual and speed) is small so may be reverted in a later version.
  860. function QTGMC_inflate( clip c, int "Y", int "U", int "V" )
  861. {
  862.     # >>>> YUY2 is planar here
  863.     mtY =default( Y, 3 )
  864.     mtU =default( U, 1 )
  865.     mtV =default( V, 1 )
  866.     rgY = (mtY == 3) ? 20 : -1
  867.     rgU = (mtU == 3) ? 20 : -1
  868.     rgV = (mtV == 3) ? 20 : -1
  869.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "max", Y=mtY,U=mtU,V=mtV )
  870. }
  871.  
  872. function QTGMC_deflate( clip c, int "Y", int "U", int "V" )
  873. {
  874.     # >>>> YUY2 is planar here
  875.     mtY =default( Y, 3 )
  876.     mtU =default( U, 1 )
  877.     mtV =default( V, 1 )
  878.     rgY = (mtY == 3) ? 20 : -1
  879.     rgU = (mtU == 3) ? 20 : -1
  880.     rgV = (mtV == 3) ? 20 : -1
  881.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "min", Y=mtY,U=mtU,V=mtV )
  882. }
  883.  
  884. # Helper function: Compare processed clip with reference clip: only allow thin, horizontal areas of difference, i.e. bob shimmer fixes
  885. # Rough algorithm: Get difference, deflate vertically by a couple of pixels or so, then inflate again. Thin regions will be removed
  886. #                  by this process. Restore remaining areas of difference back to as they were in reference clip.
  887. function QTGMC_KeepOnlyBobShimmerFixes( clip Input, clip Ref, int Rep, bool Chroma )
  888. {
  889.     # >>>> YUY2 is planar here
  890.  
  891.     # ed is the erosion distance - how much to deflate then reflate to remove thin areas of interest: 0 = minimum to 6 = maximum
  892.     # od is over-dilation level  - extra inflation to ensure areas to restore back are fully caught:  0 = none to 3 = one full pixel
  893.     # If Rep < 10, then ed = Rep and od = 0, otherwise ed = 10s digit and od = 1s digit (nasty method, but kept for compatibility with original TGMC)
  894.     Rep    = default( Rep,    1    )
  895.     Chroma = default( Chroma, true )
  896.     ed = (Rep < 10) ? Rep : Rep / 10
  897.     od = (Rep < 10) ? 0   : Rep % 10
  898.     RCrg  = Chroma ? 3 : 1
  899.     RCrgo = Chroma ? 3 : 2
  900.  
  901.     diff = mt_makediff(Ref, Input, U=3,V=3 )
  902.  
  903.     # Areas of positive difference                                                                # ed = 0 1 2 3 4 5 6 7
  904.     choke1 =                        diff.  mt_inpand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel   \
  905.     choke1 = (ed > 2)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . x x x x x    1 pixel    |  Deflate to remove thin areas
  906.     choke1 = (ed > 5)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . . x x    1 pixel   /
  907.     choke1 = (ed % 3 != 0)        ? choke1.QTGMC_deflate( U=RCrg,V=RCrg )              : choke1   #      . x x . x x . x    A bit more deflate & some horizonal effect
  908.     choke1 = (ed == 2 || ed == 5) ? choke1.RemoveGrain( 4              )               : choke1   #      . . x . . x . .    Local median
  909.                                                                                                                      
  910.     choke1 =                        choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel  \
  911.     choke1 = (ed > 1)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . x x x x x x    1 pixel   | Reflate again
  912.     choke1 = (ed > 4)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . x x x    1 pixel  /
  913.  
  914.     # Over-dilation - extra reflation up to about 1 pixel
  915.     choke1 = (od == 0)            ? choke1 : \
  916.              (od == 1)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ) : \
  917.              (od == 2)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ).QTGMC_inflate( U=RCrg,V=RCrg ) : \
  918.                                     choke1.mt_expand ( U=RCrg,V=RCrg )
  919.  
  920.     # Areas of negative difference (similar to above)
  921.     choke2 =                        diff.  mt_expand( mode="vertical", U=RCrg,V=RCrg )        
  922.     choke2 = (ed > 2)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  923.     choke2 = (ed > 5)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  924.     choke2 = (ed % 3 != 0)        ? choke2.QTGMC_inflate( U=RCrg,V=RCrg )              : choke2
  925.     choke2 = (ed == 2 || ed == 5) ? choke2.RemoveGrain( 4              )               : choke2
  926.     choke2 =                        choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg )
  927.     choke2 = (ed > 1)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  928.     choke2 = (ed > 4)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  929.     choke2 = (od == 0)            ? choke2 : \
  930.              (od == 1)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg )  : \
  931.              (od == 2)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg ).QTGMC_deflate( U=RCrg,V=RCrg ) : \
  932.                                     choke2.mt_inpand ( U=RCrg,V=RCrg )
  933.  
  934.     # Combine above areas to find those areas of difference to restore
  935.     restore = diff.mt_lutxy( choke1, "x 129 < x y 128 < 128 y ? ?", U=RCrg,V=RCrg ).mt_lutxy( choke2, "x 127 > x y 128 > 128 y ? ?", U=RCrg,V=RCrg )
  936.  
  937.     return Input.mt_adddiff( restore, U=RCrgo,V=RCrgo )
  938. }
  939.  
  940.  
  941. # Given noise extracted from an interlaced source (i.e. the noise is interlaced), generate "progressive" noise with a new "field" of noise injected. The new
  942. # noise is centered on a weighted local average and uses the difference between local min & max as an estimate of local variance
  943. # YUY2 clip input is planar, but must pass interleaved version of clip to setup noise
  944. function QTGMC_Generate2ndFieldNoise( clip Input, clip InterleavedClip, bool "ChromaNoise" )
  945. {
  946.     # >>>> YUY2 is planar here. Noise is generated (AddGrainC) interleaved, but immediately made planar
  947.     ChromaNoise = default( ChromaNoise, false )
  948.     CNmt1 = ChromaNoise ? 3 : 1
  949.     origNoise = Input.SeparateFields()
  950.     noiseMax  = origNoise.mt_expand( mode="square", U=CNmt1,V=CNmt1 ).mt_expand( mode="horizontal", U=CNmt1,V=CNmt1 )
  951.     noiseMin  = origNoise.mt_inpand( mode="square", U=CNmt1,V=CNmt1 ).mt_inpand( mode="horizontal", U=CNmt1,V=CNmt1 )
  952.     random    = BlankClip( InterleavedClip.SeparateFields(), color_yuv=$808080 ).AddGrainC( var=1800, uvar=ChromaNoise ? 1800 : 0 )
  953.     random    = InterleavedClip.IsYUY2() ? random.converttoyv16() : random
  954.     varRandom = mt_makediff( noiseMax, noiseMin, U=CNmt1,V=CNmt1 ).mt_lutxy( random, "x 128 - y * 256 / 128 +", U=CNmt1,V=CNmt1)
  955.     newNoise  = noiseMin.mt_adddiff( varRandom, U=CNmt1,V=CNmt1 )
  956.     return Interleave( origNoise, newNoise ).Weave()
  957. }
  958.  
  959.  
  960. # Insert the source lines into the result to create a true lossless output. However, the other lines in the result have had considerable processing and won't
  961. # exactly match source lines. There will be some slight residual combing. Use vertical medians to clean a little of this away
  962. function QTGMC_MakeLossless( clip Input, clip Source, int InputType )
  963. {
  964.     Assert( InputType != 1, "Lossless modes are incompatible with InputType=1" )
  965.  
  966.     # >>>> YUY2: 'Input' is planar, 'Source' is interleaved (changed to planar here for processing) - returns planar result
  967.  
  968.     # Weave the source fields and the "new" fields that have generated in the input
  969.     srcFields1 = (InputType == 0) ? Source.SeparateFields() : Source.SeparateFields().SelectEvery( 4, 0,3 )
  970.     srcFields  = Source.IsYUY2() ? srcFields1.converttoyv16() : srcFields1
  971.     newFields  = Input.SeparateFields().SelectEvery( 4, 1,2 )
  972.     processed  = Interleave( srcFields, newFields ).SelectEvery(4, 0,1,3,2 ).Weave()
  973.  
  974.     # Clean some of the artefacts caused by the above - creating a second version of the "new" fields
  975.     vertMedian  = processed.VerticalCleaner( mode=1 )
  976.     vertMedDiff = mt_makediff( processed, vertMedian, U=3,V=3 )
  977.     vmNewDiff1  = vertMedDiff.SeparateFields().SelectEvery( 4, 1,2 )
  978.     vmNewDiff2  = vmNewDiff1.VerticalCleaner( mode=1 ).mt_lutxy( vmNewDiff1, "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 )
  979.     vmNewDiff3  = vmNewDiff2.Repair( vmNewDiff2.RemoveGrain( 2 ), 1 )
  980.  
  981.     # Reweave final result
  982.     return Interleave( srcFields, newFields.mt_makediff( vmNewDiff3, U=3,V=3 )).SelectEvery( 4, 0,1,3,2 ).Weave()
  983. }
  984.  
  985.  
  986. # Source-match, a three stage process that takes the difference between deinterlaced input and the original interlaced source, to shift the input more towards
  987. # the source without introducing shimmer. All other arguments defined in main script
  988. function QTGMC_ApplySourceMatch( clip Deinterlace, int InputType, val Source, val bVec1, val fVec1, val bVec2, val fVec2, \
  989.                                  int SubPel, int SubPelInterp, int hpad, int vpad, int ThSAD1, int ThSCD1, int ThSCD2, int SourceMatch, \
  990.                                  int MatchTR1, string MatchEdi, int MatchNNSize, int MatchNNeurons, int MatchEdiQual, int MatchEdiMaxD,\
  991.                                  int MatchTR2, string MatchEdi2, int MatchNNSize2, int MatchNNeurons2, int MatchEdiQual2, int MatchEdiMaxD2, \
  992.                                  float MatchEnhance, int EdiThreads, bool lsb )
  993. {
  994.     # >>>> YUY2: 'Deinterlace' is planar, 'Source' is interleaved (changed to planar here for all processing except interpolation) - returns planar result
  995.     yuy2 = Source.IsYUY2()
  996.     Source = yuy2 ? Source.converttoyv16() : Source
  997.  
  998.     # Basic source-match. Find difference between source clip & equivalent fields in interpolated/smoothed clip (called the "error" in formula below). Ideally
  999.     # there should be no difference, we want the fields in the output to be as close as possible to the source whilst remaining shimmer-free. So adjust the
  1000.     # *source* in such a way that smoothing it will give a result closer to the unadjusted source. Then rerun the interpolation (edi) and binomial smooth with
  1001.     # this new source. Result will still be shimmer-free and closer to the original source.
  1002.     # Formula used for correction is P0' = P0 + (P0-P1)/(k+S(1-k)), where P0 is original image, P1 is the 1st attempt at interpolation/smoothing , P0' is the
  1003.     # revised image to use as new source for interpolation/smoothing, k is the weighting given to the current frame in the smooth, and S is a factor indicating
  1004.     # "temporal similarity" of the error from frame to frame, i.e. S = average over all pixels of [neighbor frame error / current frame error] . Decreasing
  1005.     # S will make the result sharper, sensible range is about -0.25 to 1.0. Empirically, S=0.5 is effective [will do deeper analysis later]
  1006.     errorTemporalSimilarity = 0.5  # S in formula described above
  1007.     errorAdjust1   = Select( MatchTR1, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1008.     match1Clip     = (SourceMatch < 1 || InputType == 1) ? Deinterlace : Deinterlace.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1009.     match1Update   = (SourceMatch < 1 || MatchTR1 == 0) \
  1010.                         ? Source : mt_lutxy( Source, match1Clip, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 )
  1011.     noyv16ma1Edi   = MatchEdi =="NNEDI2" || MatchEdi =="NNEDI" || MatchEdi =="EEDI3+NNEDI3" || MatchEdi =="EEDI3" || MatchEdi =="EEDI2" || MatchEdi =="TDeint" || MatchEdi =="cYadif" || MatchEdi =="RepcYadif"
  1012.     noyv16ma2Edi   = MatchEdi2=="NNEDI2" || MatchEdi2=="NNEDI" || MatchEdi2=="EEDI3+NNEDI3" || MatchEdi2=="EEDI3" || MatchEdi2=="EEDI2" || MatchEdi2=="TDeint" || MatchEdi2=="cYadif" || MatchEdi2=="RepcYadif"
  1013.     match1Edi      = (SourceMatch == 0) ? NOP() : \
  1014.     !noyv16ma1Edi || !yuy2 ? match1Update.QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) : \
  1015.                              match1Update.ConvertToYUY2() \
  1016.                                          .QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) \
  1017.                                          .ConvertToYv16()
  1018.     match1Super    = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1019.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MDegrain1( match1Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1020.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? match1Edi.MDegrain1( match1Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1021.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) && lsb ? match1Degrain1.ditherpost(mode=6, slice=false) : match1Degrain1
  1022.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) && lsb ? match1Degrain2.ditherpost(mode=6, slice=false) : match1Degrain2
  1023.     match1         = (SourceMatch < 1) ? Deinterlace : \
  1024.                      (MatchTR1 == 0)   ? match1Edi : \
  1025.                      (MatchTR1 == 1)   ? match1Degrain1.Merge( match1Edi, 0.25 ) : \
  1026.                                          match1Degrain1.Merge( match1Degrain2, 0.2 ).Merge( match1Edi, 0.0625 )
  1027.  
  1028.     # Enhance effect of source-match stages 2 & 3 by sharpening clip prior to refinement (source-match tends to underestimate so this will leave result sharper)
  1029.     match1Shp = (SourceMatch > 1 && MatchEnhance > 0.0) ? match1.mt_lutxy( match1.RemoveGrain( 12 ), "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 ) : match1
  1030.  
  1031.     # Source-match refinement. Find difference between source clip & equivalent fields in (updated) interpolated/smoothed clip. Interpolate & binomially smooth
  1032.     # this difference then add it back to output. Helps restore differences that the basic match missed. However, as this pass works on a difference rather than
  1033.     # the source image it can be prone to occasional artefacts (difference images are not ideal for interpolation). In fact a lower quality interpolation such
  1034.     # as a simple bob often performs nearly as well as advanced, slower methods (e.g. NNEDI3)
  1035.     match2Clip     = (SourceMatch < 2 || InputType == 1) ? match1Shp : match1Shp.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1036.     match2Diff     = (SourceMatch > 1) ? mt_makediff( Source, match2Clip, U=3,V=3 ) : NOP()
  1037.     match2Edi      = (SourceMatch <= 1) ? NOP() : \
  1038.     !noyv16ma2Edi || !yuy2 ? match2Diff.QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) : \
  1039.                              match2Diff.ConvertToYUY2() \
  1040.                                        .QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) \
  1041.                                        .ConvertToYv16()
  1042.     match2Super    = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1043.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MDegrain1( match2Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1044.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? match2Edi.MDegrain1( match2Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1045.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) && lsb ? match2Degrain1.ditherpost(mode=6, slice=false) : match2Degrain1
  1046.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) && lsb ? match2Degrain2.ditherpost(mode=6, slice=false) : match2Degrain2
  1047.     match2         = (SourceMatch < 2) ? match1 : \
  1048.                      (MatchTR2 == 0)   ? match2Edi : \
  1049.                      (MatchTR2 == 1)   ? match2Degrain1.Merge( match2Edi, 0.25 ) : \
  1050.                                          match2Degrain1.Merge( match2Degrain2, 0.2 ).Merge( match2Edi, 0.0625 )
  1051.  
  1052.     # Source-match second refinement - correct error introduced in the refined difference by temporal smoothing. Similar to error correction from basic step
  1053.     errorAdjust2   = Select( MatchTR2, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1054.     match3Update   = (SourceMatch < 3 || MatchTR2 == 0) \
  1055.                          ? match2Edi : mt_lutxy( match2Edi, match2, "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 )
  1056.     match3Super    = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1057.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MDegrain1( match3Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1058.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? match3Update.MDegrain1( match3Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1059.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) && lsb ? match3Degrain1.ditherpost(mode=6, slice=false) : match3Degrain1
  1060.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) && lsb ? match3Degrain2.ditherpost(mode=6, slice=false) : match3Degrain2
  1061.     match3         = (SourceMatch < 3) ? match2 : \
  1062.                      (MatchTR2 == 0)   ? match3Update : \
  1063.                      (MatchTR2 == 1)   ? match3Degrain1.Merge( match3Update, 0.25 ) : \
  1064.                                          match3Degrain1.Merge( match3Degrain2, 0.2 ).Merge( match3Update, 0.0625 )
  1065.  
  1066.     # Apply difference calculated in source-match refinement
  1067.     return (SourceMatch < 2) ? match1 : match1Shp.mt_adddiff( match3, U=3,V=3 )
  1068. }
  1069.  
  1070.  
  1071. # Set global variable called "Prefix_Name" to "Value". Throws exception if global already exists unless Replace=true, in which case the global is overwritten
  1072. function QTGMC_SetUserGlobal( string Prefix, string Name, val Value, bool "Replace" )
  1073. {
  1074.     Replace = default( Replace, false )
  1075.     globalName = Prefix + "_" + Name
  1076.  
  1077.     # Tricky logic to check global: enter catch block if Replace=true *or* globalName doesn't exist (i.e. need to set the global), the exception is not rethrown
  1078.     # Not entering catch block means that Replace=false and global exists - so it throws an exception back to AviSynth
  1079.     try { Assert( !Replace && defined(Eval(globalName)) ) }
  1080.     catch (e)
  1081.     {
  1082.         Eval( "global " + globalName + " = Value" )
  1083.         Replace = true
  1084.     }
  1085.     Assert( Replace, """Multiple calls to QTGMC, set PrevGlobals="Replace" or read documentation on 'Multiple QTGMC Calls'""" )
  1086. }
  1087.  
  1088. # Return value of global variable called "Prefix_Name". Returns NOP() if it doesn't exist or Reuse is false
  1089. function QTGMC_GetUserGlobal( string Prefix, string Name, bool "Reuse" )
  1090. {
  1091.     Reuse = default( Reuse, false )
  1092.     globalName = Prefix + "_" + Name
  1093.  
  1094.     try       { ret = Reuse ? Eval( globalName ) : NOP() }
  1095.     catch (e) { ret = NOP() }
  1096.     return ret
  1097. }
Advertisement
Add Comment
Please, Sign In to add comment
Public Pastes
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!