try destroydialog igorznag_hair catch()
rollout igorznag_hair "Hair"
(
	spinner spn_radius1 "Radius1:" type:#worldunits range:[0,1e9,2] pos:[5,5] fieldwidth:55
	spinner spn_radius2 "Radius2:" type:#worldunits range:[0,1e9,0] pos:[5,25]fieldwidth:55
	spinner spn_height_segments "Height Segments:" type:#integer range:[1,1e9,25] pos:[5,45] fieldwidth:35
	button btn_create "Create" pos:[5,65] width:135
	on btn_create pressed do
	(
		if selection.count>0 then
		(
			r1=Bezier_Float(); r1.value=spn_radius1.value; r2=Bezier_Float(); r2.value=spn_radius2.value
			hs=Bezier_Float(); hs.value=spn_height_segments.value
			undo on
			(
				for obj in selection do
				(
					if classof obj==line or classof obj==SplineShape do
					(
						n=numSegments obj 1; seg_lengths=getSegLengths obj 1 cum:true; spline_length=seg_lengths[2*n]
						obj_cone=cone(); obj_cone.heightsegs.controller=hs
						obj_cone.height=spline_length; obj_cone.radius1.controller=r1; obj_cone.radius2.controller=r2
						addmodifier obj_cone (SpacePathDeform())
						m=obj_cone.modifiers[1]; m.path=obj; obj_cone.transform = obj.transform
						completeredraw()
					)--if classof obj==line or classof obj==SplineShape do
				)--	for obj in selection do
			)--undo on
		)else messagebox "Select line or editable spline objects!"
	)--on btn_create pressed do
); createdialog igorznag_hair 145 90 style:#(#style_titlebar, #style_border, #style_sysmenu,#style_minimizebox)