folderpreview-git

pkgname=folderpreview-git
pkgver=0.3.1.r0.gba6c8ce
pkgrel=1
pkgdesc="Generates folder thumbs using child files thumbs"
arch=('any')
url="https://gitlab.com/hxss-linux/folderpreview"
license=('MIT')
depends=('python-dbus-next' 'python-systemd-mosquito' 'python-pyxdg' 'python-yaml'
         'python-gobject' 'python-pyvips' 'python-parse' 'python-colorlog')
makedepends=('python-setuptools')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://gitlab.com/hxss-linux/folderpreview.git')
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/${pkgname%-git}"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "$srcdir/${pkgname%-git}"
    python setup.py build
}

package() {
    cd "$srcdir/${pkgname%-git}"
    export PYTHONHASHSEED=0
    python setup.py install --root="$pkgdir" --optimize=1 --skip-build

    install -Dm644 folderpreview.thumbnailer -t "$pkgdir/usr/share/thumbnailers"
    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}