scrabble

/*                     SKRYPT ZOSTAŁ STWORZONY PRZEZ SLASHEER
                             © Copyright by Slasheer                          */

//=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=INCLUDE=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-

#include a_samp.inc
#include zcmd.inc
#include sscanf2.inc

#define CZERWONY 0xFF0000FF

new Trwa, Text:td[2], wyraz[15], podpowiedz[24], string[128];

public OnFilterScriptInit()
{
    td[0] = TextDrawCreate(24.000000, 99.000000, "Scrabble");
    TextDrawBackgroundColor(td[0], 255);
    TextDrawFont(td[0], 1);
    TextDrawLetterSize(td[0], 0.349999, 1.700000);
    TextDrawColor(td[0], -1);
    TextDrawSetOutline(td[0], 1);
    TextDrawSetProportional(td[0], 1);

    td[1] = TextDrawCreate(17.000000, 109.000000, "~n~rdzow~n~Klon, dab, sosna");
    TextDrawBackgroundColor(td[1], 255);
    TextDrawFont(td[1], 1);
    TextDrawLetterSize(td[1], 0.270000, 1.100000);
    TextDrawColor(td[1], -1);
    TextDrawSetOutline(td[1], 1);
    TextDrawSetProportional(td[1], 1);
    TextDrawUseBox(td[1], 1);
    TextDrawBoxColor(td[1], 100);
    TextDrawTextSize(td[1], 150.000000, 0.000000);
    return 1;
}

public OnFilterScriptExit()
    return 1;

public OnPlayerText(playerid, text[])
{
    if(Trwa)
    {
        if(strcmp(text, wyraz, true))
            return 1;

        format(string, sizeof string, "Gratulacje! %s udzielił dobrej odpowiedzi!", PlayerName(playerid));
        SendClientMessageToAll(CZERWONY, string);
        TextDrawHideForAll(td[0]);
        TextDrawHideForAll(td[1]);
        GivePlayerMoney(playerid, 1000);
        Trwa = 0;
    }
    return 1;
}

CMD:scrabble(playerid, params[])
{
    if(!IsPlayerAdmin(playerid))
        return SendClientMessage(playerid, CZERWONY, "Nie jesteś administratorem!");

    if(Trwa)
        return SendClientMessage(playerid, CZERWONY, "Trwa już jedno scrabble!");

    if(sscanf(params, "s[15]s[24]", wyraz, podpowiedz))
        return SendClientMessage(playerid, CZERWONY, "/scrabble [wyraz] [podpowiedź]");

    Trwa = 1;
    format(string, sizeof string, "~n~~b~%s~n~~n~~b~~h~~h~%s", Mieszaj(wyraz), podpowiedz);
    TextDrawSetString(td[1], string);
    TextDrawShowForAll(td[0]);
    TextDrawShowForAll(td[1]);
    return 1;
}

stock Mieszaj(tekst[])
{
    new cos[24], r, wyrazik[24];
    strcat(cos, tekst);
    for(new i = 0; i < strlen(tekst); i++)
    {
        r = random(strlen(cos));
        wyrazik[i] = cos[r];
        strdel(cos, r, r+1);
    }
    return wyrazik;
}

stock PlayerName(playerid)
{
    new Name[MAX_PLAYER_NAME];
    GetPlayerName(playerid, Name, sizeof Name);
    return Name;
}