$fs = 0.5;
$fa = 0.5;

screw_spacing = 38;
screw_margin = 4;
screw_post_h = 3;
screw_post_d = 6;
screw_d = 3.2;

inward_w = 12;
outward_w = 30;

edge_r = 3;

plate_l = screw_spacing + screw_margin * 2;
plate_w = inward_w + outward_w;
plate_t = 4;

bar_l = 30;
bar_x_offset = 24;

color([0,0,1])
  esc_plate();

module esc_plate() {
  difference() {
    union() {
      // Plate
      hull() {
        for(i=[-1,1]) {
          translate([-inward_w + edge_r, (plate_l * 0.5 - edge_r) * i, plate_t * 0.5])
            cylinder(r=edge_r, h=plate_t, center=true);
          translate([outward_w - edge_r, (plate_l * 0.5 - edge_r) * i, plate_t * 0.5])
            cylinder(r=edge_r, h=plate_t, center=true);
        }
      }
      // Screw Posts
      for(i=[-1,1])
        translate([0, screw_spacing * 0.5 * i, -screw_post_h*0.5])
          cylinder(d=screw_post_d, h=screw_post_h, center=true);
      translate([bar_x_offset, 0, 0])
        hull() {
          for(i=[-1,1])
            translate([0, (bar_l * 0.5 - edge_r) * i, -screw_post_h * 0.5])
              cylinder(d=edge_r, h=screw_post_h, center=true);
        }
    }
    for(i=[-1,1])
      translate([0, screw_spacing * 0.5 * i, 0])
        cylinder(d=screw_d, h=plate_t * 4, center=true);
  }
}