Create Directory Junctions for Each Directories

@rem Create Directory Junctions for Every Directories in A Directory

@rem http://stackoverflow.com/questions/7044985/how-can-i-auto-elevate-my-batch-file-so-that-it-requests-from-uac-admin-rights
:::::::::::::::::::::::::::::::::::::::::
:: Automatically check & get admin rights
:::::::::::::::::::::::::::::::::::::::::
:checkPrivileges
@NET FILE 1>NUL 2>NUL
@if '%errorlevel%' == '0' ( @goto gotPrivileges ) else ( @goto getPrivileges )

:getPrivileges
@if '%1'=='ELEV' (@shift & goto gotPrivileges)

@setlocal DisableDelayedExpansion
@set "batchPath=%~0"
@setlocal EnableDelayedExpansion
@ECHO Set UAC = CreateObject^("Shell.Application"^) > "%temp%\OEgetPrivileges.vbs"
@ECHO UAC.ShellExecute "!batchPath!", "ELEV", "", "runas", 1 >> "%temp%\OEgetPrivileges.vbs"
@"%temp%\OEgetPrivileges.vbs"
@exit /B

:gotPrivileges
::::::::::::::::::::::::::::
::START
::::::::::::::::::::::::::::

@setlocal

@set PREV_DIR=%CD%
@set LIB_LOGICAL_DIR=D:\Users\Public\Documents\Sample Library
@set LIB_PHYSICAL_DIR=G:\Sample Library

echo %LIB_PHYSICAL_DIR% にあるフォルダを %LIB_LOGICAL_DIR% にリンクします。
@cd /d "%LIB_PHYSICAL_DIR%"
@for /d %%a in (*) do @mklink /D "%LIB_LOGICAL_DIR%\%%a" "%LIB_PHYSICAL_DIR%\%%a"

@cd /d "%PREV_DIR%"

@endlocal
@pause