skeuos-gtk-theme-git

pkgname=skeuos-gtk-theme-git
_pkgname="${pkgname%-theme-git}"
pkgver=20210921.r0.gc67518f
pkgrel=1
pkgdesc="Skeuomorphic GTK theme"
arch=('any')
url="https://gnome-look.org/p/1441725"
license=('GPL3')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
options=('!strip')
source=('git+https://github.com/daniruiz/skeuos-gtk.git')
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

package() {
  cd "$srcdir/$_pkgname"
  make DESTDIR="$pkgdir/" install

  pushd themes
  for color in Black Blue Brown Cyan Green Grey Magenta Orange Red Teal Violet White Yellow; do

    # GNOME Shell default
    cp -r Skeuos-${color}-Dark-GNOME_40/gnome-shell "$pkgdir"/usr/share/themes/Skeuos-${color}-Dark
    cp -r Skeuos-${color}-Light-GNOME_40/gnome-shell "$pkgdir"/usr/share/themes/Skeuos-${color}-Light

    # GNOME Shell full panel
#    cp -r Skeuos-${color}-Dark-FullPanel-GNOME_40/gnome-shell "$pkgdir"/usr/share/themes/Skeuos-${color}-Dark
#    cp -r Skeuos-${color}-Light-FullPanel-GNOME_40/gnome-shell "$pkgdir"/usr/share/themes/Skeuos-${color}-Light

    # XFWM default
    cp -r Skeuos-${color}-Dark-XFWM/xfwm4 "$pkgdir"/usr/share/themes/Skeuos-${color}-Dark
    cp -r Skeuos-${color}-Light-XFWM/xfwm4 "$pkgdir"/usr/share/themes/Skeuos-${color}-Light

    # XFWM xHiDPI
#    cp -r Skeuos-${color}-Dark-XFWM-xHiDPI/xfwm4 "$pkgdir"/usr/share/themes/Skeuos-${color}-Dark
#    cp -r Skeuos-${color}-Light-XFWM-xHiDPI/xfwm4 "$pkgdir"/usr/share/themes/Skeuos-${color}-Light
  done
  popd
}