/*
 *
 * plant controller - tim eastwood
 *
 */

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1); // -1 is the reset pin, or 4 // Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)

/*
 *
 *  PIN ASSIGNMENTS
 *
 */

#define flow1Interrupt 3 //pin 1
#define flow2Interrupt 2 //pin 0
#define dht1Pin 4
#define dht2Pin 5
#define ledPin 6
#define buzzPin 7
#define buttonPin 8
#define floatSw1Pin 9
#define floatSw2Pin 20
#define lamp1Pin 10
#define lamp2Pin 16
#define pump1Pin 14
#define pump2Pin 15
#define RXPin 19
#define TXPin 18

#include "DHT.h"
DHT dht1(dht1Pin, DHT22); //pin, type
DHT dht2(dht2Pin, DHT22);

#include <SoftwareSerial.h>
SoftwareSerial SerialS(RXPin, TXPin);

#define initialDisplayMessage "Waiting for ESP..."

//draws the border and title
void drawInitial() {
  display.drawRoundRect(0,0,display.width(),display.height(), 2, WHITE); //x, y, x, y, radius, color
  display.fillRoundRect(0,0,display.width(),10, 2, WHITE); //x, y, x, y, radius, color
  display.setTextSize(1);      // Normal 1:1 pixel scale
  display.setTextColor(BLACK); // Draw black text
  display.setCursor(2, 2);     // Start at top-left corner
  display.cp437(true);         // Use full 256 char 'Code Page 437' font
  display.print(" Plant Controller v1");
  display.setTextColor(WHITE, BLACK); // Draw white text with a black background (transparent by default)
  display.display();
}

unsigned int long timer = 0;
unsigned int long lastPageTimer = 0; //track when page was last changed
String displayMessage = initialDisplayMessage;
void setup() {

  pinMode(buttonPin, INPUT_PULLUP);
  pinMode(floatSw1Pin, INPUT_PULLUP);
  pinMode(floatSw2Pin, INPUT_PULLUP);
  pinMode(ledPin, OUTPUT);
  pinMode(buzzPin, OUTPUT);

  delay(1000);

  Serial.begin(115200); //pour a bowl of Serial
  SerialS.begin(9600); //the RX/TX pins are on a separate hardware UART! Hurrah!
  Serial.println("Hello");
  dht1.begin();
  dht2.begin(); //initilize the DHT22 sensors

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally. no idea wtf this does
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 err"));
    for(;;); // Don't proceed, loop forever
  }

  display.clearDisplay();
  drawInitial();
  display.setCursor(2, 12);
  display.print(displayMessage); // line 1
  timer = millis();
  lastPageTimer = millis();
}

String inputString = ""; // a String to hold incoming data
bool stringComplete = false;
void serialEventCapture() {
  while (SerialS.available()) {
    char inChar = (char)SerialS.read();
    if (inChar == '\n') {
      if (millis() > 3000) { //ignore data for the first three seconds since boot
        displayMessage = inputString;
        stringComplete = true;
        Serial.println(displayMessage);
      }
      inputString = "";
    } else {
      if ((' ' <= inChar) && (inChar <= '~')) { //filter out garbage characters
        inputString += inChar;
      }
    }
  }
}

int page = 1;
#define numPages 2
#define pageTime 2 //seconds to display each page before moving to the next
#define updateFrequency 500 //how often to update the LCD and read sensors

bool waitingForESP = true;
bool ESPWaitingForAVR = true;
void loop() {

  if (SerialS.available()) {
    serialEventCapture();
  }

  //tell the AVR when ready
  if (ESPWaitingForAVR) {
    delay(500);
    SerialS.println("AVR Ready\n");
  }
  if (stringComplete && (ESPWaitingForAVR || waitingForESP)) {
    if (inputString == "ESP seen AVR") {
      ESPWaitingForAVR = false;
      Serial.println("Seen the ESP");
    } else if (inputString == "ESP Ready") {
      SerialS.println("AVR seen ESP");
      Serial.println("ESP has seen us");
      waitingForESP = false;
    } else {
      Serial.println(inputString);
      delay(15);
    }
    stringComplete = false;
  }

  //advance the page every x ms
  if (millis() - lastPageTimer > pageTime * 1000) {
    page++;
    if (page > numPages) {
      page = 1;
    }
    lastPageTimer = millis();
    //fill in the display area with black to mask any previous display elements. not using a display.clearDisplay() to prevent a refresh of the border / title
    display.fillRect(1,10,display.width()-2,display.height()-11, BLACK);
  }

  //control update frequency
  if (millis() - timer > updateFrequency) {
    timer = millis();

    float humidity1 = dht1.readHumidity(); //read humidity
    float temp1 = dht1.readTemperature(); //read temperature as Celsius (the default)
    float humidity2 = dht2.readHumidity();
    float temp2 = dht2.readTemperature();

    float workingRHSensors = 2.0; //used for working out the average humidity
    if (isnan(humidity1)) { humidity1 = 0; workingRHSensors -= 1.0; } //check for valid reading
    if (isnan(humidity2)) { humidity2 = 0; workingRHSensors -= 1.0; }
    float averageHumidity = (humidity1 + humidity2) / workingRHSensors;

    float workingTempSensors = 2.0;
    if (isnan(temp1)) { temp1 = 0; workingTempSensors -= 1; }
    if (isnan(temp2)) { temp2 = 0; workingTempSensors -= 1; }
    float averageTemp = (temp1 + temp2) / workingTempSensors;

    if (page == 1) {
      display.setCursor(2, 12); display.print(displayMessage); // line 1
      display.setTextSize(2); //use larger font
      display.setCursor(2, 20); display.print("Avg Temp");// line 2
      display.setCursor(2, 36);
      if (workingTempSensors > 0) {
        display.print(averageTemp); display.print("C"); // line 4
      } else {
        display.print("N/A");
      }
      display.setTextSize(1); //set back to size 1
    }
    else if (page == 2) {
      display.setCursor(2, 12); display.print(displayMessage); // line 1
      display.setTextSize(2); //use larger font
      display.setCursor(2, 20); display.print("Avg Humid."); // line 2
      display.setCursor(2, 36);
      if (workingRHSensors > 0) {
        display.print(averageHumidity); display.print("%"); // line 4
      } else {
        display.print("N/A");
      }
      display.setTextSize(1); //set back to size 1
    }

    //line 6
    display.setCursor(2, 52); display.print("Sensors: H "); display.print(int(workingRHSensors)); display.print(", T "); display.println(int(workingTempSensors));

    display.display();

    //compile the data into a string of POST values to send to the HTTP connection on the ESP
    //I've shortened these to a few characters to keep the RAM impact minimal... not sure if neccessary but the ESP's serial is buggy as shit so less is more (apparently)
    String data = "&t1="; data += temp1;
    data += "&t2="; data += temp2;
    data += "&h1="; data += humidity1;
    data += "&h2="; data += humidity2;

    if (!ESPWaitingForAVR && !waitingForESP) {
        Serial.print(".");
        SerialS.println(data);
    }
  }

}