effect mnd = $effect[Absinthe-Minded];

void acquire_absinthe_minded() {
    if ( mnd.have_effect() >= 10 ) {
        return;
    }
    item abs = $item[tiny bottle of absinthe];
    if ( abs.available_amount() < 1 ) {
        buy(1, abs);
    }
    use(1, abs);
}

void set_up_choice_adventures() {
    # The Rogue Windmill
    # La Vie Boheme, Check out the restrooms
    set_property("choiceAdventure170", 1);
    # Midst the Pallor of the Parlor, Approach the Woman
    set_property("choiceAdventure168", 3);
    # The Stately Pleasure Dome
    # Death is a Boat, Check out the helm
    set_property("choiceAdventure166", 3);
}

boolean run_one_adventure(location l) {
    restore_hp(my_maxhp());
    adv1(l, 0, "");
    if ($effect[beaten up].have_effect() > 0) {
        print("Beaten up, stopping...", "red");
        return false;
    }
    return true;
}

boolean acquire_rat_faced() {
    if ( mnd.have_effect() < 7 ) {
        acquire_absinthe_minded();
    }

    while ( $effect[Rat-Faced].have_effect() < 1 && mnd.have_effect() > 6 ) {
        run_one_adventure($location[The Rogue Windmill]);
    }

    return true;
}

boolean acquire_an_unusual_fashion_sense() {
    if ( mnd.have_effect() < 4 ) {
        acquire_absinthe_minded();
    }

    while ( $effect[Unusual Fashion Sense].have_effect() < 1 && mnd.have_effect() > 3 ) {
        if ( $effect[Rat-Faced].have_effect() < 1 ) {
            if ( !acquire_rat_faced() ) {
                print("Could not acquire rat faced", "red");
                return false;
            }
        }
        run_one_adventure($location[The Mouldering Mansion]);
    }

    return true;
}

void acquire_necklace() {
    if ( mnd.have_effect() < 1 ) {
        acquire_absinthe_minded();
    }
    int turns_spent = 0;
    while ( mnd.have_effect() > 0 && turns_spent++ < 19 ) {
        # Check if we got Unusual Fashion Sense
        if ( $effect[Unusual Fashion Sense].have_effect() < 1 ) {
            if ( !acquire_an_unusual_fashion_sense() ) {
                print("Could not get an unusual fashion sense, sorry!", "red");
                return;
            }
        }
        run_one_adventure($location[The Stately Pleasure Dome]);
    }
}

# Check if we got Rat-Faced
# Check if we got the necklace

set_up_choice_adventures();
acquire_necklace();