@echo off

@rem -------------------------------------------
@rem DB接続パラメータ
@rem -------------------------------------------
set HOST=localhost
set PORT=5432
set USER=<ユーザ名>
set PASSWORD=<パスワード>
set DATABASE=<データベース名>

@rem -------------------------------------------
@rem PostgreSQL環境変数
@rem -------------------------------------------
set PGCLIENTENCODING=<SQLファイルのエンコーディング (UTF8, SJIS...)>

@rem -------------------------------------------
@rem DB接続パスワードファイル作成
@rem -------------------------------------------
set MAKE_PGDIR=0
pushd %APPDATA%
if exist "postgresql\pgpass.conf" (
    pushd "postgresql"
    rename "pgpass.conf" "pgpass.conf.bk"
    popd
) else (
    if not exist "postgresql" (
        mkdir "postgresql"
        set MAKE_PGDIR=1
    )
)
(echo %HOST%:%PORT%:*:%USER%:%PASSWORD%) > "postgresql\pgpass.conf"
popd

@rem -------------------------------------------
@rem SQL実行（カレントフォルダのsqlファイル）
@rem -------------------------------------------
for /F "usebackq" %%i in (`dir /B /ON "*.sql"`) do (
    echo [%%i]
    psql -h %HOST% -p %PORT% -d %DATABASE% -U %USER% -f %%i
    echo.
    echo.
)

@rem -------------------------------------------
@rem DB接続パスワードファイル削除
@rem -------------------------------------------
pushd "%APPDATA%\postgresql"
    del "pgpass.conf"
    if exist "pgpass.conf.bk" (
        rename "pgpass.conf.bk" "pgpass.conf"
    )
popd
if %MAKE_PGDIR% == 1 (
    rmdir "%APPDATA%\postgresql"
)

pause