UI build module

description = "UI"

val agent: Configuration by configurations.creating

configurations {
    testImplementation {
        extendsFrom(configurations.annotationProcessor.get())
    }
}

tasks.compileJava {
    options.compilerArgs.add("-Xplugin:Manifold")
}

tasks.compileTestJava {
    options.compilerArgs.add("-Xplugin:Manifold")
}

dependencies {
    agent("org.aspectj:aspectjweaver")

    implementation(project(":model"))
    implementation(project(":api"))
    implementation("com.codeborne:selenide:6.5.0")
    implementation("io.github.sskorol:cdt-java-client")
    implementation("io.github.sskorol:webdriver-supplier:1.1.3")
    implementation("com.fasterxml.jackson.core:jackson-databind:2.13.3")
    implementation("javax.xml.bind:jaxb-api:2.4.0-b180830.0359")
    // Keep 2.35 version, as 3+ contains breaking changes that would require refactoring
    implementation("org.glassfish.jersey.core:jersey-client:2.35")
    implementation("io.rest-assured:rest-assured")

    implementation("org.aeonbits.owner:owner")
    implementation("com.github.ben-manes.caffeine:caffeine")
    implementation("io.qameta.allure:allure-testng") {
        exclude(group = "org.testng", module = "testng")
    }
    implementation("io.github.sskorol:test-data-supplier")
    implementation("org.testng:testng")
    implementation("org.assertj:assertj-core")
    implementation("org.aspectj:aspectjrt")
    implementation("org.aspectj:aspectjweaver")
    implementation("systems.manifold:manifold-ext")
    implementation("systems.manifold:manifold-ext-rt")
    implementation("org.awaitility:awaitility:4.2.0")

    compileOnly("com.google.code.findbugs:annotations")
    compileOnly("com.google.code.findbugs:jsr305")

    annotationProcessor("systems.manifold:manifold-ext")
    testAnnotationProcessor("systems.manifold:manifold-ext")
    annotationProcessor("org.projectlombok:lombok")
    compileOnly("org.projectlombok:lombok")
    testImplementation("org.projectlombok:lombok")
    testAnnotationProcessor("org.projectlombok:lombok")
}

tasks.register<Delete>("cleanRootBuild") {
    delete(rootProject.buildDir)
}

tasks.clean {
    dependsOn("cleanRootBuild")
}

tasks.test {
    val suiteName = System.getenv("UI_SUITE_NAME") ?: "smoke-suite-ui"
    val jiraUrl = System.getenv("JIRA_URL")
    val jiraIssuePattern = "${jiraUrl}/browse/{}"

    systemProperty("selenide.timeout", 15000)
    systemProperty("allure.model.indentOutput", true)
    systemProperty("allure.link.issue.pattern", jiraIssuePattern)
    systemProperty("allure.link.tms.pattern", jiraIssuePattern)

    useTestNG {
        listeners.add("io.github.sskorol.listeners.BeforeMethodListener")
        listeners.add("com.plannuh.utils.PageCacheProvider")
        listeners.add("com.plannuh.utils.AttachmentsListener")
        listeners.add("com.plannuh.utils.CDPProvider")
        listeners.add("com.plannuh.assertions.AssertListener")
        suites("src/test/resources/${suiteName}.xml")
    }

    doFirst {
        jvmArgs("-javaagent:${agent.singleFile}")
    }
}

sonarqube {
    properties {
        properties(
            hashMapOf<String, String>(
                "sonar.branch" to "ui"
            )
        )
    }
}