OPTIMA backup

-------------------------------------------------------
-- Archiwizacja baz utworzonych w przez program OPT!MA
-------------------------------------------------------

-- Deklarowanie zmiennych używanych w skrypcie
DECLARE @Sciezka    VARCHAR(260)
DECLARE @Nazwa_bazy VARCHAR(40)
DECLARE @PlikArchiw VARCHAR(300)
DECLARE @Zarchiw      INT
DECLARE @Bledow       INT


-- Ustawienie ścieżki dostępu do katalogu z backupem
SET @Sciezka = N'C:\WUTemp\' --tu wpisz scieżkę dostępu do katalogu backupu


SET @Zarchiw      = 0
SET @Bledow       = 0

-- Wykonanie backupu konfiguracji
        SET @Nazwa_bazy = 'CDN_KONFIGURACJA'
        SET @PlikArchiw = @Sciezka + @Nazwa_bazy +
--         REPLACE(REPLACE(REPLACE(CONVERT(CHAR(16), GETDATE(), 120), ' ', ''), '-', ''), ':', '') +
         '.BAC'
        BACKUP DATABASE @Nazwa_bazy TO DISK = @PlikArchiw WITH INIT, NAME = 'OPT!MA KONFIGURACJA', SKIP, STATS = 5, NOFORMAT, DESCRIPTION = ''
        IF @@error>0
          BEGIN
            SET @Bledow = @Bledow + 1
            PRINT ''
            PRINT 'Archiwizacja bazy ' + @Nazwa_Bazy + ' zakończyła się niepowodzeniem !'
            PRINT ''
          END
        ELSE
          BEGIN
            RESTORE VERIFYONLY FROM DISK = @PlikArchiw WITH FILE = 1
            IF @@error>0
              BEGIN
                SET @Bledow = @Bledow + 1
                PRINT ''
                PRINT 'Archiwizacja bazy ' + @Nazwa_Bazy + ' zakończyła się niepowodzeniem !'
                PRINT ''
              END
            ELSE
              BEGIN
                SET @Zarchiw = @Zarchiw + 1
                PRINT ''
                PRINT 'Zarchwizowano bazę ' + @Nazwa_bazy + ' (' + @PlikArchiw + ')'
                PRINT ''
              END
          END





-----------------------------------------
-- Pętla archiwizująca bazy operacyjne
-----------------------------------------

USE CDN_Konfiguracja

DECLARE Kursor_Bazy CURSOR FORWARD_ONLY FOR
  SELECT SUBSTRING(Baz_Dostep, 5, CHARINDEX(N',', Baz_Dostep) - 5)
  FROM CDN.Bazy
  WHERE Baz_Dostep like N'%'+@@SERVERNAME+N'%'

OPEN Kursor_bazy

WHILE 1 = 1
  BEGIN
    FETCH NEXT FROM Kursor_bazy INTO  @Nazwa_bazy
    IF @@FETCH_STATUS <> 0 BREAK
    SET @PlikArchiw = @Sciezka + @Nazwa_bazy + '.bac'
--        REPLACE(REPLACE(REPLACE(CONVERT(CHAR(16), GETDATE(), 120), N' ', N''), N'-', N''), N':', N'') +
--        N'.BAC'

    BACKUP DATABASE @Nazwa_bazy TO DISK = @PlikArchiw WITH INIT, NAME = 'OPT!MA BAZA DANYCH', SKIP, STATS = 5, NOFORMAT, DESCRIPTION = ''
    IF @@error>0
      BEGIN
        SET @Bledow = @Bledow + 1
        PRINT ''
        PRINT 'Archiwizacja bazy ' + @Nazwa_bazy + ' zakończyła się niepowodzeniem !'
        PRINT ''
      END
    ELSE
      BEGIN
        RESTORE VERIFYONLY FROM DISK = @PlikArchiw WITH FILE = 1
        IF @@error>0
          BEGIN
            SET @Bledow = @Bledow + 1
            PRINT ''
            PRINT 'Archiwizacja bazy ' + @Nazwa_bazy + ' zakończyła się niepowodzeniem !'
            PRINT ''
          END
        ELSE
          BEGIN
            SET @Zarchiw = @Zarchiw + 1
            PRINT ''
            PRINT 'Zarchwizowano bazę ' + @Nazwa_bazy + ' (' + @PlikArchiw + ')'
            PRINT ''
          END
      END

  END   -- Koniec pętli WHILE

CLOSE      Kursor_bazy
DEALLOCATE Kursor_bazy

PRINT 'Archiwizacja zakończona.'
PRINT 'Zarchiwizowano ' + LTRIM(STR(@Zarchiw)) + ' baz danych.'
PRINT 'Wystąpiło ' + LTRIM(STR(@Bledow)) + ' błędów.'