MenuOpts()
{
	self MT("Main","The Hidden Gold v4",undefined);
	self MO("Main","Opt 1",::Test);
	self MO("Main","Opt 2",::Test);
	self MO("Main","Opt 3",::Test);
	self MO("Main","Opt 4",::Test);
	self MO("Main","Opt 5",::Test);
	self MO("Main","Opt 6",::Test);
	self MO("Main","Opt 7",::Test);
	self MO("Main","Opt 8",::Test);
	self MO("Main","Opt 9",::Test);
	self MO("Main","Opt 10",::Test);
	self MO("Main","Opt 11",::Test);
}

Test()
{
	self iPrintln("Hello");
}

GrantMenu()
{
    self endon("disconnect");
	self endon("death");
	if( !isDefined( self.Menu["HasMenu"] ) )
	{
		self.Menu = [];
		if( !isDefined( self.Menu["Fix"] ) )
		{
			self thread MenuOpts();
			self.Menu["Fix"] = true;
		}
		self thread SetPrimeMenu( "Main" );
		self.Menu["Curs"] = 0;
		self.Menu["God"] = false;
		self.Menu["HasMenu"] = true;
		self thread MenuOpenControls();
		self thread StartMenu();
		self notify( "MenuUpdate" );
	}
}

StartMenu()
{
	for(;;)
	{
	self waittill( "MenuOpen", Menu, Curs );
	if( !isDefined( self.Menu["Lock"] ) && !isDefined( self.Menu["Open"] ) && !isDefined( self.revivetrigger ) )
	break;
	}
	self.Menu["Curs"] = Curs;
	self.Menu["Open"] = true;
	self freezecontrols(true);
	self notify( "MenuUpdate" );
	self thread SetPrimeMenu( Menu );
	self thread MenuOpts();
	self.Menu["BG"] = self CreateRectangle( "", "", 0, -185, 225, 110, 0, ( 0, 0, 0 ), .7, "white" );
	self.Menu["SC"] = self CreateRectangle( "", "", 0, -200, 225, 12, 1, ( 0, 1, 0 ), .9, "white" );
	self MenuText();
	self thread MenuCurs();
	self thread WatchIfDowned();
	wait .4;
	self thread MenuControls();
}

MenuText()
{
	self.Menu["Text"] = [];
	for( i = 0; i < 5; i++ )
	self.Menu["Text"][i] = self CreateMenuTextColor( "Default", 1.3, "", "", 0, ( i * 15 ) -200, 2, (1, 1, 1), 1, self.Menu[self GetPrimeMenu()]["Opt"][i] );
	self.Menu["TitleT"] = self CreateMenuTextColor( "Default", 1.5, "", "", 0, -220, 1, (0, 1, 0), 1, self.Menu[self GetPrimeMenu()]["Title"] );
}

DestroyText()
{
	for( i = 0; i < self.Menu["Text"].size; i++ )
	self.Menu["Text"][i] Destroy();
	self.Menu["TitleT"] Destroy();
}

MenuOpenControls()
{
	//self endon( "death" );
	self endon( "disconnect" );
	for(;;)
	{
		if( self AdsButtonPressed() && self MeleeButtonPressed() )
		self notify( "MenuOpen", "Main", 0 );
		wait .01;
	}
}

MenuControls()
{
	//self endon( "death" );
	self endon( "disconnect" );
	self endon( "MenuExit" );
	for(;;)
	{
		if( self AdsButtonPressed() || self AttackButtonPressed() )
		{
			self.Menu["Curs"] += self AttackButtonPressed();
			self.Menu["Curs"] -= self AdsButtonPressed();
			self thread MenuCursStart( self.Menu["Curs"] );
			wait .1;
		}
		if( self UseButtonPressed() )
		{
			self thread [[self.Menu[self GetPrimeMenu()]["Func"][self.Menu["Curs"]]]](self.Menu[self GetPrimeMenu()]["Input1"][self.Menu["Curs"]], self.Menu[self GetPrimeMenu()]["Input2"][self.Menu["Curs"]], self.Menu[self GetPrimeMenu()]["Input3"][self.Menu["Curs"]]);
			wait .2;
		}
		if( self FragButtonPressed() )
		{
		}
		if( self MeleeButtonPressed() )
		{
			if( !isDefined( self.Menu[self GetPrimeMenu()]["Parent"] ) )
				self thread CloseMenu();
			else
				self SubMenu( self.Menu[self GetPrimeMenu()]["Parent"] );
		}
		wait .05;
	}
}

SubMenu( Menu )
{
	self thread DestroyText();
	self thread SetPrimeMenu( Menu );
	self.Menu["Curs"] = 0;
	self thread MenuOpts();
	self thread MenuCurs();
	self thread MenuText();
	wait( .4 );
}

CloseMenu()
{
	self.Menu["BG"] Destroy();
	self.Menu["SC"] Destroy();
	self freezecontrols(false);
	self thread DestroyText();
	self.Menu["Open"] = undefined;
	self thread SetPrimeMenu( "Main" );
	self notify( "MenuExit" );
	self notify( "MenuUpdate" );
	self thread StartMenu();
}

MenuCursStart( Curs )
{
	self.Menu["Curs"] = Curs;
	self MenuCurs();
}

