prontera,155,181,5	script	Sample	757,{
if( getgmlevel() < 99 ){
	mes "Only Admin can use.";
}else{
	mes "how can i help you ?";

	for( set .@i,0; .@i < $map_size; set .@i,.@i + 1 ){
		mes "["+( .@i+1 )+"]^0055FF"+$map_name$[.@i]+" - ^777777"+$map_user$[.@i]+"^000000";
		set .@menu$,.@menu$ + "^0055FF"+$map_name$[.@i]+" - ^777777"+$map_user$[.@i]+"^000000" +":";
	}
	switch( select( ( $map_size > 99 )?"":"Add",( !$map_size )?"":"Remove" ) ){
		Case 1:
			mes "Enter map name";
			do{
				input .@map$;
			}while( getmapusers( .@map$ ) < 0 );
			if( compare( .@menu$,.@map$+" - " ) ){
				mes "This map has been assigned with a users.";
				close;
			}
			mes "Enter User name";
			input .@player$;
			next;
			mes "Map : ^777777"+.@map$+"^000000";
			mes "Player : ^777777"+.@player$+"^000000";
			if( select( "Cancel","Confirm" ) == 2 ){
				set $map_name$[$map_size],.@map$;
				set $map_user$[$map_size],.@player$;
				if( !getmapflag( .@map$,mf_loadevent ) )
					setmapflag .@map$,mf_loadevent;
				mes "Done";
			}
			break;
		Case 2:
			mes "Select a Map to remove.";
			set .@i,select( .@menu$ ) - 1;
			mes "Remove this map ?";
			mes "^0055FF"+$map_name$[.@i]+" - ^777777"+$map_user$[.@i]+"^000000";
			if( select( "Cancel","Confirm" ) == 2 ){
				if( getmapflag( $map_name$[.@i],mf_loadevent ) )
					removemapflag $map_name$[.@i],mf_loadevent;
				deletearray $map_name$[.@i],1;
				deletearray $map_user$[.@i],1;
				mes "Done";
			}
		default: break;
	}
	set $map_size,getarraysize( $map_name$ );
}
close;

OnInit:
for( set .@i,0; .@i < $map_size; set .@i,.@i + 1 )
	if( !getmapflag( $map_name$[.@i],mf_loadevent ) )
		setmapflag $map_name$[.@i],mf_loadevent;
end;

OnPCLoadMapEvent:
if( getgmlevel() < 99 ){
	set .@map$,strcharinfo(3);
	for( set .@i,0; .@i < $map_size; set .@i,.@i + 1 )
		if( $map_name$[.@i] == .@map$ )
			if( $map_user$[.@i] != strcharinfo(0) ){
				mes "You can enter "+$map_name$[.@i]+".";
				mes "Only "+$map_user$[.@i]+" can enter.";
				close2;
				warp "SavePoint",0,0;
				break;
			}
}
end;
}