FUNCTION zhm_art_extend_lgort.
*"----------------------------------------------------------------------
*"*"Lokalny interfejs:
*"  IMPORTING
*"     REFERENCE(IV_MATNR) TYPE  MATNR
*"     REFERENCE(IT_MARD) TYPE  MARD_TAB
*"     REFERENCE(IT_T001L) TYPE  WRF_SIT_TT001L
*"  EXPORTING
*"     REFERENCE(ES_RETURN) TYPE  BAPIRETURN1
*"----------------------------------------------------------------------

  DATA: ls_sto_loc    TYPE bapie1mardrt,
        ls_sto_locx   TYPE bapie1mardrtx,
        ls_mard_final TYPE mard,
        lt_sto_loc    TYPE TABLE OF bapie1mardrt,
        lt_sto_locx   TYPE TABLE OF bapie1mardrtx,
        ls_return     TYPE bapireturn1,
        ls_mara_var   TYPE mara,
        ls_headdata   TYPE bapie1mathead.

  " Naglowek
  CALL FUNCTION 'MARA_SINGLE_READ'
    EXPORTING
      matnr             = iv_matnr
    IMPORTING
      wmara             = ls_mara_var
    EXCEPTIONS
      lock_on_material  = 1
      lock_system_error = 2
      wrong_call        = 3
      not_found         = 4
      OTHERS            = 5.

  ls_headdata-function   = '005'.
  ls_headdata-material   = ls_mara_var-matnr.
  ls_headdata-matl_type  = ls_mara_var-mtart.
  ls_headdata-matl_group = ls_mara_var-matkl.
  ls_headdata-matl_cat   = ls_mara_var-attyp.
  ls_headdata-logdc_view = 'X'.

  LOOP AT it_t001l INTO DATA(ls_lgort).

    AT NEW werks.
      DATA(ls_mard) = it_mard[ werks = ls_lgort-werks ].
    ENDAT.

    "Pomijamy, jeśli ten skład już istnieje
    IF line_exists( it_mard[ werks = ls_lgort-werks lgort = ls_lgort-lgort ] ).
      CONTINUE.
    ENDIF.

    CLEAR ls_mard_final.

    MOVE-CORRESPONDING ls_mard TO ls_mard_final.

    ls_mard_final-lgort = ls_lgort-lgort.

    CALL FUNCTION 'MAP2E_MARD_TO_BAPIE1MARDRT'
      EXPORTING
        mard         = ls_mard_final
      CHANGING
        bapie1mardrt = ls_sto_loc.

    ls_sto_loc-function = '005'.
    ls_sto_loc-material = iv_matnr.

    APPEND ls_sto_loc TO lt_sto_loc.

    MOVE-CORRESPONDING ls_sto_loc TO ls_sto_locx.

    APPEND ls_sto_locx TO lt_sto_locx.

  ENDLOOP.
  IF lines( lt_sto_loc ) > 0.

    CALL FUNCTION 'BAPI_MATERIAL_MAINTAINDATA_RT'
      EXPORTING
        headdata             = ls_headdata
      IMPORTING
        return               = es_return
      TABLES
        storagelocationdata  = lt_sto_loc
        storagelocationdatax = lt_sto_locx.

  ENDIF.







ENDFUNCTION.