vapp-android/build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:1.2.3'
    }
}

apply plugin: 'com.android.application'
apply plugin: 'idea'

android {
    buildToolsVersion = '22.0.1'
    compileSdkVersion = 'android-22'

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_1_7
    }

    defaultConfig {
        applicationId 'net.dermetfan.vapp.android'
        minSdkVersion 13
        targetSdkVersion 22
        versionCode 1
        versionName = '0.0.1'
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
        debug {
            debuggable true
        }
    }

    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src/main']
            res {
                srcDirs = ['res']
            }
        }
    }
}

dependencies {
    compile fileTree(dir: 'libs', include: '*.jar')
    compile 'com.android.support:support-v4:22.2.0'
}

idea {
    project.languageLevel = android.compileOptions.sourceCompatibility
    module {
        sourceDirs = android.sourceSets.main.java.srcDirs
        testSourceDirs = android.sourceSets.test.java.srcDirs
        scopes.COMPILE = [plus: [configurations.compile]]

        iml {
            withXml {
                def node = it.asNode()
                def builder = NodeBuilder.newInstance()
                builder.current = node
                builder.component(name: 'FacetManager') {
                    facet(type: 'android', name: 'Android') {
                        configuration {
                            option(name: 'UPDATE_PROPERTY_FILES', value: 'true')
                        }
                    }
                }
            }
        }
    }
}