Speed-UP

//credits: Slice
#include <a_samp>
#define SPEED_MULTIPLIER 1.020
#define SPEED_THRESHOLD  0.4

new
          g_SpeedUpTimer = -1,
    Float:g_SpeedThreshold,
          PLAYER_SLOTS
;

new const
          KEY_VEHICLE_FORWARD  = 0b001000,
          KEY_VEHICLE_BACKWARD = 0b100000
;

public OnFilterScriptInit() {
    PLAYER_SLOTS = GetMaxPlayers();

    g_SpeedUpTimer = SetTimer("SpeedUp", 220, true);
    g_SpeedThreshold = SPEED_THRESHOLD * SPEED_THRESHOLD;
}

public OnFilterScriptExit() {
    KillTimer(g_SpeedUpTimer);
}

forward SpeedUp();
public SpeedUp() {
    new
        vehicleid,
        keys,
        Float:vx,
        Float:vy,
        Float:vz
    ;
    for (new playerid = 0; playerid < PLAYER_SLOTS; playerid++) {
        if (!IsPlayerConnected(playerid))
            continue;

        if ((vehicleid = GetPlayerVehicleID(playerid))) {
            GetPlayerKeys(playerid, keys, _:vx, _:vx);

            if ((keys & (KEY_VEHICLE_FORWARD | KEY_VEHICLE_BACKWARD | KEY_HANDBRAKE)) == KEY_VEHICLE_FORWARD) {
                GetVehicleVelocity(vehicleid, vx, vy, vz);

                if (vx * vx + vy * vy < g_SpeedThreshold)
                    continue;

                vx *= SPEED_MULTIPLIER;
                vy *= SPEED_MULTIPLIER;

                if (vz > 0.04 || vz < -0.04)
                    vz -= 0.020;

                SetVehicleVelocity(vehicleid, vx, vy, vz);
            }
        }
    }
}