MonitorDeConexion.cmd

@echo off
rem Autor: John Llewelyn
rem fb.com/johnwilliam.llewelyn
rem twitter.com/JWLLEWELYN
rem Tlf: +584149101115
rem Description: Monitor de Conexion ADSL para mantener de manera persistente la conectividad a Internet.

title Monitor de Conexion

rem Ajustes
SETLOCAL ENABLEEXTENSIONS
set "DNS=www.google.com"
set "IP=8.8.8.8"
set "ADAPTER=WAN"

rem Generador de Fecha y Tiempo
for /F "tokens=2" %%i in ('date /t') do set mydate=%%i
set "mytime=%time%"

rem Generador de Reporte
set "logfile=C:\Reporte.log"

rem Generador de Mensajes
set "message_test_dns=Comprobacion de la conexion, por favor espere..."
set "message_fail=FALLO!"
set "message_tryagain=Dejame intentarlo un poco mas, por favor espere..."
set "message_test_ip=Comprobacion de DNS, vamos a tratar por la direccion IP..."
set "message_netdown=Parece que tiene problemas de red, no tiene conectividad."
set "message_connectivity=Tiene una conexion a Internet activa"
set "message_packetloss=Se detecto una conexion a Internet activa, pero un poco de perdida de paquetes"
set "message_noconnectivity=Usted no tiene una conexion a Internet activa"
set "message_resolve=Reparando conexion a Internet, espere por favor..."

:AGAIN
cls
echo %message_test_dns%
ping -n 1 %DNS%|find "bytes=" >NUL
IF NOT ERRORLEVEL 1 goto SUCCESS
IF     ERRORLEVEL 1 goto TRYAGAIN

:TRYAGAIN
cls
echo %message_fail%
echo %message_tryagain%
PING -n 3 %DNS%|find "bytes=" >NUL
IF NOT ERRORLEVEL 1 goto SUCCESS2
IF     ERRORLEVEL 1 goto TRYIP

:TRYIP
cls
echo %message_fail%
echo %message_test_ip%
ping -n 1 %IP%|find "bytes=" >NUL
IF NOT ERRORLEVEL 1 goto SUCCESS2
IF     ERRORLEVEL 1 goto NETDOWN

:NETDOWN
cls
echo %message_fail%
echo %message_netdown%
timeout /t 10 > nul
goto FAILURE

:SUCCESS
CLS
echo %message_connectivity%
echo %mydate% %mytime%
netsh interface ip show config name="%ADAPTER%" | find "IP"
echo ======================================================================================================== >> %logfile%
echo %message_packetloss% - %mydate% %mytime% >> %logfile%
netsh interface ip show config name="%ADAPTER%" | find "IP" >> %logfile%
echo ======================================================================================================== >> %logfile%
timeout /T 180 > nul
goto AGAIN

:SUCCESS2
cls
echo %message_packetloss%
echo %mydate% %mytime%
netsh interface ip show config name="%ADAPTER%" | find "IP"
echo ======================================================================================================== >> %logfile%
echo %message_packetloss% - %mydate% %mytime% >> %logfile%
netsh interface ip show config name="%ADAPTER%" | find "IP" >> %logfile%
echo ======================================================================================================== >> %logfile%
timeout /T 180 > nul
goto AGAIN

:FAILURE
cls
echo %message_noconnectivity%
echo %mydate% %mytime%
echo ======================================================================================================== >> %logfile%
echo %message_noconnectivity% - %mydate% %mytime% >> %logfile%
echo ======================================================================================================== >> %logfile%
timeout /t 10 > nul
goto RESOLVE

:RESOLVE
cls
echo %message_resolve%
ipconfig/release "%ADAPTER%" > nul
timeout /t 10 > nul
ipconfig/renew "%ADAPTER%" > nul
goto AGAIN