herbsteal.cmd

# If you need herbs, it goes shopping
#   You need .herbsort script to set what herbs you need
#   You need an herb stacker
#
# written by Hanryu
# Please report any bugs to Hanryu#0052 (Discord) or [email protected]
# This script may be reused in whole or in part as long as credit is given
# This script is designed to use Oulander, http://outlanderapp.com
# 2020-05-07
#    Initial release
# 2020-05-20
#    Added check to not steal to many things, and if caught abort
#    Added check to steal 1 herb each if stealing a lot of herbs so that get them all
#2021-12-08
#   remove armor
#   Outlander2 conversion
#debug 5

#### LOAD VARIABLES ####
#edit this list with what you can steal and stock
if ($zoneid = 1) then {var HerbList aevaes potion,aloe salve,georin salve,hulnik grass,ithor potion,jadice flower,junliar stem,muljin sap,nemoih root,nilos salve,plovik lea,riolur lea,sufil sap,yelith root}
if ($zoneid = 4a) then {var HerbList cebi root,hisan salve}
if ($zoneid = 67) then {var HerbList aevaes potion,aloe salve,cebi root,eghmok potion,georin salve,hisan salve,hulnik grass,ithor potion,jadice flower,junliar stem,muljin sap,nemoih root,nilos salve,plovik lea,riolur lea,sufil sap,yelith root}

eval SCRIPTNAME tocaps(%scriptname)
put #echo >User >%SCRIPTNAME: $time
var totaltime $gametime
var herb
var TotalHerbsNeeded 0
var StealCount 0

####  Top, Do you need herbs at all?  ####
gosub call herbsort
if matchre("$HerbsNeeded", "\$|^$") then {goto done}

#### Travel to herb shop, this only works if you are in a town with a shop ####
gosub call travel herb

#### What to steal ####
eval HerbsNeeded replacere("$HerbsNeeded", "\|$", "")
eval TotalHerbsNeeded count("$HerbsNeeded", "|")
loop:
  if matchre("%HerbList", "(%HerbsNeeded)( \w+)") then {var herb $1$2}
  else {goto done}
  gosub steal %herb
  gosub stow %herb
  if (%TotalHerbsNeeded < 5) then {
    gosub steal %herb
    gosub stow %herb
    }
  if (%StealCount > 7) then {goto done}
  eval HerbList replacere("%HerbList", "%herb", "")
  goto loop

end:
done:
  if (%StealCount > 0) then {gosub call armor normal}
  math totaltime subtract $gametime
  math totaltime multiply -1
  var minutes %totaltime
  var seconds %totaltime
  math seconds modulus 60
  if (%seconds < 10) then {var seconds 0%seconds}
  math minutes divide 60
  if matchre("%minutes", "(\d+)\.\d*") then {var minutes $1}
  put #printbox %SCRIPTNAME took %minutes:%seconds to steal %StealCount herbs
  put #echo >user <%SCRIPTNAME: %minutes:%seconds
  put #parse ** %SCRIPTNAME DONE **
  exit

#### LOAD INCLUDES ####
include commonINC