BEAGY_DEMO_1

#include <ESP8266WiFi.h>
#include <PubSubClient.h>

#define ledPinRed D1
#define ledPinGreen D2
#define potPin A0
#define button D6

int buttonState = 0;
int lastButtonState = 0;

int potmeterValue = 0;
long lastMsg = 0;

//WIFI adatok
const char* ssid = "beagy_labor";
const char* password = "12345678";
//MQTT szerver IP címe
const char* mqtt_server = "192.168.0.100";
//Wifi kliens
WiFiClient espClient;
//MQTT-t megvalósító kliens
PubSubClient client(espClient);

//A Yolobor1 helyére egyedi ID-t írjatok be!
String clientId = "Yolobor1";

//WIFI-re csatlakozás
void setup_wifi() {

  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

//Üzenet kezelő függvény
void callback(char* topic_in, byte* payload, unsigned int length) {

  //Üzenet char* ból Stringbe konvertálása
  String message = "";
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }

  //Topic char* hosszának meghatározása
  int k = 0;
  while((char)topic_in[k] != '\0'){
    k++;
  }

  //Topic char* ból Stringbe konvertálása
  String topic = "";
  for (int i = 0; i < k; i++) {
    topic += (char)topic_in[i];
  }

  Serial.print("Topic: ");
  Serial.println(topic);
  Serial.print("Message: ");
  Serial.println(message);
  Serial.println();

  if(topic == "root/error"){
    errorHandle(message);
  }
}

//root/error topicba érkező üzenet kezelő
void errorHandle(String message){
    if(message == "stop"){
        digitalWrite(ledPinRed, HIGH);
        digitalWrite(ledPinGreen, LOW);
      }
      else if(message == "continue") {
        digitalWrite(ledPinRed, LOW);
        digitalWrite(ledPinGreen, HIGH);
      }
}

//Connect és reconnect az MQTT szerverre.
void reconnect() {
  // Loop ameddig nem csatlakoztunk
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");

    // Csatlakozás próbálkozás
    // .c_str() átalakítás Stringből!!!
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");

      // Miután csatlakozott
      client.subscribe("root/error");

    }
    else {
      //rc => return code
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");

      delay(5000);
    }
  }
}

void setup() {

  Serial.begin(115200);

  //Wifire csatlakozás
  setup_wifi();

  //MQTT kliens beállítások
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);

  //Alapállapot beállítása
  pinMode(ledPinRed, OUTPUT);
  pinMode(ledPinGreen, OUTPUT);
  digitalWrite(ledPinRed, LOW);
  digitalWrite(ledPinGreen, HIGH);
}

void loop() {

  //MQTT kapcsolat fentartása
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  //Potmeter, error szimulálására
  long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;
    potmeterValue = analogRead(potPin);
    Serial.println(potmeterValue);

    if(potmeterValue < 50) {
    client.publish("root/error", "stop");
    }
  }

  //Gomb
  buttonState = digitalRead(button);

  //Prellmentesítés
  if (buttonState != lastButtonState) {
    if(buttonState == HIGH) {
      //RANDOM ÜZENET szabadon választható
      client.publish("root/servermsg", (clientId + " RANDOM ÜZENET").c_str());
    }
    delay(50);
    lastButtonState = buttonState;
  }
}