; Proposal #1

;(1541)

convers
     !byte %1111, %0111, %1101, %0101, %1011, %0011, %1001, %0001
     !byte %1110, %0110, %1100, %0100, %1010, %0010, %1000, %0000

    ldy #$00
send
    lda buffer,y    ; 4 X=abcdefgh
    ldx #$0f        ; 2
    sbx #$00        ; 2
    lsr             ; 2
    lsr             ; 2
    lsr             ; 2
    lsr             ; 2
    sta .y0+1       ; 4
    lda convers,x   ; 4             Load: 24

waitloop
    bit $1800       ; 4
    bpl waitloop    ; 2/3 (6+?)     Wait: 6+

    sta $1800       ; 4 (Send hg)
    asl             ; 2
    ldx #%00001010  ; 2
    sax $1800       ; 4 (Send fe)
.y0
    lda convers     ; 4
    sax $1800       ; 4 (Send dc)
    asl             ; 2
    iny             ; 2
    sax $1800       ; 4 (Send ba)   Transfer: 28

    bne send        ; 3/2           Loop ctrl: 3


; Proposal #2

;(1541)

    ldy #$00
send
    ldx buffer,y    ; 4 X=abcdefgh
    lda convers,x   ; 4 X=abcdefgh => A=hfgedbca
    tax             ; 2
    lsr             ; 2
    lsr             ; 2
    lsr             ; 2
    lsr             ; 2 A=0000hfge  Load: 18

waitloop
    bit $1800       ; 4
    bpl waitloop    ; 2/3           Wait: 6+

    sta $1800       ; 4 (Send hg)
    asl             ; 2
    and #$0f        ; 2
    sta $1800       ; 4 (Send fe)
    txa             ; 2 X=hfgedbca
    ldx #%00001010  ; 2
    sax $1800       ; 4 (Send dc)
    asl             ; 2
    iny             ; 2
    sax $1800       ; 4 (Send ba)    Transfer: 28

    bne send        ; 3/2   (3)      Loop ctrl: 3

convers
; 256 byte conversion table