bitlbee-bzr-libpurple PKGBUILD

# AndrzejL

pkgname=bitlbee-bzr-libpurple
_pkgname=bitlbee
pkgver=1005
pkgrel=1
pkgdesc="An IRC to IM gateway. Supports MSN, ICQ, Jabber, Yahoo!, and AIM. libpurple enabled."
arch=('i686' 'x86_64')
url="http://www.bitlbee.org/"
license=('GPL')
depends=('gnutls' 'glib2' 'libpurple-minimal')
makedepends=('bzr' 'asciidoc' 'libotr' 'xmlto' 'lynx' 'gnutls' 'libpurple-minimal' 'glib2' 'pkg-config')
checkdepends=('check')
optdepends=('xinetd: to run bitlbee through xinetd'
'skype4py: to use skyped'
'libotr: for OTR encryption support')
conflicts=('bitlbee' 'bitlbee-libpurple' 'bitlbee-bzr' 'bitlbee-bzr-libpurple' 'bitlbee-msn' 'bitlbee-msn-xiaoi' 'bitlbee-otr' 'bitlbee-otr-bzr' 'bitlbee-recode')
backup=('etc/bitlbee/bitlbee.conf'
        'etc/bitlbee/motd.txt'
        'etc/xinetd.d/bitlbee')
install=${_pkgname}.install
provides=('bitlbee')
_bzrmod=bitlbee

source=('bitlbee::bzr+http://code.bitlbee.org/bitlbee/'
	'bitlbee.xinetd'
	'bitlbee.rcd'
	'0001-local-clist.patch')
sha512sums=('SKIP'
'6225d950be752635dbc8e41f7ccf847bcac6636717f9d69f7e1c719e4cf16580ccf32edd15ef2bbfe924a7ee94320d57e41c58d75e97dc8b260bf7410ac13587'
'90c7de716ad4f1ce1faf0204c3a379a5b4a880903b522a8c6efd82cb8e1d27b26b223234f9d2ec1219c82b9599049308a12316826a2f0c90a8301bee8fa5c3a2'
'a8a72fee753d6b039f7fb4c80a1cb7e542be9770a9ba49371d6843dc5e4b8aa0810d8dd84aa3dae3c1ab682864b655a60bb91e222d557f1aaea23a339b3a4924')

pkgver() {
  cd "$srcdir/$_bzrmod"
  bzr revno
}

build() {
	cd "$srcdir/$_bzrmod"
	patch -Np1 -i ../0001-local-clist.patch

	./configure --prefix=/usr \
		--ssl=gnutls \
		--etcdir=/etc/bitlbee \
		--pidfile=/var/run/bitlbee/bitlbee.pid \
		--ipcsocket=/var/run/bitlbee/bitlbee.sock \
		--purple=1 \
		--twitter=1 \
		--strip=0 \
		--otr=plugin \
		--skype=plugin
	make
}

package() {
	cd "$srcdir/$_bzrmod"

	install -dm755 ${pkgdir}/var/lib
	install -o65 -g65 -dm0770 ${pkgdir}/var/lib/bitlbee
	install -dm755 ${pkgdir}/var/run
	install -o65 -g65 -dm755 ${pkgdir}/var/run/bitlbee
	install -Dm644 ${srcdir}/bitlbee.xinetd \
		${pkgdir}/etc/xinetd.d/bitlbee
	install -Dm755 ${srcdir}/bitlbee.rcd \
		${pkgdir}/etc/rc.d/bitlbee
	make DESTDIR=${pkgdir} install
	make DESTDIR=${pkgdir} install-etc
	make DESTDIR=${pkgdir} install-dev
}