PKGBUILD smtube-svn

pkgname=smtube-svn
pkgver=r6904
pkgrel=1
pkgdesc="Search, download and play videos from YouTube. SVN build."
arch=('i686' 'x86_64')
url="http://smtube.sourceforge.net"
license=('GPL')
depends=('qt5-script' 'desktop-file-utils' 'hicolor-icon-theme' 'libxkbcommon-x11')
makedepends=('subversion' 'qt5-tools')
optdepends=('smplayer: play videos with SMPlayer'
            'mpv: play videos with mpv'
            'gnome-mplayer: play videos with GNOME MPlayer'
            'kdemultimedia-dragonplayer: play videos with Dragon Player'
            'totem: play videos with Totem'
            'vlc: play videos with VLC')
provides=('smtube')
conflicts=('smtube')
source=('smtube::svn+https://subversion.assembla.com/svn/smplayer/smtube/trunk/')
md5sums=('SKIP')

pkgver() {
  cd "$SRCDEST"/smtube
  local ver="$(svnversion)"
  printf "r%s" "$ver"
}

build() {
  cd "$srcdir/smtube"
  ./get_svn_revision.sh
  make PREFIX="/usr"
}

package() {
  cd "$srcdir/smtube"
  make PREFIX="/usr" DESTDIR="$pkgdir" install
}