Scriptname ARTH_LAL_VersionTrackingScript extends Quest Conditional

Int Property LastVersion Auto Hidden
ARTH_LAL_StartQuest Property ChargenQuest Auto
Message Property ARTHLALUpgradeNotice Auto
ARTH_LAL_Patch210RetroScript Property ARTHLALPatch21Quest Auto
ARTH_LAL_Patch212RetroScript Property ARTHLALPatch212Quest Auto
ARTH_LAL_Patch216RetroScript Property ARTHLALPatch216Quest Auto
ARTH_LAL_Patch218RetroScript Property ARTHLALPatch218Quest Auto
ARTH_LAL_Patch220RetroScript Property ARTHLALPatch220Quest Auto
ARTH_LAL_Patch230RetroScript Property ARTHLALPatch230Quest Auto
ARTH_LAL_Patch231RetroScript Property ARTHLALPatch231Quest Auto
ARTH_LAL_Patch232RetroScript Property ARTHLALPatch232Quest Auto
ARTH_LAL_Patch233RetroScript Property ARTHLALPatch233Quest Auto
ARTH_LAL_Patch235RetroScript Property ARTHLALPatch235Quest Auto
ARTH_LAL_Patch236RetroScript Property ARTHLALPatch236Quest Auto
ARTH_LAL_Patch237RetroScript Property ARTHLALPatch237Quest Auto
ARTH_LAL_Patch240RetroScript Property ARTHLALPatch240Quest Auto
ARTH_LAL_Patch241RetroScript Property ARTHLALPatch241Quest Auto
ARTH_LAL_Patch250RetroScript Property ARTHLALPatch250Quest Auto
ARTH_LAL_Patch251RetroScript Property ARTHLALPatch251Quest Auto
ARTH_LAL_Patch252RetroScript Property ARTHLALPatch252Quest Auto
ARTH_LAL_Patch300RetroScript Property ARTHLALPatch300Quest Auto

Faction Property DLC1VampireCompanionFaction Auto
Faction Property DLC1RadiantVampireBanditNecroAllys Auto
Faction Property VampireFaction Auto
Faction Property VampireThrallFaction Auto
Faction Property BanditFaction Auto
Faction Property WolfFaction Auto
Faction Property ARTHLALBanditVampireFaction Auto

Potion property SnowberryExtract Auto Hidden ; Frostfall support
bool property FrostfallInstalled Auto Hidden ; Frostfall support

bool Property BlockHelgenStart Auto Hidden Conditional ; Use to block Helgen start option.
bool Property RTHInstalled Auto Hidden Conditional ; For Giskard's Return to Helgen - blocks Solitude start options.

bool Property KNInstalled Auto Hidden Conditional ; For Keld-Nar inn start
ObjectReference Property ARTHKeldNarInnStartMarker Auto Hidden

bool Property OldHroldanInstalled Auto Hidden Conditional ;For Shezrie's Old Hroldan Inn

Quest Property MQ101 Auto

Event OnInit()
	DLCSupportCheck()
	VersionCheck()
EndEvent

Function DLCSupportCheck()
	BanditFaction.SetAlly(ARTHLALBanditVampireFaction)
	VampireFaction.SetAlly(ARTHLALBanditVampireFaction)
	VampireThrallFaction.SetAlly(ARTHLALBanditVampireFaction)
	WolfFaction.SetAlly(ARTHLALBanditVampireFaction)

	VampireFaction.SetAlly(DLC1VampireCompanionFaction)
	VampireThrallFaction.SetAlly(DLC1VampireCompanionFaction)

	BanditFaction.SetAlly(DLC1RadiantVampireBanditNecroAllys)
	VampireFaction.SetAlly(DLC1RadiantVampireBanditNecroAllys)
	VampireThrallFaction.SetAlly(DLC1RadiantVampireBanditNecroAllys)

	;Don't perform the checks if chargen is complete. MQ101 Stage 250 is as good a check as any.
	if( MQ101.GetStage() < 250 )
		debug.trace( "==== LAL: Mod support check - Ignore errors about missing files. ====" )

		;Frostfall check, for shipwreck start to add 2 Strawberry Extract potions to the sack near the start area.
		If Game.GetModByName("Chesko_Frostfall.esp")
			if( Game.GetFormFromFile( 0x0001D430, "Chesko_Frostfall.esp" ) )
				debug.trace( "LAL: Frostfall detected." )
				SnowberryExtract = Game.GetFormFromFile( 0x0001D430, "Chesko_Frostfall.esp" ) as Potion

				FrostfallInstalled = True
			Else
				SnowberryExtract = None

				FrostfallInstalled = False
			EndIf
		Endif
		BlockHelgenStart = False

		;Helgen Reborn check - disables vanilla start option if it's active.
