Dead Key Function

;{ Dead Key List
deadKeyList := {}
deadKeyList["Grave"]:=     {"a":"à", "e":"è", "i":"ì", "n":"ǹ", "o":"ò", "u":"ù", "w":"ẁ", "y":"ỳ"
    ,                                "none":"``"}
deadKeyList["Tilde"]:=     {"a":"ã", "e":"ẽ", "i":"ĩ", "n":"ñ", "o":"õ", "u":"ũ", "v":"ṽ", "y":"ỹ"
    ,                                "none":"~"}
deadKeyList["Acute"]:=     {"a":"á", "c":"ć", "e":"é", "g":"ǵ", "i":"í", "k":"ḱ", "l":"ĺ", "m":"ḿ"
    ,                                "n":"ń", "o":"ó", "p":"ṕ", "r":"ŕ", "s":"ś", "u":"ú", "w":"ẃ"
    ,                                "y":"ý", "z":"ź", "æ":"ǽ", "none":"'"}
deadKeyList["Umlaut"]:=    {"a":"ä", "e":"ë", "h":"ḧ", "i":"ï", "o":"ö", "t":"ẗ", "u":"ü", "w":"ẅ"
    ,                                "x":"ẍ", "y":"ÿ", "none":Chr(34)}
deadKeyList["Circumflex"]:={"a":"â", "c":"ĉ", "e":"ê", "g":"ĝ", "h":"ĥ", "i":"î", "j":"ĵ", "o":"ô"
    ,                                "s":"ŝ", "u":"û", "w":"ŵ", "y":"ŷ", "z":"ẑ",  "none":"+6"}
deadKeyList["Macron"]:=    {"a":"ā", "b":"ḇ", "d":"ḏ", "e":"ē", "g":"ḡ", "h":"ẖ", "i":"ī", "k":"ḵ"
    ,                                "l":"ḻ", "n":"ṉ", "o":"ō", "r":"ṟ", "t":"ṯ", "u":"ū", "y":"ȳ"
    ,                                "z":"ẕ", "none":"-"}
deadKeyList["Stroke"]:=    {"a":"ⱥ", "b":"ƀ", "c":"ȼ", "d":"đ", "e":"ɇ", "g":"ǥ", "h":"ħ", "i":"ɨ"
    ,                                "j":"ɉ", "l":"ł", "o":"ø", "p":"ᵽ", "r":"ɍ", "t":"ŧ", "u":"ʉ"
    ,                                "y":"ɏ", "z":"ƶ", "none":"_"}
deadKeyList["Ring"]:=      {"a":"å", "u":"ů", "w":"ẘ", "y":"ẙ", "none":"˚"}
deadKeyList["Caron"]:=     {"a":"ǎ", "c":"č", "d":"ď", "e":"ě", "g":"ǧ", "h":"ȟ", "i":"ǐ", "j":"ǰ"
    ,                                "k":"ǩ", "l":"ľ", "n":"ň", "o":"ǒ", "r":"ř", "s":"š", "t":"ť"
    ,                                "u":"ǔ", "z":"ž", "none":"ˇ"}
deadKeyList["Cedilla"]:=   {"c":"ç", "d":"ḑ", "e":"ȩ", "g":"ģ", "h":"ḩ", "k":"ķ", "l":"ļ", "n":"ņ"
    ,                                "r":"ŗ", "s":"ş", "t":"ţ", "none":"¸"}
deadKeyList["Ogonek"]:=    {"a":"ą", "e":"ę", "i":"į", "o":"ǫ", "u":"ų", "none":"˛"}
deadKeyList["Breve"]:=     {"a":"ă", "e":"ĕ", "g":"ğ", "h":"ḫ", "i":"ĭ", "o":"ŏ", "u":"ŭ"
    ,                                "none":"˘"}
;} Dead Key List

DeadKey(diacritic) {
    global deadKeyList
    light(1, 1)
    Suspend On
    Input letter, l1
    Suspend Off
    if (letter = " ")
        Send % deadKeyList[diacritic, "none"]
    else if (deadKeyList[diacritic].hasKey(letter))
    {
        outLetter := deadKeyList[diacritic, letter]
        if letter is upper
            StringUpper, outLetter, outLetter
        Send %outLetter%
    }
    else, Send % deadKeyList[diacritic, "none"] . letter
    light(1, 0)
}

$`::DeadKey("Grave")
$+`::DeadKey("Tilde")
$'::DeadKey("Acute")
$+'::DeadKey("Umlaut")
$+6::DeadKey("Circumflex")
$-::DeadKey("Macron")
$+-::DeadKey("Stroke")
<^>!+`::DeadKey("Ring")
<^>!v::DeadKey("Caron")
<^>!.::DeadKey("Cedilla")
<^>!`::DeadKey("Breve")
<^>!+.::DeadKey("Ogonek")