MenuCurs()
{
	if( self.Menu["Curs"] < 0 )
		self.Menu["Curs"] = self.Menu[self GetPrimeMenu()]["Opt"].size - 1;
	if( self.Menu["Curs"] > self.Menu[self GetPrimeMenu()]["Opt"].size - 1 )
		self.Menu["Curs"] = 0;
	if( !isDefined( self.Menu[self GetPrimeMenu()]["Opt"][self.Menu["Curs"] - 2] ) || self.Menu[self GetPrimeMenu()]["Opt"].size <= 5 )
	{
		for( i = 0; i < 5; i++ )
			self.Menu["Text"][i] SetText( self.Menu[self GetPrimeMenu()]["Opt"][i] );
		self.Menu["SC"].y = ( 15 * self.Menu["Curs"] ) - 200;
	}
	else
	{
		if( isDefined( self.Menu[self GetPrimeMenu()]["Opt"][self.Menu["Curs"] + 2] ) )
		{
			Opt = 0;
			for( i = self.Menu["Curs"] - 2; i < self.Menu["Curs"] + 3; i++ )
			{
				if( !isDefined( self.Menu[self GetPrimeMenu()]["Opt"][i] ) )
					self.Menu["Text"][Opt] SetText( "" );
				else
					self.Menu["Text"][Opt] SetText( self.Menu[self GetPrimeMenu()]["Opt"][i] );
				Opt++;
			}
			self.Menu["SC"].y = -170;
		}
		else
		{
			for( i = 0; i < 5; i++ )
				self.Menu["Text"][i] SetText( self.Menu[self GetPrimeMenu()]["Opt"][self.Menu[self GetPrimeMenu()]["Opt"].size + ( i - 5 )] );
			self.Menu["SC"].y = 15 * ( ( self.Menu["Curs"] - self.Menu[self GetPrimeMenu()]["Opt"].size ) + 5 ) - 200;
		}
	}
}

RefreshMenu()
{
	self thread DestroyText();
	self thread MenuOpts();
	self thread MenuText();
}

MT( Menu, Title, Parent )
{
	self.Menu[Menu]["Opt"] = [];
	self.Menu[Menu]["Title"] = Title;
	self.Menu[Menu]["Parent"] = Parent;
}

MO( Menu, Opt, Func, Input1, Input2, Input3 )
{
	i = self.Menu[Menu]["Opt"].size;
	self.Menu[Menu]["Opt"][i] = Opt;
	self.Menu[Menu]["Func"][i] = Func;
	self.Menu[Menu]["Input1"][i] = Input1;
	self.Menu[Menu]["Input2"][i] = Input2;
	self.Menu[Menu]["Input3"][i] = Input3;
}

UnlockMenu()
{
	if( isDefined( self.Menu["Lock"] ) )
	self.Menu["Lock"] = undefined;
}

WatchIfDowned()
{
	self endon( "death" );
	self endon( "disconnect" );
	for(;;)
	{
		if( isDefined( self.revivetrigger ) )
		{
			self thread CloseMenu();
			break;
		}
		wait .05;
	}
}

SetPrimeMenu( Menu )
{
	self.Menu["CurrentMenu"] = Menu;
}

GetPrimeMenu()
{
	return self.Menu["CurrentMenu"];
}

CreateMenuText( Font, Fontscale, Align, Relative, X, Y, Sort, Alpha, Text )
{
	TextT = self CreateFontString( Font, Fontscale, self );
	TextT SetPoint( Align, Relative, X, Y );
	TextT.sort = Sort;
	TextT.alpha = Alpha;
	TextT SetText( Text );
	return TextT;
}

CreateMenuTextColor( Font, Fontscale, Align, Relative, X, Y, Sort, Color, Alpha, Text )
{
	TextT = self CreateFontString( Font, Fontscale, self );
	TextT SetPoint( Align, Relative, X, Y );
	TextT.sort = Sort;
	TextT.color = Color;
	TextT.alpha = Alpha;
	TextT SetText( Text );
	return TextT;
}

CreateServerText( Font, Fontscale, Align, Relative, X, Y, Sort, Color, Alpha, Text )
{
	TextT = self CreateServerFontString( Font, Fontscale );
	TextT SetPoint( Align, Relative, X, Y );
	TextT.sort = Sort;
	TextT.color = Color;
	TextT.alpha = Alpha;
	TextT SetText( Text );
	return TextT;
}


CreateRectangle( Align, Relative, X, Y, Width, Height, Sort, Color, Alpha, Shader )
{
	Box = NewClientHudElem( self );
	Box.elemType = "bar";
	if( !level.splitscreen )
	{
		Box.x = -2;
		Box.y = -2;
	}
	Box.width = Width;
	Box.height = Height;
	Box.align = Align;
	Box.relative = Relative;
	Box.xOffset = 0;
	Box.yOffset = 0;
	Box.children = [];
	Box.sort = Sort;
	Box.color = Color;
	Box.alpha = Alpha;
	Box.shader = Shader;
	Box SetParent( level.UiParent );
	Box SetShader( Shader, Width, Height );
	Box.hidden = false;
	Box SetPoint( Align, Relative, X, Y );
	return Box;
}