;		if( Game.GetFormFromFile( 0x000012CA, "Helgen Reborn.esp" ) )
;			debug.trace( "LAL: Helgen Reborn detected." )
;			BlockHelgenStart = True
;		EndIf

		;Return to Helgen check - disables Solitude start options if it's active.
		If Game.GetModByName("teg_returntohelgen.esp")
			if( Game.GetFormFromFile( 0x000012CA, "teg_returntohelgen.esp" ) )
				debug.trace( "LAL: Return to Helgen detected. Solitude start options are now disabled." )
				RTHInstalled = True
			Else
				RTHInstalled = False
			EndIf
		Endif
		;Keld-Nar check - used for additional inn start if it's installed.
		If Game.GetModByName("Keld-Nar.esp")
			if( Game.GetFormFromFile( 0x00013AD8, "Keld-Nar.esp" ) )
				ARTHKeldNarInnStartMarker = Game.GetFormFromFile( 0x00013AD8, "Keld-Nar.esp" ) as ObjectReference
				KNInstalled = True
			Else
				ARTHKeldNarInnStartMarker = None
				KNINstalled = False
			EndIf
		Endif
		;Old Hroldan Inn. Move player to adjusted location marker if Shezrie's version is present.
		If Game.GetModByName("ShezriesOldHroldan.esp")
			if( Game.GetFormFromFile( 0x000149e6, "ShezriesOldHroldan.esp" ) )
				debug.trace( "LAL: Shezrie's Old Hroldan Town detected." )
				OldHroldanInstalled = True
			Else
				OldHroldanInstalled = False
			EndIf
		Endif
		debug.trace( "==== LAL: Mod support check - Done. ====" )
	EndIf
EndFunction

Function VersionCheck()
	if( LastVersion < 300 )
		if( ChargenQuest.GetStage() >= 10 && ChargenQuest.GetStage() < 20 )
			ARTHLALUpgradeNotice.Show()
			Return
		EndIf

		if( LastVersion < 210 )
			ARTHLALPatch21Quest.Process()
		ElseIf( LastVersion < 212 )
			ARTHLALPatch212Quest.Process()
		elseif( LastVersion < 216 )
			ARTHLALPatch216Quest.Process()
		elseif( LastVersion < 218 )
			ARTHLALPatch218Quest.Process()
		elseif( LastVersion < 220 )
			ARTHLALPatch220Quest.Process()
		elseif( LastVersion < 230 )
			ARTHLALPatch230Quest.Process()
		elseif( LastVersion < 231 )
			ARTHLALPatch231Quest.Process()
		elseif( LastVersion < 232 )
			ARTHLALPatch232Quest.Process()
		elseif( LastVersion < 233 )
			ARTHLALPatch233Quest.Process()
		elseif( LastVersion < 235 )
			ARTHLALPatch235Quest.Process()
		elseif( LastVersion < 236 )
			ARTHLALPatch236Quest.Process()
		elseif( LastVersion < 237 )
			ARTHLALPatch237Quest.Process()
		elseif( LastVersion < 240 )
			ARTHLALPatch240Quest.Process()
		elseif( LastVersion < 241 )
			ARTHLALPatch241Quest.Process()
		elseif( LastVersion < 250 )
			ARTHLALPatch250Quest.Process()
		elseif( LastVersion < 251 )
			ARTHLALPatch251Quest.Process()
		elseif( LastVersion < 252 )
			ARTHLALPatch252Quest.Process()
		elseif( LastVersion < 300 )
			ARTHLALPatch300Quest.Process()
		EndIf
	EndIf
EndFunction