-	script	main_script	-1,{
OnGoldRoom: callsub OnNPCTalk,1,"Gold Room"; close;
OnZenyRoom: callsub OnNPCTalk,2,"Zeny Room"; close;

OnNPCTalk:
mes "Enter ^0055FF"+getarg(1)+"^000000 ?";
mes " ";
mes "Time Duration : "+.second+" seconds.";
next;
if( select("Confirm:Close") == 1 )
	if( getd( "#Day_"+getarg(0) ) == atoi( gettimestr( "%Y%m%d", 9 ) ) ){
		mes "You cant enter this room more than 1 time in a day.";
	}else{
		deltimer strnpcinfo(0)+"::OnKick";
		addtimer ( .second * 1000 ),strnpcinfo(0)+"::OnKick";
		setd( "#Day_"+getarg(0) ),atoi( gettimestr( "%Y%m%d", 9 ) );
		if( getarg(0) == 1 ) warp "poring_c02",66,77;
		else warp "poring_c02",172,78;
	}
close;


OnKick:
if( strcharinfo(3) == "poring_c02" )
	warp "SavePoint",0,0;
end;

OnInit:
// how many seconds they stay inside
set .second,5;

setarray .@mf[0],mf_nomemo,mf_noteleport,mf_nosave,mf_nobranch,mf_noskill,mf_nowarp,mf_nogo,mf_nomobloot,mf_nomvploot,mf_nowarpto;
for( set .@i,0; .@i < getarraysize( .@mf ); set .@i,.@i + 1 )
	setmapflag "poring_c02",.@mf[.@i];

while( 1 ){
	if( getmapusers( "poring_c02" ) ){
		makeitem 607,1,"poring_c02",rand( 61,71 ),rand( 70,85 );
		makeitem 969,1,"poring_c02",rand( 165,176 ),rand( 70,85 );
	}
	sleep rand( 50,500 );
}
end;
}

prontera,150,161,5	script	Gold Room	757,{
	doevent "main_script::OnGoldRoom";
}

prontera,155,161,5	script	Zeny Room	757,{
	doevent "main_script::OnZenyRoom";
}