alakajam 1

x = 2: y = 0
DO
  CLS
  COLOR 15
  PRINT "DAY OFF WORK : The Adventure"
  PRINT "----------------------------"
  IF x = 2 AND y = 0 THEN
    COLOR 8: PRINT "Written by sorceress, for Alakajam #01, September 2017."
    COLOR 15: PRINT
  END IF
  SELECT CASE x + y * 3
    CASE 0: PRINT "You are in the hills."
      IF water > 0 THEN
        PRINT "You are quite thirsty climbing these hills and stop for a drink.": water = water - 1
        IF drunk = 1 THEN PRINT "The fresh air and water clear your head.": drunk = 0
      END IF
    CASE 1: PRINT "You are in a small village. There is a shop here."
      INPUT "Would you like to purchase a weapon? [Y/N]"; a$
      IF a$ = "Y" OR a$ = "y" THEN
        IF gold > 0 THEN
          PRINT "You bought a weapon for 1 gold."
          gold = gold - 1
          weapon = weapon + 1
        ELSE
          PRINT "You have no gold."
        END IF
      ELSE
        PRINT "Ok, whatever."
      END IF
    CASE 2: PRINT "You are in your home in a small village."
      PRINT "Since it's your day off work, you are thinking about that quest..."
      PRINT "The village is plagued by a firey dragon."
      INPUT "Would you like to go on a quest? [Y/N]"; a$
      PRINT "Ok then!"
    CASE 3: PRINT "You are in a meadow near to a forest."
      PRINT "You see a philosopher's stone here, reputed for it's alchemical power!"
      IF lead = 0 AND water = 0 THEN PRINT "Though it doesn't seem to do anything."
      IF lead > 0 THEN PRINT "Your LEAD turns to GOLD in your hands!": gold = gold + lead: lead = 0
      IF water = 1 AND wine = 0 THEN PRINT "Your WATER turns to WINE in your flask!": water = 0: wine = 1
    CASE 4: PRINT "You are in a forest. Beware of bears!"
      IF wine > 0 THEN
        PRINT "To suppress your fear of bears, you decide to imbibe your wine."
        PRINT "Nothing like being drunk in the middle of a forest!"
        wine = wine - 1: drunk = 1
      END IF
    CASE 5: PRINT "You arrive at a lake. The water is quite still."
      IF water = 0 AND wine = 0 THEN PRINT "You fill up your water flask while you are here.": water = 1
    CASE 6: PRINT "You approach the slopes of a dormant volcano."
      PRINT " 'This must be where the dragon lives', you think."
      IF drunk = 0 THEN
        PRINT "Realising this makes you feel very scared."
        PRINT "Like the coward you are, you make your way back down the slopes."
      ELSE
        PRINT "A DRAGON swoops down to attack!"
        IF weapon = 1 THEN
          PRINT "You draw your WEAPON and stick it up."
          PRINT "The DRAGON stops his firey attack to admire it, then says..."
          PRINT " 'Wow! Can I have that?'"
          INPUT "Do you want to give your weapon to the DRAGON? [Y/N]"; a$
          IF a$ = "Y" OR a$ = "y" THEN
            weapon = 0
            PRINT "You give away your only weapon."
          ELSE
            PRINT "The DRAGON lunges, and you lunge back. It goes on..."
            PRINT "Long story short : you win the battle!"
            gameover = 1
          END IF
        END IF
        IF weapon > 1 THEN
          PRINT "You draw one of your WEAPONS and stick it up."
          PRINT "The DRAGON is scared and flies back up the volcano."
          PRINT "You must be too intimidating with all these weapons you came with."
          PRINT " 'What to do now?', you ask yourself."
        END IF
        IF weapon = 0 THEN
          PRINT "Since you do not have a weapon, the DRAGON is without fear."
          PRINT "Before you can scream you are eaten."
          PRINT "The last thing you hear before death are your bones crunching."
          gameover = 2
        END IF
      END IF
    CASE 7: PRINT "You are in a swamp. Not the nicest of places to visit on your day off."
      IF weapon = 1 THEN PRINT "Oh dear, you lost your only weapon in the mud."
      IF weapon > 1 THEN PRINT "Oh dear, you lost one of your weapons in the mud."
      IF weapon > 0 THEN weapon = weapon - 1
    CASE 8: PRINT "You are in a cave. You found some LEAD here.": lead = lead + 1
  END SELECT
  PRINT "------------------------------------"

  IF gameover = 1 THEN
    COLOR 10
    PRINT
    PRINT "YOU HAVE WON!"
    PRINT "... Or was it all just a drunken dream?"
    PRINT
    PRINT "Find out in our next adventure!"
    SLEEP
    END
  END IF
  IF gameover = 2 THEN
    COLOR 12
    PRINT
    PRINT "YOU HAVE DIED!"
    PRINT
    PRINT "THAT MEANS GAME OVER"
    SLEEP
    END
  END IF

  COLOR 11
  PRINT
  PRINT "You are carrying:"
  IF lead > 0 THEN PRINT lead; "x LEAD"
  IF gold > 0 THEN PRINT gold; "x GOLD"
  IF weapon > 0 THEN PRINT weapon; "x WEAPON"
  IF water > 0 THEN PRINT water; "x WATER"
  IF wine > 0 THEN PRINT wine; "x WINE"

  IF drunk = 1 THEN
    COLOR 12
    PRINT
    PRINT "You are currently intoxicated."
  END IF

  COLOR 14
  PRINT
  a$ = ""
  IF y > 0 THEN a$ = a$ + " NORTH,"
  IF y < 2 THEN a$ = a$ + " SOUTH,"
  IF x < 2 THEN a$ = a$ + " EAST,"
  IF x > 0 THEN a$ = a$ + " WEST,"
  PRINT "Exits are: " + a$
  INPUT "[N/S/E/W]"; a$

  COLOR 12
  IF a$ = "N" OR a$ = "n" THEN
    IF y > 0 THEN y = y - 1 ELSE PRINT "You try, but you can't find a path to the north."
  END IF
  IF a$ = "S" OR a$ = "s" THEN
    IF y < 2 THEN y = y + 1 ELSE PRINT "You try, but you can't find a path to the south."
  END IF
  IF a$ = "E" OR a$ = "e" THEN
    IF x < 2 THEN x = x + 1 ELSE PRINT "You try, but you can't find a path to the east."
  END IF
  IF a$ = "W" OR a$ = "w" THEN
    IF x > 0 THEN x = x - 1 ELSE PRINT "You try, but you can't find a path to the west."
  END IF

LOOP