ellipses

int cols = 10, rows = cols, w, h, frms = 120;
Square[] squares = new Square[rows*cols];
float theta;
PVector v;

void setup() {
  size(540, 540);
  w = 540/cols;
  h = 540/rows;
  int i=0;
  for (int x=1; x<(rows-1); x++) {
    for (int y=1; y<(cols-1); y++) {
      squares[i] = new Square(x*w, y*h);
      i++;
    }
  }
}

void draw() {
  randomSeed(1234);
  background(255);
  v = new PVector(width/2+sin(theta)*270, height/2+cos(theta)*270);
  for (int i=0; i<(cols-2)*(rows-2); i++) {
    squares[i].update();
    squares[i].display();
  }
  theta += TWO_PI/frms;
}

class Square {

  PGraphics square;
  float x, y;

  Square(float _x, float _y) {
    x = _x;
    y = _y;
    square = createGraphics(w, h);
  }

  void update() {
    float distance = dist(v.x, v.y, x+w/2, y+h/2);
    float r = map(distance, 0, sqrt(sq(width)+sq(height)), 0, HALF_PI);
    float x = map(distance, 0, sqrt(sq(width)+sq(height)), -30, 30);
    float sz = map(distance, 0, sqrt(sq(width)+sq(height)), w*.9, w*1.2);
    square.beginDraw();
    square.rectMode(CENTER);
    square.background(255);
    square.pushMatrix();
    square.translate(w/2, h/2);
    square.rotate(r);
    square.fill(255);
    square.stroke(0);
    square.ellipse(x, 0, sz, sz);
    square.popMatrix();
    square.endDraw();
  }

  void display() {
    image(square, x, y);
  }
}