GetFilePointer

; FAT
FILE_START      equ 4000h   ; Start of FAT
FILE_NULL       equ 0
FILE_DELETED_F      equ 1
FILE_DELETED_D      equ 2
;FILE_DELETED_S     equ 3
FILE_FILE       equ 4
FILE_DIRECTORY      equ 5
;FILE_SYMLINK       equ 6
FILE_END        equ 7
; Error codes
SUCCCESS        equ 0
FIND_FOUND      equ 0
ALLOCATE_SUCCESS    equ 0
ERROR           equ 1
FIND_MISSING        equ 1
ALLOCATE_OUT_OF_MEM equ 1
CORRUPT         equ 2
MEMORY_CORRUPT      equ 2
FIND_MEMORY_CORRUPT equ 2

; returns the pointer to the file from the path in de
; outputs   de = pointer to file
;       bc = length of file
;       a  = status code
;       h  = flash page
GetFilePointer:
    ld a, 1 ; Set flash page 1 in bank 2.
    out (6), a
    push de
    ld hl,(FILE_START)
    ld de,FILE_START
    or a
    sbc hl,de
        jr z,_ ; if they are the same no corruption
    ; corruption error here
    ld a,FIND_MEMORY_CORRUPT
    pop de
    ret

_   pop de ; memory is fine here
    ld hl,FILE_START
_DirLoop:
    call ContainsSlash
;       jr nz, ; Directory in path
        jr nz, _FileSearch ; no directory in path
    ;handle directory searching here
    ld a, (hl)
    cp FILE_END ; End of table
        ret z ; Not found
    cp FILE_DIRECTORY ; Directory
        jr z, _CheckDirectory
    cp FILE_FILE
        ret nz ; don't handle anything else for now
    call SkipFileEntry
    jr _DirLoop
_CheckDirectory:
    inc hl
    call DirectoryCompare
        jr nz, _DirNotFound
    ; Directory found :D
    ; Move DE past the directory, and move on
    inc de
    jr _DirLoop
_DirNotFound:
    call SkipDirEntry
    jr _DirLoop
_FileSearch:
    ld a,(hl)   ;get File type
    cp FILE_END ; End of table
        ret z ; Not found
    cp FILE_FILE ; File
        jr z, _FileCheck
    cp FILE_DIR
        ret nz ; don't handle other types for now
    call SkipDirEntry
    jr _FileSearch
_FileCheck:
    push de
        call CmpStrings
    pop de
    jr z, _
    call SkipFileEntry
    jr _FileSearch
_   call SkipEntryName  ; Found file
    inc hl
    ld a, (hl) ; Flash page into A
    inc hl
    ld e, (hl)
    inc hl
    ld d, (hl) ; Location in DE
    inc hl
    ld c, (hl)
    inc hl
    ld b, (hl) ; Size in BC
    out (6), a ; Set flash page
    ld h,a
    ld a,FIND_FOUND ; Give the right Return code
    ret
;
SkipDirEntry:
    call SkipEntryName
    inc hl \ inc hl ; pass the Dir ID
    ret
;
SkipFileEntry:
    call SkipEntryName
    push de \ ld de,7 \ add hl,de \ pop de  ; skip the rest of the data
    ret
SkipEntryName:
    ld a, 0
    push bc
        ld bc, 0FFFFh
        cpir    ; Move HL to the end of the name
    pop bc
    ret
; inputs    de = Pointer to path
; outputs   z  = true
;       nz = false
ContainsSlash:
    push de
_       ld a, (de)
        cp '/'
        jr z, ++_
        or a
        jr z, _
        inc de
        jr -_
_   cp 1
_   pop de
    ret
; checks to see if the directory exists
DirectoryCompare:
        ld a, (de)
        cp 0
        jr z,_
        cp '/'
            jr z,_
        cp (hl)
            ret nz
        inc hl
        inc de
        jr DirectoryCompare
_   ld a, (hl)
    cp 0
        ret z
    cp 1
    ret
; Input: HL and DE are strings
; Output: Z if equal, NZ otherwise
CmpStrings:
    ld a, (de)
    cp 0
    jr z, CmpStringsEoS
    cp (hl)
    ret nz
    inc hl
    inc de
    jr CmpStrings
CmpStringsEoS:
    ld a, (hl)
    cp 0
    ret

FATTable:
    dw FILE_START           ; Type ID = Start of flash

    db FILE_DIRECTORY       ; Type ID = Folder
    db "root",0         ; Folder name
    dw 0                ; Directory ID (word)

    db FILE_FILE            ; Type ID = File
    db "boot.txt", 0        ; File name
    db 01h              ; Flash page
    dw BootText         ; Pointer to data (word)
    dw BootTextEnd-BootText     ; Length (word)
    dw 0                ; Directory ID (word)

    db FILE_END         ;end of FAT