<stdin>

/////
///
//  DECORATE EXAMPLE
///
////

actor "Super Shotgun": SuperShotgun replaces SuperShotgun
{
    AttackSound "none"

    States
    {
      Fire:
        SHT2 A 0 A_JumpIfInventory("UseCoopBullets", 1, "CoopFire")
        SHT2 A 0 A_FireBullets(11.2, 7.1, 20, ACS_ExecuteWithResult(430, 1, 5, 3), "OneshotWeaponPuff", FBF_NORANDOM | FBF_USEAMMO)
        goto Fire2

      CoopFire:
        // 112 for horizontal comes from (11.2 * 10)
        // 71  for vertical   comes from (7.1  * 10)
        SHT2 AAAAAAAAAAAAAAAAAAAA 0 A_FireCustomMissile("OneshotBullet", ACS_ExecuteWithResult(473, 50, 112) / 100.0, 0, 0, 4, 0,
                                                                         ACS_ExecuteWithResult(473, 50, 71)  / 100.0)
        SHT2 A 0 A_FireCustomMissile("AmmoWaster")
        goto Fire2

      Fire2:
        SHT2 A 0 A_PlaySound("weapons/sshotf", CHAN_WEAPON)
        SHT2 A 7 bright A_GunFlash
        SHT2 B 7
        SHT2 C 7 A_CheckReload
        SHT2 D 7 A_OpenShotgun2
        SHT2 E 7
        SHT2 F 7 A_LoadShotgun2
        SHT2 G 6
        SHT2 H 6 A_CloseShotgun2
        Goto Ready

      Hold:
        SHT2 A 3
        goto Fire
    }
}


/////
///
//  ACS
///
////

script 473 (int count, int low, int high)
{
    int ret = 0;
    int i;
    if (!high) { high = low; low = -high; }

    for (i = 0; i < count; i++) { ret += random(low, high); }
    SetResultValue(ret);
}