Comando de Eval con BDFD-API | Bot Designer for Discord #5

$nomention
$botListHide $c[Hide to BotDesignerList.]

$c[
Remember to use BDScript 2!

Version: 01/04/2023

#D.B.D.Team: https://discord.gg/FTtVXfj
]

$c[Remember add your ID to use this command!]
$try
$onlyForIDs[{TU ID};Error]
$argsCheck[>1;Añade el código para ejecutar en el eval. Ej.: `<prefix>eval <code>`.]
$var[status;continue]
$catch
$onlyIf[$error[message]!=;]
La ID no fue definida en `%{DOL}%onlyForIDs` o el mensaje de error es inválido.
Error en detalles:

``$error[command]: $optOff[$unescape[$error[message]]]``
$var[status;denied!]
$stop
$endtry

$if[$var[status]!=denied]
$try
$eval[$optOff[$unescape[$message]]]
$catch

$c[Execute in case if the code return error.]
$onlyIf[$error[message]!=;]

$if[$checkContains[$optOff[$unescape[$error[message]]];. Function `]==true]
$textSplit[$error[message];. Function `]
$textSplit[$splitText[2];`]
$var[getFunction;$splitText[1]]
$elseif[$checkContains[$optOff[$unescape[$error[message]]];. Expected `\]` at the end of `]==true]
$textSplit[$error[message];. Expected `\]` at the end of `]
$textSplit[$splitText[2];`]
$var[getFunction;$splitText[1]]
$elseif[$checkContains[$optOff[$unescape[$error[message]]];Failed to ban user!]==true]
$var[getFunction;%{DOL}%banID]
$elseif[$checkContains[$optOff[$unescape[$error[message]]];Failed to kick user!]==true]
$var[getFunction;%{DOL}%kick]
$elseif[$checkContains[$optOff[$unescape[$error[message]]];Select menu needs at least 1 option]==true]
$var[getFunction;%{DOL}%newSelectMenu]
$else
$var[getFunction;%{DOL}%eval]
$endif

$try
$optOff[$httpGet[https://bdfdapi.idcteam.xyz/api/fox.v1/$replaceText[$replaceText[$replaceText[$replaceText[$replaceText[$toLowercase[$optOff[$unescape[$trimSpace[$var[getFunction]]]]];%{DOL}%;;-1];[;;-1];\];;-1];yes;;-1];no;;-1].json]]
$catch
$var[error;Avoid]
$endtry

$title[Comando de Eval]
$embeddedURL[https://bdfd-api.glitch.me/api/fox.v1/]
$description[
Error en la función de  `$optOff[$unescape[$var[getFunction]]]`.
$addField[Detalles;``$optOff[$unescape[$error[message]]]``;no]
$try
$addField[API;Resultados encontrados en la API...;no]
$if[$httpResult[isPremium]==true]
$addField[Premium;``Sí.``;no]
$else
$addField[Premium;``No.``;no]
$endif
$addField[Descripción;``$httpResult[es;description]``;no]
$addField[Uso(s);``$httpResult[es;use]``;no]
$catch
$addField[API;Resultado en la API no encontrado.;no]
$endtry
]
$color[5865F2] $c[Color de Zorua]
$endtry
$else
$stop
$endif