-- =============================================
-- Author:		<Marcin Pazdan>
-- Create date: <2018-11-15>
-- Description:	<Statystyka zadań na egzaminie.>
-- WorkItem:	#11217
-- =============================================
CREATE PROCEDURE [egzamin].[proc_PodmiotPytanieArkuszaEzgaminacyjnegoStatystykaZadaniaList]
	@PlacowkaID INT,
	@EgzaminID INT
AS
BEGIN
	SET NOCOUNT ON;

	DECLARE @GminaID INT
	DECLARE @PowiatID INT
	DECLARE @WojewodztwoID INT

	SELECT
		@GminaID = g.ID, @PowiatID = pow.ID, @WojewodztwoID = pow.IdWojewodztwo
	FROM
		podmiot.Placowka AS p
		INNER JOIN podmiot.Adres AS a ON a.IdPlacowka = p.ID AND a.IdTypAdresu = 1
		INNER JOIN teryt.Miejscowosc AS m ON m.ID = a.IdMiejscowosc
		INNER JOIN teryt.Gmina AS g ON m.IdGmina = g.ID
		INNER JOIN teryt.Powiat AS pow ON pow.ID = g.IdPowiat
	WHERE
		p.ID = @PlacowkaID

	SELECT
		pae.ID,
		pae.Etykieta,
		szo.ID AS StatystykaZadaniaWOddzialeID,
		szo.SredniProcent AS StatystykaZadaniaWOddzialeSredniProcent,
		o.ID AS OddzialID,
		o.Kod AS OddzialKod,
		szpl.ID StatystykaZadaniaWPlacowceID,
		szpl.SredniProcent AS StatystykaZadaniaWPlacowceSredniProcent,
		szg.ID AS StatystykaZadaniaWGminieID,
		szg.SredniProcent AS StatystykaZadaniaWGminieSredniProcent,
		szpo.ID AS StatystykaZadaniaWPowiecieID,
		szpo.SredniProcent AS StatystykaZadaniaWPowiecieSredniProcent,
		szw.ID AS StatystykaZadaniaWWojewodztwieID,
		szw.SredniProcent AS StatystykaZadaniaWWojewodztwieSredniProcent
	FROM
		egzamin.PytanieArkuszaEgzaminacyjnego AS pae
		INNER JOIN wynik.StatystykaZadaniaWOddziale AS szo ON szo.IdPytanieArkuszaEgzamiancyjnego = pae.ID
		INNER JOIN podmiot.Oddzial AS o ON o.ID = szo.IdOddzial
		LEFT JOIN wynik.StatystykaZadaniaWPlacowce AS szpl ON szpl.IdPytanieArkuszaEgzamiancyjnego = pae.ID AND szpl.IdEgzamin = @EgzaminID AND szpl.IdPlacowka = @PlacowkaID
		LEFT JOIN wynik.StatystykaZadaniaWGminie AS szg ON szg.IdPytanieArkuszaEgzamiancyjnego = pae.ID AND szg.IdEgzamin = @EgzaminID AND szg.IdGmina = @GminaID
		LEFT JOIN wynik.StatystykaZadaniaWPowiecie AS szpo ON szpo.IdPytanieArkuszaEgzamiancyjnego = pae.ID AND szpo.IdEgzamin = @EgzaminID AND szpo.IdPowiat = @PowiatID
		LEFT JOIN wynik.StatystykaZadaniaWWojewodztwie AS szw ON szw.IdPytanieArkuszaEgzamiancyjnego = pae.ID AND szw.IdEgzamin = @EgzaminID AND szw.IdWojewodztwo = @WojewodztwoID
	WHERE
		o.IdPlacowka = @PlacowkaID
		AND szo.IdEgzamin = @EgzaminID
	ORDER BY
		pae.Numer
END